lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use strict;
   3 use warnings;
   4
   5 use Mouse::Meta::Method::Constructor;
   6 use Mouse::Meta::Method::Destructor;
   7 use Scalar::Util qw/blessed/;
   8 use Mouse::Util qw/get_linear_isa/;
   9 use Carp 'confess';
  10
  11 do {
  12     my %METACLASS_CACHE;
  13
  14     # because Mouse doesn't introspect existing classes, we're forced to
  15     # only pay attention to other Mouse classes
  16     sub _metaclass_cache {
  17         my $class = shift;
  18         my $name  = shift;
  19         return $METACLASS_CACHE{$name};
  20     }
  21
  22     sub initialize {
  23         my $class = shift;
  24         my $name  = shift;
  25         $METACLASS_CACHE{$name} = $class->new(name => $name)
  26             if !exists($METACLASS_CACHE{$name});
  27         return $METACLASS_CACHE{$name};
  28     }
  29 };
  30
  31 sub new {
  32     my $class = shift;
  33     my %args  = @_;
  34
  35     $args{attributes} = {};
  36     $args{superclasses} = do {
  37         no strict 'refs';
  38         \@{ $args{name} . '::ISA' };
  39     };
  40     $args{roles} ||= [];
  41
  42     bless \%args, $class;
  43 }
  44
  45 sub name { $_[0]->{name} }
  46
  47 sub superclasses {
  48     my $self = shift;
  49
  50     if (@_) {
  51         Mouse::load_class($_) for @_;
  52         @{ $self->{superclasses} } = @_;
  53     }
  54
  55     @{ $self->{superclasses} };
  56 }
  57
  58 sub add_method {
  59     my $self = shift;
  60     my $name = shift;
  61     my $code = shift;
  62
  63     my $pkg = $self->name;
  64
  65     no strict 'refs';
  66     no warnings 'redefine';
  67     $self->{'methods'}->{$name}++; # Moose stores meta object here.
  68     *{ $pkg . '::' . $name } = $code;
  69 }
  70
  71 # copied from Class::Inspector
  72 sub get_method_list {
  73     my $self = shift;
  74     my $name = $self->name;
  75
  76     no strict 'refs';
  77     # Get all the CODE symbol table entries
  78     my @functions =
  79       grep !/^(?:has|with|around|before|after|blessed|extends|confess)$/,
  80       grep { defined &{"${name}::$_"} }
  81       keys %{"${name}::"};
  82     push @functions, keys %{$self->{'methods'}->{$name}};
  83     wantarray ? @functions : \@functions;
  84 }
  85
  86 sub add_attribute {
  87     my $self = shift;
  88     my $attr = shift;
  89
  90     $self->{'attributes'}{$attr->name} = $attr;
  91 }
  92
  93 sub compute_all_applicable_attributes {
  94     my $self = shift;
  95     my (@attr, %seen);
  96
  97     for my $class ($self->linearized_isa) {
  98         my $meta = $self->_metaclass_cache($class)
  99             or next;
 100
 101         for my $name (keys %{ $meta->get_attribute_map }) {
 102             next if $seen{$name}++;
 103             push @attr, $meta->get_attribute($name);
 104         }
 105     }
 106
 107     return @attr;
 108 }
 109
 110 sub get_attribute_map { $_[0]->{attributes} }
 111 sub has_attribute     { exists $_[0]->{attributes}->{$_[1]} }
 112 sub get_attribute     { $_[0]->{attributes}->{$_[1]} }
 113
 114 sub linearized_isa { @{ get_linear_isa($_[0]->name) } }
 115
 116 sub clone_object {
 117     my $class    = shift;
 118     my $instance = shift;
 119
 120     (blessed($instance) && $instance->isa($class->name))
 121         || confess "You must pass an instance of the metaclass (" . $class->name . "), not ($instance)";
 122
 123     $class->clone_instance($instance, @_);
 124 }
 125
 126 sub clone_instance {
 127     my ($class, $instance, %params) = @_;
 128
 129     (blessed($instance))
 130         || confess "You can only clone instances, ($instance) is not a blessed instance";
 131
 132     my $clone = bless { %$instance }, ref $instance;
 133
 134     foreach my $attr ($class->compute_all_applicable_attributes()) {
 135         if ( defined( my $init_arg = $attr->init_arg ) ) {
 136             if (exists $params{$init_arg}) {
 137                 $clone->{ $attr->name } = $params{$init_arg};
 138             }
 139         }
 140     }
 141
 142     return $clone;
 143
 144 }
 145
 146 sub make_immutable {
 147     my $self = shift;
 148     my %args = @_;
 149     my $name = $self->name;
 150     $self->{is_immutable}++;
 151     $self->add_method('new' => Mouse::Meta::Method::Constructor->generate_constructor_method_inline( $self ));
 152     if ($args{inline_destructor}) {
 153         $self->add_method('DESTROY' => Mouse::Meta::Method::Destructor->generate_destructor_method_inline( $self ));
 154     }
 155 }
 156
 157 sub make_mutable { confess "Mouse does not currently support 'make_mutable'" }
 158
 159 sub is_immutable { $_[0]->{is_immutable} }
 160
 161 sub attribute_metaclass { "Mouse::Meta::Class" }
 162
 163 sub _install_fast_modifier {
 164     my $self     = shift;
 165     my $into     = shift;
 166     my $type     = shift;
 167     my $modifier = pop;
 168
 169     foreach my $name (@_) {
 170         my $method = Data::Util::get_code_ref( $into, $name );
 171
 172         if ( !$method || !Data::Util::subroutine_modifier($method) ) {
 173
 174             unless ($method) {
 175                 $method = $into->can($name)
 176                     or confess "The method '$name' is not found in the inheritance hierarchy for class $into";
 177             }
 178             $method = Data::Util::modify_subroutine( $method,
 179                 $type => [$modifier] );
 180
 181             no warnings 'redefine';
 182             Data::Util::install_subroutine( $into, $name => $method );
 183         }
 184         else {
 185             Data::Util::subroutine_modifier( $method, $type => $modifier );
 186         }
 187     }
 188     return;
 189 }
 190
 191 sub _install_modifier {
 192     my ( $self, $into, $type, $name, $code ) = @_;
 193     if (eval "require Data::Util; 1") {
 194         $self->_install_fast_modifier(
 195             $into,
 196             $type,
 197             $name,
 198             $code
 199         );
 200     }
 201     else {
 202         require Class::Method::Modifiers;
 203         Class::Method::Modifiers::_install_modifier(
 204             $into,
 205             $type,
 206             $name,
 207             $code
 208         );
 209     }
 210 }
 211
 212 sub add_before_method_modifier {
 213     my ( $self, $name, $code ) = @_;
 214     $self->_install_modifier( $self->name, 'before', $name, $code );
 215 }
 216
 217 sub add_around_method_modifier {
 218     my ( $self, $name, $code ) = @_;
 219     $self->_install_modifier( $self->name, 'around', $name, $code );
 220 }
 221
 222 sub add_after_method_modifier {
 223     my ( $self, $name, $code ) = @_;
 224     $self->_install_modifier( $self->name, 'after', $name, $code );
 225 }
 226
 227 sub roles { $_[0]->{roles} }
 228
 229 sub does_role {
 230     my ($self, $role_name) = @_;
 231
 232     (defined $role_name)
 233         || confess "You must supply a role name to look for";
 234
 235     for my $role (@{ $self->{roles} }) {
 236         return 1 if $role->name eq $role_name;
 237     }
 238
 239     return 0;
 240 }
 241
 242 sub create {
 243     my ($self, $package_name, %options) = @_;
 244
 245     (ref $options{superclasses} eq 'ARRAY')
 246         || confess "You must pass an ARRAY ref of superclasses"
 247             if exists $options{superclasses};
 248
 249     (ref $options{attributes} eq 'ARRAY')
 250         || confess "You must pass an ARRAY ref of attributes"
 251             if exists $options{attributes};
 252
 253     (ref $options{methods} eq 'HASH')
 254         || confess "You must pass a HASH ref of methods"
 255             if exists $options{methods};
 256
 257     do {
 258         ( defined $package_name && $package_name )
 259           || confess "You must pass a package name";
 260
 261         my $code = "package $package_name;";
 262         $code .= "\$$package_name\:\:VERSION = '" . $options{version} . "';"
 263           if exists $options{version};
 264         $code .= "\$$package_name\:\:AUTHORITY = '" . $options{authority} . "';"
 265           if exists $options{authority};
 266
 267         eval $code;
 268         confess "creation of $package_name failed : $@" if $@;
 269     };
 270
 271     my %initialize_options = %options;
 272     delete @initialize_options{qw(
 273         package
 274         superclasses
 275         attributes
 276         methods
 277         version
 278         authority
 279     )};
 280     my $meta = $self->initialize( $package_name => %initialize_options );
 281
 282     # FIXME totally lame
 283     $meta->add_method('meta' => sub {
 284         $self->initialize(ref($_[0]) || $_[0]);
 285     });
 286
 287     $meta->superclasses(@{$options{superclasses}})
 288         if exists $options{superclasses};
 289     # NOTE:
 290     # process attributes first, so that they can
 291     # install accessors, but locally defined methods
 292     # can then overwrite them. It is maybe a little odd, but
 293     # I think this should be the order of things.
 294     if (exists $options{attributes}) {
 295         foreach my $attr (@{$options{attributes}}) {
 296             Mouse::Meta::Attribute->create($meta, $attr->{name}, %$attr);
 297         }
 298     }
 299     if (exists $options{methods}) {
 300         foreach my $method_name (keys %{$options{methods}}) {
 301             $meta->add_method($method_name, $options{methods}->{$method_name});
 302         }
 303     }
 304     return $meta;
 305 }
 306
 307 {
 308     my $ANON_CLASS_SERIAL = 0;
 309     my $ANON_CLASS_PREFIX = 'Mouse::Meta::Class::__ANON__::SERIAL::';
 310     sub create_anon_class {
 311         my ( $class, %options ) = @_;
 312         my $package_name = $ANON_CLASS_PREFIX . ++$ANON_CLASS_SERIAL;
 313         return $class->create( $package_name, %options );
 314     }
 315 }
 316
 317 1;
 318
 319 __END__
 320
 321 =head1 NAME
 322
 323 Mouse::Meta::Class - hook into the Mouse MOP
 324
 325 =head1 METHODS
 326
 327 =head2 initialize ClassName -> Mouse::Meta::Class
 328
 329 Finds or creates a Mouse::Meta::Class instance for the given ClassName. Only
 330 one instance should exist for a given class.
 331
 332 =head2 new %args -> Mouse::Meta::Class
 333
 334 Creates a new Mouse::Meta::Class. Don't call this directly.
 335
 336 =head2 name -> ClassName
 337
 338 Returns the name of the owner class.
 339
 340 =head2 superclasses -> [ClassName]
 341
 342 Gets (or sets) the list of superclasses of the owner class.
 343
 344 =head2 add_attribute Mouse::Meta::Attribute
 345
 346 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 347 class.
 348
 349 =head2 compute_all_applicable_attributes -> (Mouse::Meta::Attribute)
 350
 351 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 352 this class and its superclasses.
 353
 354 =head2 get_attribute_map -> { name => Mouse::Meta::Attribute }
 355
 356 Returns a mapping of attribute names to their corresponding
 357 L<Mouse::Meta::Attribute> objects.
 358
 359 =head2 has_attribute Name -> Bool
 360
 361 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 362
 363 =head2 get_attribute Name -> Mouse::Meta::Attribute | undef
 364
 365 Returns the L<Mouse::Meta::Attribute> with the given name.
 366
 367 =head2 linearized_isa -> [ClassNames]
 368
 369 Returns the list of classes in method dispatch order, with duplicates removed.
 370
 371 =head2 clone_object Instance -> Instance
 372
 373 Clones the given C<Instance> which must be an instance governed by this
 374 metaclass.
 375
 376 =head2 clone_instance Instance, Parameters -> Instance
 377
 378 Clones the given C<Instance> and sets any additional parameters.
 379
 380 =cut
 381