lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use strict;
   3 use warnings;
   4
   5 use Mouse::Meta::Method::Constructor;
   6 use Mouse::Meta::Method::Destructor;
   7 use Scalar::Util qw/blessed/;
   8 use Mouse::Util qw/get_linear_isa/;
   9 use Carp 'confess';
  10
  11 do {
  12     my %METACLASS_CACHE;
  13
  14     # because Mouse doesn't introspect existing classes, we're forced to
  15     # only pay attention to other Mouse classes
  16     sub _metaclass_cache {
  17         my $class = shift;
  18         my $name  = shift;
  19         return $METACLASS_CACHE{$name};
  20     }
  21
  22     sub initialize {
  23         my $class = shift;
  24         my $name  = shift;
  25         $METACLASS_CACHE{$name} = $class->new(name => $name)
  26             if !exists($METACLASS_CACHE{$name});
  27         return $METACLASS_CACHE{$name};
  28     }
  29 };
  30
  31 sub new {
  32     my $class = shift;
  33     my %args  = @_;
  34
  35     $args{attributes} = {};
  36     $args{superclasses} = do {
  37         no strict 'refs';
  38         \@{ $args{name} . '::ISA' };
  39     };
  40     $args{roles} ||= [];
  41
  42     bless \%args, $class;
  43 }
  44
  45 sub name { $_[0]->{name} }
  46
  47 sub superclasses {
  48     my $self = shift;
  49
  50     if (@_) {
  51         Mouse::load_class($_) for @_;
  52         @{ $self->{superclasses} } = @_;
  53     }
  54
  55     @{ $self->{superclasses} };
  56 }
  57
  58 sub add_method {
  59     my $self = shift;
  60     my $name = shift;
  61     my $code = shift;
  62
  63     my $pkg = $self->name;
  64
  65     no strict 'refs';
  66     no warnings 'redefine';
  67     $self->{'methods'}->{$name}++; # Moose stores meta object here.
  68     *{ $pkg . '::' . $name } = $code;
  69 }
  70
  71 # copied from Class::Inspector
  72 sub get_method_list {
  73     my $self = shift;
  74     my $name = $self->name;
  75
  76     no strict 'refs';
  77     # Get all the CODE symbol table entries
  78     my @functions =
  79       grep !/^(?:has|with|around|before|after|blessed|extends|confess)$/,
  80       grep { defined &{"${name}::$_"} }
  81       keys %{"${name}::"};
  82     push @functions, keys %{$self->{'methods'}->{$name}};
  83     wantarray ? @functions : \@functions;
  84 }
  85
  86 sub add_attribute {
  87     my $self = shift;
  88     my $attr = shift;
  89
  90     $self->{'attributes'}{$attr->name} = $attr;
  91 }
  92
  93 sub compute_all_applicable_attributes {
  94     my $self = shift;
  95     my (@attr, %seen);
  96
  97     for my $class ($self->linearized_isa) {
  98         my $meta = $self->_metaclass_cache($class)
  99             or next;
 100
 101         for my $name (keys %{ $meta->get_attribute_map }) {
 102             next if $seen{$name}++;
 103             push @attr, $meta->get_attribute($name);
 104         }
 105     }
 106
 107     return @attr;
 108 }
 109
 110 sub get_attribute_map { $_[0]->{attributes} }
 111 sub has_attribute     { exists $_[0]->{attributes}->{$_[1]} }
 112 sub get_attribute     { $_[0]->{attributes}->{$_[1]} }
 113
 114 sub linearized_isa { @{ get_linear_isa($_[0]->name) } }
 115
 116 sub clone_object {
 117     my $class    = shift;
 118     my $instance = shift;
 119
 120     (blessed($instance) && $instance->isa($class->name))
 121         || confess "You must pass an instance of the metaclass (" . $class->name . "), not ($instance)";
 122
 123     $class->clone_instance($instance, @_);
 124 }
 125
 126 sub clone_instance {
 127     my ($class, $instance, %params) = @_;
 128
 129     (blessed($instance))
 130         || confess "You can only clone instances, ($instance) is not a blessed instance";
 131
 132     my $clone = bless { %$instance }, ref $instance;
 133
 134     foreach my $attr ($class->compute_all_applicable_attributes()) {
 135         if ( defined( my $init_arg = $attr->init_arg ) ) {
 136             if (exists $params{$init_arg}) {
 137                 $clone->{ $attr->name } = $params{$init_arg};
 138             }
 139         }
 140     }
 141
 142     return $clone;
 143
 144 }
 145
 146 sub make_immutable {
 147     my $self = shift;
 148     my %args = @_;
 149     my $name = $self->name;
 150     $self->{is_immutable}++;
 151     $self->add_method('new' => Mouse::Meta::Method::Constructor->generate_constructor_method_inline( $self ));
 152     if ($args{inline_destructor}) {
 153         $self->add_method('DESTROY' => Mouse::Meta::Method::Destructor->generate_destructor_method_inline( $self ));
 154     }
 155 }
 156
 157 sub make_mutable { confess "Mouse does not currently support 'make_mutable'" }
 158
 159 sub is_immutable { $_[0]->{is_immutable} }
 160
 161 sub attribute_metaclass { "Mouse::Meta::Class" }
 162
 163 sub add_before_method_modifier {
 164     my ($self, $name, $code) = @_;
 165     require Class::Method::Modifiers;
 166     Class::Method::Modifiers::_install_modifier(
 167         $self->name,
 168         'before',
 169         $name,
 170         $code,
 171     );
 172 }
 173
 174 sub add_around_method_modifier {
 175     my ($self, $name, $code) = @_;
 176     require Class::Method::Modifiers;
 177     Class::Method::Modifiers::_install_modifier(
 178         $self->name,
 179         'around',
 180         $name,
 181         $code,
 182     );
 183 }
 184
 185 sub add_after_method_modifier {
 186     my ($self, $name, $code) = @_;
 187     require Class::Method::Modifiers;
 188     Class::Method::Modifiers::_install_modifier(
 189         $self->name,
 190         'after',
 191         $name,
 192         $code,
 193     );
 194 }
 195
 196 sub roles { $_[0]->{roles} }
 197
 198 sub does_role {
 199     my ($self, $role_name) = @_;
 200
 201     (defined $role_name)
 202         || confess "You must supply a role name to look for";
 203
 204     for my $role (@{ $self->{roles} }) {
 205         return 1 if $role->name eq $role_name;
 206     }
 207
 208     return 0;
 209 }
 210
 211 sub create {
 212     my ($self, $package_name, %options) = @_;
 213
 214     (ref $options{superclasses} eq 'ARRAY')
 215         || confess "You must pass an ARRAY ref of superclasses"
 216             if exists $options{superclasses};
 217
 218     (ref $options{attributes} eq 'ARRAY')
 219         || confess "You must pass an ARRAY ref of attributes"
 220             if exists $options{attributes};
 221
 222     (ref $options{methods} eq 'HASH')
 223         || confess "You must pass a HASH ref of methods"
 224             if exists $options{methods};
 225
 226     do {
 227         ( defined $package_name && $package_name )
 228           || confess "You must pass a package name";
 229
 230         my $code = "package $package_name;";
 231         $code .= "\$$package_name\:\:VERSION = '" . $options{version} . "';"
 232           if exists $options{version};
 233         $code .= "\$$package_name\:\:AUTHORITY = '" . $options{authority} . "';"
 234           if exists $options{authority};
 235
 236         eval $code;
 237         confess "creation of $package_name failed : $@" if $@;
 238     };
 239
 240     my %initialize_options = %options;
 241     delete @initialize_options{qw(
 242         package
 243         superclasses
 244         attributes
 245         methods
 246         version
 247         authority
 248     )};
 249     my $meta = $self->initialize( $package_name => %initialize_options );
 250
 251     # FIXME totally lame
 252     $meta->add_method('meta' => sub {
 253         $self->initialize(ref($_[0]) || $_[0]);
 254     });
 255
 256     $meta->superclasses(@{$options{superclasses}})
 257         if exists $options{superclasses};
 258     # NOTE:
 259     # process attributes first, so that they can
 260     # install accessors, but locally defined methods
 261     # can then overwrite them. It is maybe a little odd, but
 262     # I think this should be the order of things.
 263     if (exists $options{attributes}) {
 264         foreach my $attr (@{$options{attributes}}) {
 265             Mouse::Meta::Attribute->create($meta, $attr->{name}, %$attr);
 266         }
 267     }
 268     if (exists $options{methods}) {
 269         foreach my $method_name (keys %{$options{methods}}) {
 270             $meta->add_method($method_name, $options{methods}->{$method_name});
 271         }
 272     }
 273     return $meta;
 274 }
 275
 276 {
 277     my $ANON_CLASS_SERIAL = 0;
 278     my $ANON_CLASS_PREFIX = 'Mouse::Meta::Class::__ANON__::SERIAL::';
 279     sub create_anon_class {
 280         my ( $class, %options ) = @_;
 281         my $package_name = $ANON_CLASS_PREFIX . ++$ANON_CLASS_SERIAL;
 282         return $class->create( $package_name, %options );
 283     }
 284 }
 285
 286 1;
 287
 288 __END__
 289
 290 =head1 NAME
 291
 292 Mouse::Meta::Class - hook into the Mouse MOP
 293
 294 =head1 METHODS
 295
 296 =head2 initialize ClassName -> Mouse::Meta::Class
 297
 298 Finds or creates a Mouse::Meta::Class instance for the given ClassName. Only
 299 one instance should exist for a given class.
 300
 301 =head2 new %args -> Mouse::Meta::Class
 302
 303 Creates a new Mouse::Meta::Class. Don't call this directly.
 304
 305 =head2 name -> ClassName
 306
 307 Returns the name of the owner class.
 308
 309 =head2 superclasses -> [ClassName]
 310
 311 Gets (or sets) the list of superclasses of the owner class.
 312
 313 =head2 add_attribute Mouse::Meta::Attribute
 314
 315 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 316 class.
 317
 318 =head2 compute_all_applicable_attributes -> (Mouse::Meta::Attribute)
 319
 320 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 321 this class and its superclasses.
 322
 323 =head2 get_attribute_map -> { name => Mouse::Meta::Attribute }
 324
 325 Returns a mapping of attribute names to their corresponding
 326 L<Mouse::Meta::Attribute> objects.
 327
 328 =head2 has_attribute Name -> Bool
 329
 330 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 331
 332 =head2 get_attribute Name -> Mouse::Meta::Attribute | undef
 333
 334 Returns the L<Mouse::Meta::Attribute> with the given name.
 335
 336 =head2 linearized_isa -> [ClassNames]
 337
 338 Returns the list of classes in method dispatch order, with duplicates removed.
 339
 340 =head2 clone_object Instance -> Instance
 341
 342 Clones the given C<Instance> which must be an instance governed by this
 343 metaclass.
 344
 345 =head2 clone_instance Instance, Parameters -> Instance
 346
 347 Clones the given C<Instance> and sets any additional parameters.
 348
 349 =cut
 350