lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use strict;
   3 use warnings;
   4
   5 use Mouse::Meta::Method::Constructor;
   6 use Mouse::Meta::Method::Destructor;
   7 use Scalar::Util qw/blessed/;
   8 use Mouse::Util qw/get_linear_isa version authority identifier/;
   9 use Carp 'confess';
  10
  11 do {
  12     my %METACLASS_CACHE;
  13
  14     # because Mouse doesn't introspect existing classes, we're forced to
  15     # only pay attention to other Mouse classes
  16     sub _metaclass_cache {
  17         my $class = shift;
  18         my $name  = shift;
  19         return $METACLASS_CACHE{$name};
  20     }
  21
  22     sub initialize {
  23         my $class = blessed($_[0]) || $_[0];
  24         my $name  = $_[1];
  25
  26         $METACLASS_CACHE{$name} = $class->new(name => $name)
  27             if !exists($METACLASS_CACHE{$name});
  28         return $METACLASS_CACHE{$name};
  29     }
  30 };
  31
  32 sub new {
  33     my $class = shift;
  34     my %args  = @_;
  35
  36     $args{attributes} = {};
  37     $args{superclasses} = do {
  38         no strict 'refs';
  39         \@{ $args{name} . '::ISA' };
  40     };
  41     $args{roles} ||= [];
  42
  43     bless \%args, $class;
  44 }
  45
  46 sub name { $_[0]->{name} }
  47
  48 sub superclasses {
  49     my $self = shift;
  50
  51     if (@_) {
  52         Mouse::load_class($_) for @_;
  53         @{ $self->{superclasses} } = @_;
  54     }
  55
  56     @{ $self->{superclasses} };
  57 }
  58
  59 sub add_method {
  60     my $self = shift;
  61     my $name = shift;
  62     my $code = shift;
  63
  64     my $pkg = $self->name;
  65
  66     no strict 'refs';
  67     no warnings 'redefine';
  68     $self->{'methods'}->{$name}++; # Moose stores meta object here.
  69     *{ $pkg . '::' . $name } = $code;
  70 }
  71
  72 sub has_method {
  73     my $self = shift;
  74     my $name = shift;
  75     $self->name->can($name);
  76 }
  77
  78 # copied from Class::Inspector
  79 my $get_methods_for_class = sub {
  80     my $self = shift;
  81     my $name = shift;
  82
  83     no strict 'refs';
  84     # Get all the CODE symbol table entries
  85     my @functions =
  86       grep !/^(?:has|with|around|before|after|augment|inner|blessed|extends|confess|override|super)$/,
  87       grep { defined &{"${name}::$_"} }
  88       keys %{"${name}::"};
  89     push @functions, keys %{$self->{'methods'}->{$name}} if $self;
  90     wantarray ? @functions : \@functions;
  91 };
  92
  93 sub get_method_list {
  94     my $self = shift;
  95     $get_methods_for_class->($self, $self->name);
  96 }
  97
  98 sub get_all_method_names {
  99     my $self = shift;
 100     my %uniq;
 101     return grep { $uniq{$_}++ == 0 }
 102             map { $get_methods_for_class->(undef, $_) }
 103             $self->linearized_isa;
 104 }
 105
 106 sub add_attribute {
 107     my $self = shift;
 108
 109     if (@_ == 1 && blessed($_[0])) {
 110         my $attr = shift @_;
 111         $self->{'attributes'}{$attr->name} = $attr;
 112     } else {
 113         my $names = shift @_;
 114         $names = [$names] if !ref($names);
 115         my $metaclass = 'Mouse::Meta::Attribute';
 116         my %options = @_;
 117
 118         if ( my $metaclass_name = delete $options{metaclass} ) {
 119             my $new_class = Mouse::Util::resolve_metaclass_alias(
 120                 'Attribute',
 121                 $metaclass_name
 122             );
 123             if ( $metaclass ne $new_class ) {
 124                 $metaclass = $new_class;
 125             }
 126         }
 127
 128         for my $name (@$names) {
 129             if ($name =~ s/^\+//) {
 130                 $metaclass->clone_parent($self, $name, @_);
 131             }
 132             else {
 133                 $metaclass->create($self, $name, @_);
 134             }
 135         }
 136     }
 137 }
 138
 139 sub compute_all_applicable_attributes {
 140     my $self = shift;
 141     my (@attr, %seen);
 142
 143     for my $class ($self->linearized_isa) {
 144         my $meta = $self->_metaclass_cache($class)
 145             or next;
 146
 147         for my $name (keys %{ $meta->get_attribute_map }) {
 148             next if $seen{$name}++;
 149             push @attr, $meta->get_attribute($name);
 150         }
 151     }
 152
 153     return @attr;
 154 }
 155
 156 sub get_attribute_map { $_[0]->{attributes} }
 157 sub has_attribute     { exists $_[0]->{attributes}->{$_[1]} }
 158 sub get_attribute     { $_[0]->{attributes}->{$_[1]} }
 159
 160 sub linearized_isa { @{ get_linear_isa($_[0]->name) } }
 161
 162 sub clone_object {
 163     my $class    = shift;
 164     my $instance = shift;
 165
 166     (blessed($instance) && $instance->isa($class->name))
 167         || confess "You must pass an instance of the metaclass (" . $class->name . "), not ($instance)";
 168
 169     $class->clone_instance($instance, @_);
 170 }
 171
 172 sub clone_instance {
 173     my ($class, $instance, %params) = @_;
 174
 175     (blessed($instance))
 176         || confess "You can only clone instances, ($instance) is not a blessed instance";
 177
 178     my $clone = bless { %$instance }, ref $instance;
 179
 180     foreach my $attr ($class->compute_all_applicable_attributes()) {
 181         if ( defined( my $init_arg = $attr->init_arg ) ) {
 182             if (exists $params{$init_arg}) {
 183                 $clone->{ $attr->name } = $params{$init_arg};
 184             }
 185         }
 186     }
 187
 188     return $clone;
 189
 190 }
 191
 192 sub make_immutable {
 193     my $self = shift;
 194     my %args = (
 195         inline_constructor => 1,
 196         @_,
 197     );
 198
 199     my $name = $self->name;
 200     $self->{is_immutable}++;
 201
 202     if ($args{inline_constructor}) {
 203         $self->add_method('new' => Mouse::Meta::Method::Constructor->generate_constructor_method_inline( $self ));
 204     }
 205
 206     if ($args{inline_destructor}) {
 207         $self->add_method('DESTROY' => Mouse::Meta::Method::Destructor->generate_destructor_method_inline( $self ));
 208     }
 209
 210     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 211     # at the end of a source file.
 212     return 1;
 213 }
 214
 215 sub make_mutable { confess "Mouse does not currently support 'make_mutable'" }
 216
 217 sub is_immutable { $_[0]->{is_immutable} }
 218
 219 sub attribute_metaclass { "Mouse::Meta::Class" }
 220
 221 sub _install_modifier {
 222     my ( $self, $into, $type, $name, $code ) = @_;
 223
 224     # which is modifer class available?
 225     my $modifier_class = do {
 226         if (eval "require Class::Method::Modifiers::Fast; 1") {
 227             'Class::Method::Modifiers::Fast';
 228         } elsif (eval "require Class::Method::Modifiers; 1") {
 229             'Class::Method::Modifiers';
 230         } else {
 231             Carp::croak("Method modifiers require the use of Class::Method::Modifiers or Class::Method::Modifiers::Fast. Please install it from CPAN and file a bug report with this application.");
 232         }
 233     };
 234     my $modifier = $modifier_class->can('_install_modifier');
 235
 236     # replace this method itself :)
 237     {
 238         no strict 'refs';
 239         no warnings 'redefine';
 240         *{__PACKAGE__ . '::_install_modifier'} = sub {
 241             my ( $self, $into, $type, $name, $code ) = @_;
 242             $modifier->(
 243                 $into,
 244                 $type,
 245                 $name,
 246                 $code
 247             );
 248         };
 249     }
 250
 251     # call me. for first time.
 252     $self->_install_modifier( $into, $type, $name, $code );
 253 }
 254
 255 sub add_before_method_modifier {
 256     my ( $self, $name, $code ) = @_;
 257     $self->_install_modifier( $self->name, 'before', $name, $code );
 258 }
 259
 260 sub add_around_method_modifier {
 261     my ( $self, $name, $code ) = @_;
 262     $self->_install_modifier( $self->name, 'around', $name, $code );
 263 }
 264
 265 sub add_after_method_modifier {
 266     my ( $self, $name, $code ) = @_;
 267     $self->_install_modifier( $self->name, 'after', $name, $code );
 268 }
 269
 270 sub add_override_method_modifier {
 271     my ($self, $name, $code) = @_;
 272
 273     my $pkg = $self->name;
 274     my $method = "${pkg}::${name}";
 275
 276     # Class::Method::Modifiers won't do this for us, so do it ourselves
 277
 278     my $body = $pkg->can($name)
 279         or confess "You cannot override '$method' because it has no super method";
 280
 281     no strict 'refs';
 282     *$method = sub { $code->($pkg, $body, @_) };
 283 }
 284
 285
 286 sub roles { $_[0]->{roles} }
 287
 288 sub does_role {
 289     my ($self, $role_name) = @_;
 290
 291     (defined $role_name)
 292         || confess "You must supply a role name to look for";
 293
 294     for my $role (@{ $self->{roles} }) {
 295         return 1 if $role->name eq $role_name;
 296     }
 297
 298     return 0;
 299 }
 300
 301 sub create {
 302     my ($self, $package_name, %options) = @_;
 303
 304     (ref $options{superclasses} eq 'ARRAY')
 305         || confess "You must pass an ARRAY ref of superclasses"
 306             if exists $options{superclasses};
 307
 308     (ref $options{attributes} eq 'ARRAY')
 309         || confess "You must pass an ARRAY ref of attributes"
 310             if exists $options{attributes};
 311
 312     (ref $options{methods} eq 'HASH')
 313         || confess "You must pass a HASH ref of methods"
 314             if exists $options{methods};
 315
 316     do {
 317         ( defined $package_name && $package_name )
 318           || confess "You must pass a package name";
 319
 320         my $code = "package $package_name;";
 321         $code .= "\$$package_name\:\:VERSION = '" . $options{version} . "';"
 322           if exists $options{version};
 323         $code .= "\$$package_name\:\:AUTHORITY = '" . $options{authority} . "';"
 324           if exists $options{authority};
 325
 326         eval $code;
 327         confess "creation of $package_name failed : $@" if $@;
 328     };
 329
 330     my %initialize_options = %options;
 331     delete @initialize_options{qw(
 332         package
 333         superclasses
 334         attributes
 335         methods
 336         version
 337         authority
 338     )};
 339     my $meta = $self->initialize( $package_name => %initialize_options );
 340
 341     # FIXME totally lame
 342     $meta->add_method('meta' => sub {
 343         $self->initialize(ref($_[0]) || $_[0]);
 344     });
 345
 346     $meta->superclasses(@{$options{superclasses}})
 347         if exists $options{superclasses};
 348     # NOTE:
 349     # process attributes first, so that they can
 350     # install accessors, but locally defined methods
 351     # can then overwrite them. It is maybe a little odd, but
 352     # I think this should be the order of things.
 353     if (exists $options{attributes}) {
 354         foreach my $attr (@{$options{attributes}}) {
 355             Mouse::Meta::Attribute->create($meta, $attr->{name}, %$attr);
 356         }
 357     }
 358     if (exists $options{methods}) {
 359         foreach my $method_name (keys %{$options{methods}}) {
 360             $meta->add_method($method_name, $options{methods}->{$method_name});
 361         }
 362     }
 363     return $meta;
 364 }
 365
 366 {
 367     my $ANON_CLASS_SERIAL = 0;
 368     my $ANON_CLASS_PREFIX = 'Mouse::Meta::Class::__ANON__::SERIAL::';
 369     sub create_anon_class {
 370         my ( $class, %options ) = @_;
 371         my $package_name = $ANON_CLASS_PREFIX . ++$ANON_CLASS_SERIAL;
 372         return $class->create( $package_name, %options );
 373     }
 374 }
 375
 376 1;
 377
 378 __END__
 379
 380 =head1 NAME
 381
 382 Mouse::Meta::Class - hook into the Mouse MOP
 383
 384 =head1 METHODS
 385
 386 =head2 initialize ClassName -> Mouse::Meta::Class
 387
 388 Finds or creates a Mouse::Meta::Class instance for the given ClassName. Only
 389 one instance should exist for a given class.
 390
 391 =head2 new %args -> Mouse::Meta::Class
 392
 393 Creates a new Mouse::Meta::Class. Don't call this directly.
 394
 395 =head2 name -> ClassName
 396
 397 Returns the name of the owner class.
 398
 399 =head2 superclasses -> [ClassName]
 400
 401 Gets (or sets) the list of superclasses of the owner class.
 402
 403 =head2 add_attribute (Mouse::Meta::Attribute| name => spec)
 404
 405 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 406 class.
 407
 408 =head2 compute_all_applicable_attributes -> (Mouse::Meta::Attribute)
 409
 410 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 411 this class and its superclasses.
 412
 413 =head2 get_attribute_map -> { name => Mouse::Meta::Attribute }
 414
 415 Returns a mapping of attribute names to their corresponding
 416 L<Mouse::Meta::Attribute> objects.
 417
 418 =head2 has_attribute Name -> Bool
 419
 420 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 421
 422 =head2 get_attribute Name -> Mouse::Meta::Attribute | undef
 423
 424 Returns the L<Mouse::Meta::Attribute> with the given name.
 425
 426 =head2 linearized_isa -> [ClassNames]
 427
 428 Returns the list of classes in method dispatch order, with duplicates removed.
 429
 430 =head2 clone_object Instance -> Instance
 431
 432 Clones the given C<Instance> which must be an instance governed by this
 433 metaclass.
 434
 435 =head2 clone_instance Instance, Parameters -> Instance
 436
 437 Clones the given C<Instance> and sets any additional parameters.
 438
 439 =cut
 440