lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use strict;
   3 use warnings;
   4
   5 use Mouse::Meta::Method::Constructor;
   6 use Mouse::Meta::Method::Destructor;
   7 use Scalar::Util qw/blessed/;
   8 use Mouse::Util qw/get_linear_isa/;
   9 use Carp 'confess';
  10
  11 do {
  12     my %METACLASS_CACHE;
  13
  14     # because Mouse doesn't introspect existing classes, we're forced to
  15     # only pay attention to other Mouse classes
  16     sub _metaclass_cache {
  17         my $class = shift;
  18         my $name  = shift;
  19         return $METACLASS_CACHE{$name};
  20     }
  21
  22     sub initialize {
  23         my $class = shift;
  24         my $name  = shift;
  25         $METACLASS_CACHE{$name} = $class->new(name => $name)
  26             if !exists($METACLASS_CACHE{$name});
  27         return $METACLASS_CACHE{$name};
  28     }
  29 };
  30
  31 sub new {
  32     my $class = shift;
  33     my %args  = @_;
  34
  35     $args{attributes} = {};
  36     $args{superclasses} = do {
  37         no strict 'refs';
  38         \@{ $args{name} . '::ISA' };
  39     };
  40     $args{roles} ||= [];
  41
  42     bless \%args, $class;
  43 }
  44
  45 sub name { $_[0]->{name} }
  46
  47 sub superclasses {
  48     my $self = shift;
  49
  50     if (@_) {
  51         Mouse::load_class($_) for @_;
  52         @{ $self->{superclasses} } = @_;
  53     }
  54
  55     @{ $self->{superclasses} };
  56 }
  57
  58 sub add_method {
  59     my $self = shift;
  60     my $name = shift;
  61     my $code = shift;
  62
  63     my $pkg = $self->name;
  64
  65     no strict 'refs';
  66     no warnings 'redefine';
  67     $self->{'methods'}->{$name}++; # Moose stores meta object here.
  68     *{ $pkg . '::' . $name } = $code;
  69 }
  70
  71 # copied from Class::Inspector
  72 my $get_methods_for_class = sub {
  73     my $self = shift;
  74     my $name = shift;
  75
  76     no strict 'refs';
  77     # Get all the CODE symbol table entries
  78     my @functions =
  79       grep !/^(?:has|with|around|before|after|blessed|extends|confess|override|super)$/,
  80       grep { defined &{"${name}::$_"} }
  81       keys %{"${name}::"};
  82     push @functions, keys %{$self->{'methods'}->{$name}} if $self;
  83     wantarray ? @functions : \@functions;
  84 };
  85
  86 sub get_method_list {
  87     my $self = shift;
  88     $get_methods_for_class->($self, $self->name);
  89 }
  90
  91 sub get_all_method_names {
  92     my $self = shift;
  93     my %uniq;
  94     return grep { $uniq{$_}++ == 0 }
  95             map { $get_methods_for_class->(undef, $_) }
  96             $self->linearized_isa;
  97 }
  98
  99 sub add_attribute {
 100     my $self = shift;
 101     my $attr = shift;
 102
 103     $self->{'attributes'}{$attr->name} = $attr;
 104 }
 105
 106 sub compute_all_applicable_attributes {
 107     my $self = shift;
 108     my (@attr, %seen);
 109
 110     for my $class ($self->linearized_isa) {
 111         my $meta = $self->_metaclass_cache($class)
 112             or next;
 113
 114         for my $name (keys %{ $meta->get_attribute_map }) {
 115             next if $seen{$name}++;
 116             push @attr, $meta->get_attribute($name);
 117         }
 118     }
 119
 120     return @attr;
 121 }
 122
 123 sub get_attribute_map { $_[0]->{attributes} }
 124 sub has_attribute     { exists $_[0]->{attributes}->{$_[1]} }
 125 sub get_attribute     { $_[0]->{attributes}->{$_[1]} }
 126
 127 sub linearized_isa { @{ get_linear_isa($_[0]->name) } }
 128
 129 sub clone_object {
 130     my $class    = shift;
 131     my $instance = shift;
 132
 133     (blessed($instance) && $instance->isa($class->name))
 134         || confess "You must pass an instance of the metaclass (" . $class->name . "), not ($instance)";
 135
 136     $class->clone_instance($instance, @_);
 137 }
 138
 139 sub clone_instance {
 140     my ($class, $instance, %params) = @_;
 141
 142     (blessed($instance))
 143         || confess "You can only clone instances, ($instance) is not a blessed instance";
 144
 145     my $clone = bless { %$instance }, ref $instance;
 146
 147     foreach my $attr ($class->compute_all_applicable_attributes()) {
 148         if ( defined( my $init_arg = $attr->init_arg ) ) {
 149             if (exists $params{$init_arg}) {
 150                 $clone->{ $attr->name } = $params{$init_arg};
 151             }
 152         }
 153     }
 154
 155     return $clone;
 156
 157 }
 158
 159 sub make_immutable {
 160     my $self = shift;
 161     my %args = (
 162         inline_constructor => 1,
 163         @_,
 164     );
 165
 166     my $name = $self->name;
 167     $self->{is_immutable}++;
 168
 169     if ($args{inline_constructor}) {
 170         $self->add_method('new' => Mouse::Meta::Method::Constructor->generate_constructor_method_inline( $self ));
 171     }
 172
 173     if ($args{inline_destructor}) {
 174         $self->add_method('DESTROY' => Mouse::Meta::Method::Destructor->generate_destructor_method_inline( $self ));
 175     }
 176
 177     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 178     # at the end of a source file.
 179     return 1;
 180 }
 181
 182 sub make_mutable { confess "Mouse does not currently support 'make_mutable'" }
 183
 184 sub is_immutable { $_[0]->{is_immutable} }
 185
 186 sub attribute_metaclass { "Mouse::Meta::Class" }
 187
 188 sub _install_modifier {
 189     my ( $self, $into, $type, $name, $code ) = @_;
 190
 191     # which is modifer class available?
 192     my $modifier_class = do {
 193         if (eval "require Class::Method::Modifiers::Fast; 1") {
 194             'Class::Method::Modifiers::Fast';
 195         } elsif (eval "require Class::Method::Modifiers; 1") {
 196             'Class::Method::Modifiers';
 197         } else {
 198             Carp::croak("Method modifiers require the use of Class::Method::Modifiers or Class::Method::Modifiers::Fast. Please install it from CPAN and file a bug report with this application.");
 199         }
 200     };
 201     my $modifier = $modifier_class->can('_install_modifier');
 202
 203     # replace this method itself :)
 204     {
 205         no strict 'refs';
 206         no warnings 'redefine';
 207         *{__PACKAGE__ . '::_install_modifier'} = sub {
 208             my ( $self, $into, $type, $name, $code ) = @_;
 209             $modifier->(
 210                 $into,
 211                 $type,
 212                 $name,
 213                 $code
 214             );
 215         };
 216     }
 217
 218     # call me. for first time.
 219     $self->_install_modifier( $into, $type, $name, $code );
 220 }
 221
 222 sub add_before_method_modifier {
 223     my ( $self, $name, $code ) = @_;
 224     $self->_install_modifier( $self->name, 'before', $name, $code );
 225 }
 226
 227 sub add_around_method_modifier {
 228     my ( $self, $name, $code ) = @_;
 229     $self->_install_modifier( $self->name, 'around', $name, $code );
 230 }
 231
 232 sub add_after_method_modifier {
 233     my ( $self, $name, $code ) = @_;
 234     $self->_install_modifier( $self->name, 'after', $name, $code );
 235 }
 236
 237 sub roles { $_[0]->{roles} }
 238
 239 sub does_role {
 240     my ($self, $role_name) = @_;
 241
 242     (defined $role_name)
 243         || confess "You must supply a role name to look for";
 244
 245     for my $role (@{ $self->{roles} }) {
 246         return 1 if $role->name eq $role_name;
 247     }
 248
 249     return 0;
 250 }
 251
 252 sub create {
 253     my ($self, $package_name, %options) = @_;
 254
 255     (ref $options{superclasses} eq 'ARRAY')
 256         || confess "You must pass an ARRAY ref of superclasses"
 257             if exists $options{superclasses};
 258
 259     (ref $options{attributes} eq 'ARRAY')
 260         || confess "You must pass an ARRAY ref of attributes"
 261             if exists $options{attributes};
 262
 263     (ref $options{methods} eq 'HASH')
 264         || confess "You must pass a HASH ref of methods"
 265             if exists $options{methods};
 266
 267     do {
 268         ( defined $package_name && $package_name )
 269           || confess "You must pass a package name";
 270
 271         my $code = "package $package_name;";
 272         $code .= "\$$package_name\:\:VERSION = '" . $options{version} . "';"
 273           if exists $options{version};
 274         $code .= "\$$package_name\:\:AUTHORITY = '" . $options{authority} . "';"
 275           if exists $options{authority};
 276
 277         eval $code;
 278         confess "creation of $package_name failed : $@" if $@;
 279     };
 280
 281     my %initialize_options = %options;
 282     delete @initialize_options{qw(
 283         package
 284         superclasses
 285         attributes
 286         methods
 287         version
 288         authority
 289     )};
 290     my $meta = $self->initialize( $package_name => %initialize_options );
 291
 292     # FIXME totally lame
 293     $meta->add_method('meta' => sub {
 294         $self->initialize(ref($_[0]) || $_[0]);
 295     });
 296
 297     $meta->superclasses(@{$options{superclasses}})
 298         if exists $options{superclasses};
 299     # NOTE:
 300     # process attributes first, so that they can
 301     # install accessors, but locally defined methods
 302     # can then overwrite them. It is maybe a little odd, but
 303     # I think this should be the order of things.
 304     if (exists $options{attributes}) {
 305         foreach my $attr (@{$options{attributes}}) {
 306             Mouse::Meta::Attribute->create($meta, $attr->{name}, %$attr);
 307         }
 308     }
 309     if (exists $options{methods}) {
 310         foreach my $method_name (keys %{$options{methods}}) {
 311             $meta->add_method($method_name, $options{methods}->{$method_name});
 312         }
 313     }
 314     return $meta;
 315 }
 316
 317 {
 318     my $ANON_CLASS_SERIAL = 0;
 319     my $ANON_CLASS_PREFIX = 'Mouse::Meta::Class::__ANON__::SERIAL::';
 320     sub create_anon_class {
 321         my ( $class, %options ) = @_;
 322         my $package_name = $ANON_CLASS_PREFIX . ++$ANON_CLASS_SERIAL;
 323         return $class->create( $package_name, %options );
 324     }
 325 }
 326
 327 1;
 328
 329 __END__
 330
 331 =head1 NAME
 332
 333 Mouse::Meta::Class - hook into the Mouse MOP
 334
 335 =head1 METHODS
 336
 337 =head2 initialize ClassName -> Mouse::Meta::Class
 338
 339 Finds or creates a Mouse::Meta::Class instance for the given ClassName. Only
 340 one instance should exist for a given class.
 341
 342 =head2 new %args -> Mouse::Meta::Class
 343
 344 Creates a new Mouse::Meta::Class. Don't call this directly.
 345
 346 =head2 name -> ClassName
 347
 348 Returns the name of the owner class.
 349
 350 =head2 superclasses -> [ClassName]
 351
 352 Gets (or sets) the list of superclasses of the owner class.
 353
 354 =head2 add_attribute Mouse::Meta::Attribute
 355
 356 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 357 class.
 358
 359 =head2 compute_all_applicable_attributes -> (Mouse::Meta::Attribute)
 360
 361 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 362 this class and its superclasses.
 363
 364 =head2 get_attribute_map -> { name => Mouse::Meta::Attribute }
 365
 366 Returns a mapping of attribute names to their corresponding
 367 L<Mouse::Meta::Attribute> objects.
 368
 369 =head2 has_attribute Name -> Bool
 370
 371 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 372
 373 =head2 get_attribute Name -> Mouse::Meta::Attribute | undef
 374
 375 Returns the L<Mouse::Meta::Attribute> with the given name.
 376
 377 =head2 linearized_isa -> [ClassNames]
 378
 379 Returns the list of classes in method dispatch order, with duplicates removed.
 380
 381 =head2 clone_object Instance -> Instance
 382
 383 Clones the given C<Instance> which must be an instance governed by this
 384 metaclass.
 385
 386 =head2 clone_instance Instance, Parameters -> Instance
 387
 388 Clones the given C<Instance> and sets any additional parameters.
 389
 390 =cut
 391