lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use Mouse::Util qw/:meta get_linear_isa not_supported/; # enables strict and warnings
   3
   4 use Scalar::Util qw/blessed weaken/;
   5
   6 use Mouse::Meta::Module;
   7 our @ISA = qw(Mouse::Meta::Module);
   8
   9 our @CARP_NOT = qw(Mouse); # trust Mouse
  10
  11 sub attribute_metaclass;
  12 sub method_metaclass;
  13
  14 sub constructor_class;
  15 sub destructor_class;
  16
  17
  18 sub _construct_meta {
  19     my($class, %args) = @_;
  20
  21     $args{attributes} = {};
  22     $args{methods}    = {};
  23     $args{roles}      = [];
  24
  25     $args{superclasses} = do {
  26         no strict 'refs';
  27         \@{ $args{package} . '::ISA' };
  28     };
  29
  30     my $self = bless \%args, ref($class) || $class;
  31     if(ref($self) ne __PACKAGE__){
  32         $self->meta->_initialize_object($self, \%args);
  33     }
  34     return $self;
  35 }
  36
  37 sub create_anon_class{
  38     my $self = shift;
  39     return $self->create(undef, @_);
  40 }
  41
  42 sub is_anon_class;
  43
  44 sub roles;
  45
  46 sub calculate_all_roles {
  47     my $self = shift;
  48     my %seen;
  49     return grep { !$seen{ $_->name }++ }
  50            map  { $_->calculate_all_roles } @{ $self->roles };
  51 }
  52
  53 sub superclasses {
  54     my $self = shift;
  55
  56     if (@_) {
  57         foreach my $super(@_){
  58             Mouse::Util::load_class($super);
  59             my $meta = Mouse::Util::get_metaclass_by_name($super);
  60
  61             next if not defined $meta;
  62
  63             if(Mouse::Util::is_a_metarole($meta)){
  64                 $self->throw_error("You cannot inherit from a Mouse Role ($super)");
  65             }
  66
  67             next if $self->isa(ref $meta); # _superclass_meta_is_compatible
  68
  69             $self->_reconcile_with_superclass_meta($meta);
  70         }
  71         @{ $self->{superclasses} } = @_;
  72     }
  73
  74     return @{ $self->{superclasses} };
  75 }
  76 my @MetaClassTypes = (
  77     'attribute',   # Mouse::Meta::Attribute
  78     'method',      # Mouse::Meta::Method
  79     'constructor', # Mouse::Meta::Method::Constructor
  80     'destructor',  # Mouse::Meta::Method::Destructor
  81 );
  82
  83 sub _reconcile_with_superclass_meta {
  84     my($self, $other) = @_;
  85
  86     # find incompatible traits
  87     my %metaroles;
  88     foreach my $metaclass_type(@MetaClassTypes){
  89         my $accessor = $self->can($metaclass_type . '_metaclass')
  90             || $self->can($metaclass_type . '_class');
  91
  92         my $other_c = $other->$accessor();
  93         my $self_c  = $self->$accessor();
  94
  95         if(!$self_c->isa($other_c)){
  96             $metaroles{$metaclass_type}
  97                 = [ $self_c->meta->_collect_roles($other_c->meta) ];
  98         }
  99     }
 100
 101     $metaroles{class} = [$self->meta->_collect_roles($other->meta)];
 102
 103     #use Data::Dumper; print Data::Dumper->new([\%metaroles], ['*metaroles'])->Indent(1)->Dump;
 104
 105     require Mouse::Util::MetaRole;
 106     $_[0] = Mouse::Util::MetaRole::apply_metaroles(
 107         for             => $self,
 108         class_metaroles => \%metaroles,
 109     );
 110     return;
 111 }
 112
 113 sub _collect_roles {
 114     my ($self, $other) = @_;
 115
 116     # find common ancestor
 117     my @self_lin_isa  = $self->linearized_isa;
 118     my @other_lin_isa = $other->linearized_isa;
 119
 120     my(@self_anon_supers, @other_anon_supers);
 121     push @self_anon_supers,  shift @self_lin_isa  while $self_lin_isa[0]->meta->is_anon_class;
 122     push @other_anon_supers, shift @other_lin_isa while $other_lin_isa[0]->meta->is_anon_class;
 123
 124     my $common_ancestor = $self_lin_isa[0] eq $other_lin_isa[0] && $self_lin_isa[0];
 125
 126     if(!$common_ancestor){
 127         $self->throw_error(sprintf '%s cannot have %s as a super class because of their metaclass incompatibility',
 128             $self->name, $other->name);
 129     }
 130
 131     my %seen;
 132     return sort grep { !$seen{$_}++ } ## no critic
 133         (map{ $_->name } map{ $_->meta->calculate_all_roles } @self_anon_supers),
 134         (map{ $_->name } map{ $_->meta->calculate_all_roles } @other_anon_supers),
 135     ;
 136 }
 137
 138
 139 sub find_method_by_name{
 140     my($self, $method_name) = @_;
 141     defined($method_name)
 142         or $self->throw_error('You must define a method name to find');
 143
 144     foreach my $class( $self->linearized_isa ){
 145         my $method = $self->initialize($class)->get_method($method_name);
 146         return $method if defined $method;
 147     }
 148     return undef;
 149 }
 150
 151 sub get_all_methods {
 152     my($self) = @_;
 153     return map{ $self->find_method_by_name($_) } $self->get_all_method_names;
 154 }
 155
 156 sub get_all_method_names {
 157     my $self = shift;
 158     my %uniq;
 159     return grep { $uniq{$_}++ == 0 }
 160             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
 161             $self->linearized_isa;
 162 }
 163
 164 sub find_attribute_by_name{
 165     my($self, $name) = @_;
 166     my $attr;
 167     foreach my $class($self->linearized_isa){
 168         my $meta = Mouse::Util::get_metaclass_by_name($class) or next;
 169         $attr = $meta->get_attribute($name) and last;
 170     }
 171     return $attr;
 172 }
 173
 174 sub add_attribute {
 175     my $self = shift;
 176
 177     my($attr, $name);
 178
 179     if(blessed $_[0]){
 180         $attr = $_[0];
 181
 182         $attr->isa('Mouse::Meta::Attribute')
 183             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
 184
 185         $name = $attr->name;
 186     }
 187     else{
 188         # _process_attribute
 189         $name = shift;
 190
 191         my %args = (@_ == 1) ? %{$_[0]} : @_;
 192
 193         defined($name)
 194             or $self->throw_error('You must provide a name for the attribute');
 195
 196         if ($name =~ s/^\+//) { # inherited attributes
 197             my $inherited_attr = $self->find_attribute_by_name($name)
 198                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 199
 200             $attr = $inherited_attr->clone_and_inherit_options(%args);
 201         }
 202         else{
 203             my($attribute_class, @traits) = $self->attribute_metaclass->interpolate_class(\%args);
 204             $args{traits} = \@traits if @traits;
 205
 206             $attr = $attribute_class->new($name, %args);
 207         }
 208     }
 209
 210     weaken( $attr->{associated_class} = $self );
 211
 212     $self->{attributes}{$attr->name} = $attr;
 213     $attr->install_accessors();
 214
 215     if(!$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 216         Carp::carp(qq{Attribute ($name) of class }.$self->name
 217             .qq{ has no associated methods (did you mean to provide an "is" argument?)});
 218     }
 219     return $attr;
 220 }
 221
 222 sub compute_all_applicable_attributes { # DEPRECATED
 223     Carp::cluck('compute_all_applicable_attributes() has been deprecated. Use get_all_attributes() instead');
 224
 225     return shift->get_all_attributes(@_)
 226 }
 227
 228 sub linearized_isa;
 229
 230 sub new_object;
 231 sub clone_object;
 232
 233
 234 sub clone_instance { # DEPRECATED
 235     my ($class, $instance, %params) = @_;
 236
 237     Carp::cluck('clone_instance() has been deprecated. Use clone_object() instead');
 238
 239     return $class->clone_object($instance, %params);
 240 }
 241
 242
 243 sub immutable_options {
 244     my ( $self, @args ) = @_;
 245
 246     return (
 247         inline_constructor => 1,
 248         inline_destructor  => 1,
 249         constructor_name   => 'new',
 250         @args,
 251     );
 252 }
 253
 254
 255 sub make_immutable {
 256     my $self = shift;
 257     my %args = $self->immutable_options(@_);
 258
 259     $self->{is_immutable}++;
 260
 261     if ($args{inline_constructor}) {
 262         $self->add_method($args{constructor_name} =>
 263             Mouse::Util::load_class($self->constructor_class)
 264                 ->_generate_constructor($self, \%args));
 265     }
 266
 267     if ($args{inline_destructor}) {
 268         $self->add_method(DESTROY =>
 269             Mouse::Util::load_class($self->destructor_class)
 270                 ->_generate_destructor($self, \%args));
 271     }
 272
 273     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 274     # at the end of a source file.
 275     return 1;
 276 }
 277
 278 sub make_mutable {
 279     my($self) = @_;
 280     $self->{is_immutable} = 0;
 281     return;
 282 }
 283
 284 sub is_immutable;
 285 sub is_mutable   { !$_[0]->is_immutable }
 286
 287 sub _install_modifier_pp{
 288     my( $self, $type, $name, $code ) = @_;
 289     my $into = $self->name;
 290
 291     my $original = $into->can($name)
 292         or $self->throw_error("The method '$name' is not found in the inheritance hierarchy for class $into");
 293
 294     my $modifier_table = $self->{modifiers}{$name};
 295
 296     if(!$modifier_table){
 297         my(@before, @after, @around, $cache, $modified);
 298
 299         $cache = $original;
 300
 301         $modified = sub {
 302             for my $c (@before) { $c->(@_) }
 303
 304             if(wantarray){ # list context
 305                 my @rval = $cache->(@_);
 306
 307                 for my $c(@after){ $c->(@_) }
 308                 return @rval;
 309             }
 310             elsif(defined wantarray){ # scalar context
 311                 my $rval = $cache->(@_);
 312
 313                 for my $c(@after){ $c->(@_) }
 314                 return $rval;
 315             }
 316             else{ # void context
 317                 $cache->(@_);
 318
 319                 for my $c(@after){ $c->(@_) }
 320                 return;
 321             }
 322         };
 323
 324         $self->{modifiers}{$name} = $modifier_table = {
 325             original => $original,
 326
 327             before   => \@before,
 328             after    => \@after,
 329             around   => \@around,
 330
 331             cache    => \$cache, # cache for around modifiers
 332         };
 333
 334         $self->add_method($name => $modified);
 335     }
 336
 337     if($type eq 'before'){
 338         unshift @{$modifier_table->{before}}, $code;
 339     }
 340     elsif($type eq 'after'){
 341         push @{$modifier_table->{after}}, $code;
 342     }
 343     else{ # around
 344         push @{$modifier_table->{around}}, $code;
 345
 346         my $next = ${ $modifier_table->{cache} };
 347         ${ $modifier_table->{cache} } = sub{ $code->($next, @_) };
 348     }
 349
 350     return;
 351 }
 352
 353 sub _install_modifier {
 354     my ( $self, $type, $name, $code ) = @_;
 355
 356     # load Data::Util first
 357     my $no_cmm_fast = do{
 358         local $@;
 359         eval q{ use Data::Util 0.55 () };
 360         $@;
 361     };
 362
 363     my $impl;
 364     if($no_cmm_fast){
 365         $impl = \&_install_modifier_pp;
 366     }
 367     else{
 368         $impl = sub {
 369             my ( $self, $type, $name, $code ) = @_;
 370             my $into = $self->name;
 371
 372             my $method = Mouse::Util::get_code_ref( $into, $name );
 373
 374             if ( !$method || !Data::Util::subroutine_modifier($method) ) {
 375                 unless ($method) {
 376                     $method = $into->can($name)
 377                         or Carp::confess("The method '$name' is not found in the inheritance hierarchy for class $into");
 378                 }
 379                 $method = Data::Util::modify_subroutine( $method,
 380                     $type => [$code] );
 381
 382                 $self->add_method($name => $method);
 383             }
 384             else {
 385                 Data::Util::subroutine_modifier( $method, $type => $code );
 386                 $self->add_method($name => Mouse::Util::get_code_ref($into, $name));
 387             }
 388
 389             return;
 390         };
 391     }
 392
 393     # replace this method itself :)
 394     {
 395         no warnings 'redefine';
 396         *_install_modifier = $impl;
 397     }
 398
 399     $self->$impl( $type, $name, $code );
 400 }
 401
 402 sub add_before_method_modifier {
 403     my ( $self, $name, $code ) = @_;
 404     $self->_install_modifier( 'before', $name, $code );
 405 }
 406
 407 sub add_around_method_modifier {
 408     my ( $self, $name, $code ) = @_;
 409     $self->_install_modifier( 'around', $name, $code );
 410 }
 411
 412 sub add_after_method_modifier {
 413     my ( $self, $name, $code ) = @_;
 414     $self->_install_modifier( 'after', $name, $code );
 415 }
 416
 417 sub add_override_method_modifier {
 418     my ($self, $name, $code) = @_;
 419
 420     if($self->has_method($name)){
 421         $self->throw_error("Cannot add an override method if a local method is already present");
 422     }
 423
 424     my $package = $self->name;
 425
 426     my $super_body = $package->can($name)
 427         or $self->throw_error("You cannot override '$name' because it has no super method");
 428
 429     $self->add_method($name => sub {
 430         local $Mouse::SUPER_PACKAGE = $package;
 431         local $Mouse::SUPER_BODY    = $super_body;
 432         local @Mouse::SUPER_ARGS    = @_;
 433
 434         $code->(@_);
 435     });
 436     return;
 437 }
 438
 439 sub add_augment_method_modifier {
 440     my ($self, $name, $code) = @_;
 441     if($self->has_method($name)){
 442         $self->throw_error("Cannot add an augment method if a local method is already present");
 443     }
 444
 445     my $super = $self->find_method_by_name($name)
 446         or $self->throw_error("You cannot augment '$name' because it has no super method");
 447
 448     my $super_package = $super->package_name;
 449     my $super_body    = $super->body;
 450
 451     $self->add_method($name => sub{
 452         local $Mouse::INNER_BODY{$super_package} = $code;
 453         local $Mouse::INNER_ARGS{$super_package} = [@_];
 454         $super_body->(@_);
 455     });
 456     return;
 457 }
 458
 459 sub does_role {
 460     my ($self, $role_name) = @_;
 461
 462     (defined $role_name)
 463         || $self->throw_error("You must supply a role name to look for");
 464
 465     $role_name = $role_name->name if ref $role_name;
 466
 467     for my $class ($self->linearized_isa) {
 468         my $meta = Mouse::Util::get_metaclass_by_name($class)
 469             or next;
 470
 471         for my $role (@{ $meta->roles }) {
 472
 473             return 1 if $role->does_role($role_name);
 474         }
 475     }
 476
 477     return 0;
 478 }
 479
 480 1;
 481 __END__
 482
 483 =head1 NAME
 484
 485 Mouse::Meta::Class - The Mouse class metaclass
 486
 487 =head1 VERSION
 488
 489 This document describes Mouse version 0.62
 490
 491 =head1 METHODS
 492
 493 =head2 C<< initialize(ClassName) -> Mouse::Meta::Class >>
 494
 495 Finds or creates a C<Mouse::Meta::Class> instance for the given ClassName. Only
 496 one instance should exist for a given class.
 497
 498 =head2 C<< name -> ClassName >>
 499
 500 Returns the name of the owner class.
 501
 502 =head2 C<< superclasses -> ClassNames >> C<< superclass(ClassNames) >>
 503
 504 Gets (or sets) the list of superclasses of the owner class.
 505
 506 =head2 C<< add_method(name => CodeRef) >>
 507
 508 Adds a method to the owner class.
 509
 510 =head2 C<< has_method(name) -> Bool >>
 511
 512 Returns whether we have a method with the given name.
 513
 514 =head2 C<< get_method(name) -> Mouse::Meta::Method | undef >>
 515
 516 Returns a L<Mouse::Meta::Method> with the given name.
 517
 518 Note that you can also use C<< $metaclass->name->can($name) >> for a method body.
 519
 520 =head2 C<< get_method_list -> Names >>
 521
 522 Returns a list of method names which are defined in the local class.
 523 If you want a list of all applicable methods for a class, use the
 524 C<get_all_methods> method.
 525
 526 =head2 C<< get_all_methods -> (Mouse::Meta::Method) >>
 527
 528 Return the list of all L<Mouse::Meta::Method> instances associated with
 529 the class and its superclasses.
 530
 531 =head2 C<< add_attribute(name => spec | Mouse::Meta::Attribute) >>
 532
 533 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 534 class.
 535
 536 =head2 C<< has_attribute(Name) -> Bool >>
 537
 538 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 539
 540 =head2 C<< get_attribute Name -> Mouse::Meta::Attribute | undef >>
 541
 542 Returns the L<Mouse::Meta::Attribute> with the given name.
 543
 544 =head2 C<< get_attribute_list -> Names >>
 545
 546 Returns a list of attribute names which are defined in the local
 547 class. If you want a list of all applicable attributes for a class,
 548 use the C<get_all_attributes> method.
 549
 550 =head2 C<< get_all_attributes -> (Mouse::Meta::Attribute) >>
 551
 552 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 553 this class and its superclasses.
 554
 555 =head2 C<< linearized_isa -> [ClassNames] >>
 556
 557 Returns the list of classes in method dispatch order, with duplicates removed.
 558
 559 =head2 C<< new_object(Parameters) -> Instance >>
 560
 561 Creates a new instance.
 562
 563 =head2 C<< clone_object(Instance, Parameters) -> Instance >>
 564
 565 Clones the given instance which must be an instance governed by this
 566 metaclass.
 567
 568 =head2 C<< throw_error(Message, Parameters) >>
 569
 570 Throws an error with the given message.
 571
 572 =head1 SEE ALSO
 573
 574 L<Mouse::Meta::Module>
 575
 576 L<Moose::Meta::Class>
 577
 578 L<Class::MOP::Class>
 579
 580 =cut
 581