lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use strict;
   3 use warnings;
   4
   5 use Mouse::Meta::Method::Constructor;
   6 use Mouse::Meta::Method::Destructor;
   7 use Scalar::Util qw/blessed/;
   8 use Mouse::Util qw/get_linear_isa/;
   9 use Carp 'confess';
  10
  11 do {
  12     my %METACLASS_CACHE;
  13
  14     # because Mouse doesn't introspect existing classes, we're forced to
  15     # only pay attention to other Mouse classes
  16     sub _metaclass_cache {
  17         my $class = shift;
  18         my $name  = shift;
  19         return $METACLASS_CACHE{$name};
  20     }
  21
  22     sub initialize {
  23         my $class = shift;
  24         my $name  = shift;
  25         $METACLASS_CACHE{$name} = $class->new(name => $name)
  26             if !exists($METACLASS_CACHE{$name});
  27         return $METACLASS_CACHE{$name};
  28     }
  29 };
  30
  31 sub new {
  32     my $class = shift;
  33     my %args  = @_;
  34
  35     $args{attributes} = {};
  36     $args{superclasses} = do {
  37         no strict 'refs';
  38         \@{ $args{name} . '::ISA' };
  39     };
  40     $args{roles} ||= [];
  41
  42     bless \%args, $class;
  43 }
  44
  45 sub name { $_[0]->{name} }
  46
  47 sub superclasses {
  48     my $self = shift;
  49
  50     if (@_) {
  51         Mouse::load_class($_) for @_;
  52         @{ $self->{superclasses} } = @_;
  53     }
  54
  55     @{ $self->{superclasses} };
  56 }
  57
  58 sub add_method {
  59     my $self = shift;
  60     my $name = shift;
  61     my $code = shift;
  62
  63     my $pkg = $self->name;
  64
  65     no strict 'refs';
  66     no warnings 'redefine';
  67     $self->{'methods'}->{$name}++; # Moose stores meta object here.
  68     *{ $pkg . '::' . $name } = $code;
  69 }
  70
  71 # copied from Class::Inspector
  72 sub get_method_list {
  73     my $self = shift;
  74     my $name = $self->name;
  75
  76     no strict 'refs';
  77     # Get all the CODE symbol table entries
  78     my @functions =
  79       grep !/^(?:has|with|around|before|after|blessed|extends|confess|override|super)$/,
  80       grep { defined &{"${name}::$_"} }
  81       keys %{"${name}::"};
  82     push @functions, keys %{$self->{'methods'}->{$name}};
  83     wantarray ? @functions : \@functions;
  84 }
  85
  86 sub add_attribute {
  87     my $self = shift;
  88     my $attr = shift;
  89
  90     $self->{'attributes'}{$attr->name} = $attr;
  91 }
  92
  93 sub compute_all_applicable_attributes {
  94     my $self = shift;
  95     my (@attr, %seen);
  96
  97     for my $class ($self->linearized_isa) {
  98         my $meta = $self->_metaclass_cache($class)
  99             or next;
 100
 101         for my $name (keys %{ $meta->get_attribute_map }) {
 102             next if $seen{$name}++;
 103             push @attr, $meta->get_attribute($name);
 104         }
 105     }
 106
 107     return @attr;
 108 }
 109
 110 sub get_attribute_map { $_[0]->{attributes} }
 111 sub has_attribute     { exists $_[0]->{attributes}->{$_[1]} }
 112 sub get_attribute     { $_[0]->{attributes}->{$_[1]} }
 113
 114 sub linearized_isa { @{ get_linear_isa($_[0]->name) } }
 115
 116 sub clone_object {
 117     my $class    = shift;
 118     my $instance = shift;
 119
 120     (blessed($instance) && $instance->isa($class->name))
 121         || confess "You must pass an instance of the metaclass (" . $class->name . "), not ($instance)";
 122
 123     $class->clone_instance($instance, @_);
 124 }
 125
 126 sub clone_instance {
 127     my ($class, $instance, %params) = @_;
 128
 129     (blessed($instance))
 130         || confess "You can only clone instances, ($instance) is not a blessed instance";
 131
 132     my $clone = bless { %$instance }, ref $instance;
 133
 134     foreach my $attr ($class->compute_all_applicable_attributes()) {
 135         if ( defined( my $init_arg = $attr->init_arg ) ) {
 136             if (exists $params{$init_arg}) {
 137                 $clone->{ $attr->name } = $params{$init_arg};
 138             }
 139         }
 140     }
 141
 142     return $clone;
 143
 144 }
 145
 146 sub make_immutable {
 147     my $self = shift;
 148     my %args = (
 149         inline_constructor => 1,
 150         @_,
 151     );
 152
 153     my $name = $self->name;
 154     $self->{is_immutable}++;
 155
 156     if ($args{inline_constructor}) {
 157         $self->add_method('new' => Mouse::Meta::Method::Constructor->generate_constructor_method_inline( $self ));
 158     }
 159
 160     if ($args{inline_destructor}) {
 161         $self->add_method('DESTROY' => Mouse::Meta::Method::Destructor->generate_destructor_method_inline( $self ));
 162     }
 163 }
 164
 165 sub make_mutable { confess "Mouse does not currently support 'make_mutable'" }
 166
 167 sub is_immutable { $_[0]->{is_immutable} }
 168
 169 sub attribute_metaclass { "Mouse::Meta::Class" }
 170
 171 sub _install_modifier {
 172     my ( $self, $into, $type, $name, $code ) = @_;
 173     if (eval "require Class::Method::Modifiers::Fast; 1") {
 174         Class::Method::Modifiers::Fast::_install_modifier(
 175             $into,
 176             $type,
 177             $name,
 178             $code
 179         );
 180     }
 181     else {
 182         require Class::Method::Modifiers;
 183         Class::Method::Modifiers::_install_modifier(
 184             $into,
 185             $type,
 186             $name,
 187             $code
 188         );
 189     }
 190 }
 191
 192 sub add_before_method_modifier {
 193     my ( $self, $name, $code ) = @_;
 194     $self->_install_modifier( $self->name, 'before', $name, $code );
 195 }
 196
 197 sub add_around_method_modifier {
 198     my ( $self, $name, $code ) = @_;
 199     $self->_install_modifier( $self->name, 'around', $name, $code );
 200 }
 201
 202 sub add_after_method_modifier {
 203     my ( $self, $name, $code ) = @_;
 204     $self->_install_modifier( $self->name, 'after', $name, $code );
 205 }
 206
 207 sub roles { $_[0]->{roles} }
 208
 209 sub does_role {
 210     my ($self, $role_name) = @_;
 211
 212     (defined $role_name)
 213         || confess "You must supply a role name to look for";
 214
 215     for my $role (@{ $self->{roles} }) {
 216         return 1 if $role->name eq $role_name;
 217     }
 218
 219     return 0;
 220 }
 221
 222 sub create {
 223     my ($self, $package_name, %options) = @_;
 224
 225     (ref $options{superclasses} eq 'ARRAY')
 226         || confess "You must pass an ARRAY ref of superclasses"
 227             if exists $options{superclasses};
 228
 229     (ref $options{attributes} eq 'ARRAY')
 230         || confess "You must pass an ARRAY ref of attributes"
 231             if exists $options{attributes};
 232
 233     (ref $options{methods} eq 'HASH')
 234         || confess "You must pass a HASH ref of methods"
 235             if exists $options{methods};
 236
 237     do {
 238         ( defined $package_name && $package_name )
 239           || confess "You must pass a package name";
 240
 241         my $code = "package $package_name;";
 242         $code .= "\$$package_name\:\:VERSION = '" . $options{version} . "';"
 243           if exists $options{version};
 244         $code .= "\$$package_name\:\:AUTHORITY = '" . $options{authority} . "';"
 245           if exists $options{authority};
 246
 247         eval $code;
 248         confess "creation of $package_name failed : $@" if $@;
 249     };
 250
 251     my %initialize_options = %options;
 252     delete @initialize_options{qw(
 253         package
 254         superclasses
 255         attributes
 256         methods
 257         version
 258         authority
 259     )};
 260     my $meta = $self->initialize( $package_name => %initialize_options );
 261
 262     # FIXME totally lame
 263     $meta->add_method('meta' => sub {
 264         $self->initialize(ref($_[0]) || $_[0]);
 265     });
 266
 267     $meta->superclasses(@{$options{superclasses}})
 268         if exists $options{superclasses};
 269     # NOTE:
 270     # process attributes first, so that they can
 271     # install accessors, but locally defined methods
 272     # can then overwrite them. It is maybe a little odd, but
 273     # I think this should be the order of things.
 274     if (exists $options{attributes}) {
 275         foreach my $attr (@{$options{attributes}}) {
 276             Mouse::Meta::Attribute->create($meta, $attr->{name}, %$attr);
 277         }
 278     }
 279     if (exists $options{methods}) {
 280         foreach my $method_name (keys %{$options{methods}}) {
 281             $meta->add_method($method_name, $options{methods}->{$method_name});
 282         }
 283     }
 284     return $meta;
 285 }
 286
 287 {
 288     my $ANON_CLASS_SERIAL = 0;
 289     my $ANON_CLASS_PREFIX = 'Mouse::Meta::Class::__ANON__::SERIAL::';
 290     sub create_anon_class {
 291         my ( $class, %options ) = @_;
 292         my $package_name = $ANON_CLASS_PREFIX . ++$ANON_CLASS_SERIAL;
 293         return $class->create( $package_name, %options );
 294     }
 295 }
 296
 297 1;
 298
 299 __END__
 300
 301 =head1 NAME
 302
 303 Mouse::Meta::Class - hook into the Mouse MOP
 304
 305 =head1 METHODS
 306
 307 =head2 initialize ClassName -> Mouse::Meta::Class
 308
 309 Finds or creates a Mouse::Meta::Class instance for the given ClassName. Only
 310 one instance should exist for a given class.
 311
 312 =head2 new %args -> Mouse::Meta::Class
 313
 314 Creates a new Mouse::Meta::Class. Don't call this directly.
 315
 316 =head2 name -> ClassName
 317
 318 Returns the name of the owner class.
 319
 320 =head2 superclasses -> [ClassName]
 321
 322 Gets (or sets) the list of superclasses of the owner class.
 323
 324 =head2 add_attribute Mouse::Meta::Attribute
 325
 326 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 327 class.
 328
 329 =head2 compute_all_applicable_attributes -> (Mouse::Meta::Attribute)
 330
 331 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 332 this class and its superclasses.
 333
 334 =head2 get_attribute_map -> { name => Mouse::Meta::Attribute }
 335
 336 Returns a mapping of attribute names to their corresponding
 337 L<Mouse::Meta::Attribute> objects.
 338
 339 =head2 has_attribute Name -> Bool
 340
 341 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 342
 343 =head2 get_attribute Name -> Mouse::Meta::Attribute | undef
 344
 345 Returns the L<Mouse::Meta::Attribute> with the given name.
 346
 347 =head2 linearized_isa -> [ClassNames]
 348
 349 Returns the list of classes in method dispatch order, with duplicates removed.
 350
 351 =head2 clone_object Instance -> Instance
 352
 353 Clones the given C<Instance> which must be an instance governed by this
 354 metaclass.
 355
 356 =head2 clone_instance Instance, Parameters -> Instance
 357
 358 Clones the given C<Instance> and sets any additional parameters.
 359
 360 =cut
 361