lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use strict;
   3 use warnings;
   4
   5 use Scalar::Util qw/blessed weaken/;
   6
   7 use Mouse::Util qw/:meta get_linear_isa not_supported/;
   8
   9 use Mouse::Meta::Method::Constructor;
  10 use Mouse::Meta::Method::Destructor;
  11 use Mouse::Meta::Module;
  12 our @ISA = qw(Mouse::Meta::Module);
  13
  14 sub method_metaclass(){ 'Mouse::Meta::Method' } # required for get_method()
  15
  16 sub _construct_meta {
  17     my($class, %args) = @_;
  18
  19     $args{attributes} ||= {};
  20     $args{methods}    ||= {};
  21     $args{roles}      ||= [];
  22
  23     $args{superclasses} = do {
  24         no strict 'refs';
  25         \@{ $args{package} . '::ISA' };
  26     };
  27
  28     #return Mouse::Meta::Class->initialize($class)->new_object(%args)
  29     #    if $class ne __PACKAGE__;
  30
  31     return bless \%args, ref($class) || $class;
  32 }
  33
  34 sub create_anon_class{
  35     my $self = shift;
  36     return $self->create(undef, @_);
  37 }
  38
  39 sub is_anon_class{
  40     return exists $_[0]->{anon_serial_id};
  41 }
  42
  43 sub roles { $_[0]->{roles} }
  44
  45 sub superclasses {
  46     my $self = shift;
  47
  48     if (@_) {
  49         Mouse::load_class($_) for @_;
  50         @{ $self->{superclasses} } = @_;
  51     }
  52
  53     return @{ $self->{superclasses} };
  54 }
  55
  56 sub find_method_by_name{
  57     my($self, $method_name) = @_;
  58     defined($method_name)
  59         or $self->throw_error('You must define a method name to find');
  60     foreach my $class( $self->linearized_isa ){
  61         my $method = $self->initialize($class)->get_method($method_name);
  62         return $method if defined $method;
  63     }
  64     return undef;
  65 }
  66
  67 sub get_all_methods {
  68     my($self) = @_;
  69     return map{ $self->find_method_by_name($_) } $self->get_all_method_names;
  70 }
  71
  72 sub get_all_method_names {
  73     my $self = shift;
  74     my %uniq;
  75     return grep { $uniq{$_}++ == 0 }
  76             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
  77             $self->linearized_isa;
  78 }
  79
  80 sub add_attribute {
  81     my $self = shift;
  82
  83     my($attr, $name);
  84
  85     if(blessed $_[0]){
  86         $attr = $_[0];
  87
  88         $attr->isa('Mouse::Meta::Attribute')
  89             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
  90
  91         $name = $attr->name;
  92     }
  93     else{
  94         # _process_attribute
  95         $name = shift;
  96
  97         my %args = (@_ == 1) ? %{$_[0]} : @_;
  98
  99         defined($name)
 100             or $self->throw_error('You must provide a name for the attribute');
 101
 102         if ($name =~ s/^\+//) { # inherited attributes
 103             my $inherited_attr;
 104
 105             foreach my $class($self->linearized_isa){
 106                 my $meta = Mouse::Util::get_metaclass_by_name($class) or next;
 107                 $inherited_attr = $meta->get_attribute($name) and last;
 108             }
 109
 110             defined($inherited_attr)
 111                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 112
 113             $attr = $inherited_attr->clone_and_inherit_options($name, \%args);
 114         }
 115         else{
 116             my($attribute_class, @traits) = Mouse::Meta::Attribute->interpolate_class($name, \%args);
 117             $args{traits} = \@traits if @traits;
 118
 119             $attr = $attribute_class->new($name, \%args);
 120         }
 121     }
 122
 123     weaken( $attr->{associated_class} = $self );
 124
 125     $self->{attributes}{$attr->name} = $attr;
 126     $attr->install_accessors();
 127
 128     if(_MOUSE_VERBOSE && !$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 129         Carp::cluck(qq{Attribute (}.$attr->name.qq{) of class }.$self->name.qq{ has no associated methods (did you mean to provide an "is" argument?)});
 130     }
 131     return $attr;
 132 }
 133
 134 sub compute_all_applicable_attributes {
 135     Carp::cluck('compute_all_applicable_attributes() has been deprecated');
 136     return shift->get_all_attributes(@_)
 137 }
 138
 139 sub get_all_attributes {
 140     my $self = shift;
 141     my (@attr, %seen);
 142
 143     for my $class ($self->linearized_isa) {
 144         my $meta = Mouse::Util::get_metaclass_by_name($class)
 145             or next;
 146
 147         for my $name ($meta->get_attribute_list) {
 148             next if $seen{$name}++;
 149             push @attr, $meta->get_attribute($name);
 150         }
 151     }
 152
 153     return @attr;
 154 }
 155
 156 sub linearized_isa { @{ get_linear_isa($_[0]->name) } }
 157
 158 sub new_object {
 159     my $self = shift;
 160     my %args = (@_ == 1 ? %{$_[0]} : @_);
 161
 162     my $instance = bless {}, $self->name;
 163
 164     $self->_initialize_instance($instance, \%args);
 165     return $instance;
 166 }
 167
 168 sub _initialize_instance{
 169     my($self, $instance, $args) = @_;
 170
 171     my @triggers_queue;
 172
 173     foreach my $attribute ($self->get_all_attributes) {
 174         my $from = $attribute->init_arg;
 175         my $key  = $attribute->name;
 176
 177         if (defined($from) && exists($args->{$from})) {
 178             $instance->{$key} = $attribute->_coerce_and_verify($args->{$from});
 179
 180             weaken($instance->{$key})
 181                 if ref($instance->{$key}) && $attribute->is_weak_ref;
 182
 183             if ($attribute->has_trigger) {
 184                 push @triggers_queue, [ $attribute->trigger, $instance->{$from} ];
 185             }
 186         }
 187         else {
 188             if ($attribute->has_default || $attribute->has_builder) {
 189                 unless ($attribute->is_lazy) {
 190                     my $default = $attribute->default;
 191                     my $builder = $attribute->builder;
 192                     my $value =   $builder                ? $instance->$builder()
 193                                 : ref($default) eq 'CODE' ? $instance->$default()
 194                                 :                           $default;
 195
 196                     # XXX: we cannot use $attribute->set_value() because it invokes triggers.
 197                     $instance->{$key} = $attribute->_coerce_and_verify($value, $instance);;
 198
 199                     weaken($instance->{$key})
 200                         if ref($instance->{$key}) && $attribute->is_weak_ref;
 201                 }
 202             }
 203             else {
 204                 if ($attribute->is_required) {
 205                     $self->throw_error("Attribute (".$attribute->name.") is required");
 206                 }
 207             }
 208         }
 209     }
 210
 211     foreach my $trigger_and_value(@triggers_queue){
 212         my($trigger, $value) = @{$trigger_and_value};
 213         $trigger->($instance, $value);
 214     }
 215
 216     if($self->is_anon_class){
 217         $instance->{__METACLASS__} = $self;
 218     }
 219
 220     return $instance;
 221 }
 222
 223 sub clone_object {
 224     my $class    = shift;
 225     my $instance = shift;
 226     my %params   = (@_ == 1) ? %{$_[0]} : @_;
 227
 228     (blessed($instance) && $instance->isa($class->name))
 229         || $class->throw_error("You must pass an instance of the metaclass (" . $class->name . "), not ($instance)");
 230
 231     my $clone = bless { %$instance }, ref $instance;
 232
 233     foreach my $attr ($class->get_all_attributes()) {
 234         if ( defined( my $init_arg = $attr->init_arg ) ) {
 235             if (exists $params{$init_arg}) {
 236                 $clone->{ $attr->name } = $params{$init_arg};
 237             }
 238         }
 239     }
 240
 241     return $clone;
 242 }
 243
 244 sub clone_instance {
 245     my ($class, $instance, %params) = @_;
 246
 247     Carp::cluck('clone_instance has been deprecated. Use clone_object instead')
 248         if _MOUSE_VERBOSE;
 249     return $class->clone_object($instance, %params);
 250 }
 251
 252 sub make_immutable {
 253     my $self = shift;
 254     my %args = (
 255         inline_constructor => 1,
 256         inline_destructor  => 1,
 257         @_,
 258     );
 259
 260     $self->{is_immutable}++;
 261
 262     if ($args{inline_constructor}) {
 263         $self->add_method('new' => Mouse::Meta::Method::Constructor->generate_constructor_method_inline( $self ));
 264     }
 265
 266     if ($args{inline_destructor}) {
 267         $self->add_method('DESTROY' => Mouse::Meta::Method::Destructor->generate_destructor_method_inline( $self ));
 268     }
 269
 270     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 271     # at the end of a source file.
 272     return 1;
 273 }
 274
 275 sub make_mutable { not_supported }
 276
 277 sub is_immutable {  $_[0]->{is_immutable} }
 278 sub is_mutable   { !$_[0]->{is_immutable} }
 279
 280 sub _install_modifier_pp{
 281     my( $self, $into, $type, $name, $code ) = @_;
 282
 283     my $original = $into->can($name)
 284         or $self->throw_error("The method '$name' is not found in the inheritance hierarchy for class $into");
 285
 286     my $modifier_table = $self->{modifiers}{$name};
 287
 288     if(!$modifier_table){
 289         my(@before, @after, @around, $cache, $modified);
 290
 291         $cache = $original;
 292
 293         $modified = sub {
 294             for my $c (@before) { $c->(@_) }
 295
 296             if(wantarray){ # list context
 297                 my @rval = $cache->(@_);
 298
 299                 for my $c(@after){ $c->(@_) }
 300                 return @rval;
 301             }
 302             elsif(defined wantarray){ # scalar context
 303                 my $rval = $cache->(@_);
 304
 305                 for my $c(@after){ $c->(@_) }
 306                 return $rval;
 307             }
 308             else{ # void context
 309                 $cache->(@_);
 310
 311                 for my $c(@after){ $c->(@_) }
 312                 return;
 313             }
 314         };
 315
 316         $self->{modifiers}{$name} = $modifier_table = {
 317             original => $original,
 318
 319             before   => \@before,
 320             after    => \@after,
 321             around   => \@around,
 322
 323             cache    => \$cache, # cache for around modifiers
 324         };
 325
 326         $self->add_method($name => $modified);
 327     }
 328
 329     if($type eq 'before'){
 330         unshift @{$modifier_table->{before}}, $code;
 331     }
 332     elsif($type eq 'after'){
 333         push @{$modifier_table->{after}}, $code;
 334     }
 335     else{ # around
 336         push @{$modifier_table->{around}}, $code;
 337
 338         my $next = ${ $modifier_table->{cache} };
 339         ${ $modifier_table->{cache} } = sub{ $code->($next, @_) };
 340     }
 341
 342     return;
 343 }
 344
 345 sub _install_modifier {
 346     my ( $self, $into, $type, $name, $code ) = @_;
 347
 348     # load Class::Method::Modifiers first
 349     my $no_cmm_fast = do{
 350         local $@;
 351         eval q{ require Class::Method::Modifiers::Fast };
 352         $@;
 353     };
 354
 355     my $impl;
 356     if($no_cmm_fast){
 357         $impl = \&_install_modifier_pp;
 358     }
 359     else{
 360         my $install_modifier = Class::Method::Modifiers::Fast->can('_install_modifier');
 361         $impl = sub {
 362             my ( $self, $into, $type, $name, $code ) = @_;
 363             $install_modifier->(
 364                 $into,
 365                 $type,
 366                 $name,
 367                 $code
 368             );
 369             $self->{methods}{$name}++; # register it to the method map
 370             return;
 371         };
 372     }
 373
 374     # replace this method itself :)
 375     {
 376         no warnings 'redefine';
 377         *_install_modifier = $impl;
 378     }
 379
 380     $self->$impl( $into, $type, $name, $code );
 381 }
 382
 383 sub add_before_method_modifier {
 384     my ( $self, $name, $code ) = @_;
 385     $self->_install_modifier( $self->name, 'before', $name, $code );
 386 }
 387
 388 sub add_around_method_modifier {
 389     my ( $self, $name, $code ) = @_;
 390     $self->_install_modifier( $self->name, 'around', $name, $code );
 391 }
 392
 393 sub add_after_method_modifier {
 394     my ( $self, $name, $code ) = @_;
 395     $self->_install_modifier( $self->name, 'after', $name, $code );
 396 }
 397
 398 sub add_override_method_modifier {
 399     my ($self, $name, $code) = @_;
 400
 401     my $package = $self->name;
 402
 403     my $body = $package->can($name)
 404         or $self->throw_error("You cannot override '$name' because it has no super method");
 405
 406     $self->add_method($name => sub { $code->($package, $body, @_) });
 407 }
 408
 409 sub does_role {
 410     my ($self, $role_name) = @_;
 411
 412     (defined $role_name)
 413         || $self->throw_error("You must supply a role name to look for");
 414
 415     for my $class ($self->linearized_isa) {
 416         my $meta = Mouse::Util::get_metaclass_by_name($class);
 417         next unless $meta && $meta->can('roles');
 418
 419         for my $role (@{ $meta->roles }) {
 420
 421             return 1 if $role->does_role($role_name);
 422         }
 423     }
 424
 425     return 0;
 426 }
 427
 428 1;
 429
 430 __END__
 431
 432 =head1 NAME
 433
 434 Mouse::Meta::Class - The Mouse class metaclass
 435
 436 =head1 METHODS
 437
 438 =head2 C<< initialize(ClassName) -> Mouse::Meta::Class >>
 439
 440 Finds or creates a C<Mouse::Meta::Class> instance for the given ClassName. Only
 441 one instance should exist for a given class.
 442
 443 =head2 C<< name -> ClassName >>
 444
 445 Returns the name of the owner class.
 446
 447 =head2 C<< superclasses -> ClassNames >> C<< superclass(ClassNames) >>
 448
 449 Gets (or sets) the list of superclasses of the owner class.
 450
 451 =head2 C<< add_method(name => CodeRef) >>
 452
 453 Adds a method to the owner class.
 454
 455 =head2 C<< has_method(name) -> Bool >>
 456
 457 Returns whether we have a method with the given name.
 458
 459 =head2 C<< get_method(name) -> Mouse::Meta::Method | undef >>
 460
 461 Returns a L<Mouse::Meta::Method> with the given name.
 462
 463 Note that you can also use C<< $metaclass->name->can($name) >> for a method body.
 464
 465 =head2 C<< get_method_list -> Names >>
 466
 467 Returns a list of method names which are defined in the local class.
 468 If you want a list of all applicable methods for a class, use the
 469 C<get_all_methods> method.
 470
 471 =head2 C<< get_all_methods -> (Mouse::Meta::Method) >>
 472
 473 Return the list of all L<Mouse::Meta::Method> instances associated with
 474 the class and its superclasses.
 475
 476 =head2 C<< add_attribute(name => spec | Mouse::Meta::Attribute) >>
 477
 478 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 479 class.
 480
 481 =head2 C<< has_attribute(Name) -> Bool >>
 482
 483 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 484
 485 =head2 C<< get_attribute Name -> Mouse::Meta::Attribute | undef >>
 486
 487 Returns the L<Mouse::Meta::Attribute> with the given name.
 488
 489 =head2 C<< get_attribute_list -> Names >>
 490
 491 Returns a list of attribute names which are defined in the local
 492 class. If you want a list of all applicable attributes for a class,
 493 use the C<get_all_attributes> method.
 494
 495 =head2 C<< get_all_attributes -> (Mouse::Meta::Attribute) >>
 496
 497 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 498 this class and its superclasses.
 499
 500 =head2 C<< linearized_isa -> [ClassNames] >>
 501
 502 Returns the list of classes in method dispatch order, with duplicates removed.
 503
 504 =head2 C<< new_object(Parameters) -> Instance >>
 505
 506 Creates a new instance.
 507
 508 =head2 C<< clone_object(Instance, Parameters) -> Instance >>
 509
 510 Clones the given instance which must be an instance governed by this
 511 metaclass.
 512
 513 =head2 C<< throw_error(Message, Parameters) >>
 514
 515 Throws an error with the given message.
 516
 517 =head1 SEE ALSO
 518
 519 L<Moose::Meta::Class>
 520
 521 L<Class::MOP::Class>
 522
 523 =cut
 524