lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use Mouse::Util qw/:meta get_linear_isa not_supported/; # enables strict and warnings
   3
   4 use Scalar::Util qw/blessed weaken/;
   5
   6 use Mouse::Meta::Method::Constructor;
   7 use Mouse::Meta::Method::Destructor;
   8 use Mouse::Meta::Module;
   9 our @ISA = qw(Mouse::Meta::Module);
  10
  11 sub method_metaclass()    { 'Mouse::Meta::Method'    }
  12 sub attribute_metaclass() { 'Mouse::Meta::Attribute' }
  13
  14 sub constructor_class()   { 'Mouse::Meta::Method::Constructor' }
  15 sub destructor_class()    { 'Mouse::Meta::Method::Destructor'  }
  16
  17 sub _construct_meta {
  18     my($class, %args) = @_;
  19
  20     $args{attributes} ||= {};
  21     $args{methods}    ||= {};
  22     $args{roles}      ||= [];
  23
  24     $args{superclasses} = do {
  25         no strict 'refs';
  26         \@{ $args{package} . '::ISA' };
  27     };
  28
  29     my $self = bless \%args, ref($class) || $class;
  30     if(ref($self) ne __PACKAGE__){
  31         $self->meta->_initialize_object($self, \%args);
  32     }
  33     return $self;
  34 }
  35
  36 sub create_anon_class{
  37     my $self = shift;
  38     return $self->create(undef, @_);
  39 }
  40
  41 sub is_anon_class{
  42     return exists $_[0]->{anon_serial_id};
  43 }
  44
  45 sub roles { $_[0]->{roles} }
  46
  47 sub superclasses {
  48     my $self = shift;
  49
  50     if (@_) {
  51         foreach my $super(@_){
  52             Mouse::Util::load_class($super);
  53             my $meta = Mouse::Util::get_metaclass_by_name($super);
  54             if($meta && $meta->isa('Mouse::Meta::Role')){
  55                 $self->throw_error("You cannot inherit from a Mouse Role ($super)");
  56             }
  57         }
  58         @{ $self->{superclasses} } = @_;
  59     }
  60
  61     return @{ $self->{superclasses} };
  62 }
  63
  64 sub find_method_by_name{
  65     my($self, $method_name) = @_;
  66     defined($method_name)
  67         or $self->throw_error('You must define a method name to find');
  68
  69     foreach my $class( $self->linearized_isa ){
  70         my $method = $self->initialize($class)->get_method($method_name);
  71         return $method if defined $method;
  72     }
  73     return undef;
  74 }
  75
  76 sub get_all_methods {
  77     my($self) = @_;
  78     return map{ $self->find_method_by_name($_) } $self->get_all_method_names;
  79 }
  80
  81 sub get_all_method_names {
  82     my $self = shift;
  83     my %uniq;
  84     return grep { $uniq{$_}++ == 0 }
  85             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
  86             $self->linearized_isa;
  87 }
  88
  89 sub find_attribute_by_name{
  90     my($self, $name) = @_;
  91     my $attr;
  92     foreach my $class($self->linearized_isa){
  93         my $meta = Mouse::Util::get_metaclass_by_name($class) or next;
  94         $attr = $meta->get_attribute($name) and last;
  95     }
  96     return $attr;
  97 }
  98
  99 sub add_attribute {
 100     my $self = shift;
 101
 102     my($attr, $name);
 103
 104     if(blessed $_[0]){
 105         $attr = $_[0];
 106
 107         $attr->isa('Mouse::Meta::Attribute')
 108             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
 109
 110         $name = $attr->name;
 111     }
 112     else{
 113         # _process_attribute
 114         $name = shift;
 115
 116         my %args = (@_ == 1) ? %{$_[0]} : @_;
 117
 118         defined($name)
 119             or $self->throw_error('You must provide a name for the attribute');
 120
 121         if ($name =~ s/^\+//) { # inherited attributes
 122             my $inherited_attr = $self->find_attribute_by_name($name)
 123                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 124
 125             $attr = $inherited_attr->clone_and_inherit_options(%args);
 126         }
 127         else{
 128             my($attribute_class, @traits) = $self->attribute_metaclass->interpolate_class(\%args);
 129             $args{traits} = \@traits if @traits;
 130
 131             $attr = $attribute_class->new($name, %args);
 132         }
 133     }
 134
 135     weaken( $attr->{associated_class} = $self );
 136
 137     $self->{attributes}{$attr->name} = $attr;
 138     $attr->install_accessors();
 139
 140     if(_MOUSE_VERBOSE && !$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 141         Carp::cluck(qq{Attribute (}.$attr->name.qq{) of class }.$self->name.qq{ has no associated methods (did you mean to provide an "is" argument?)});
 142     }
 143     return $attr;
 144 }
 145
 146 sub compute_all_applicable_attributes {
 147     Carp::cluck('compute_all_applicable_attributes() has been deprecated')
 148         if _MOUSE_VERBOSE;
 149     return shift->get_all_attributes(@_)
 150 }
 151
 152 sub get_all_attributes {
 153     my $self = shift;
 154     my (@attr, %seen);
 155
 156     for my $class ($self->linearized_isa) {
 157         my $meta = Mouse::Util::get_metaclass_by_name($class)
 158             or next;
 159
 160         for my $name ($meta->get_attribute_list) {
 161             next if $seen{$name}++;
 162             push @attr, $meta->get_attribute($name);
 163         }
 164     }
 165
 166     return @attr;
 167 }
 168
 169 sub linearized_isa { @{ get_linear_isa($_[0]->name) } }
 170
 171 sub new_object {
 172     my $self = shift;
 173     my %args = (@_ == 1 ? %{$_[0]} : @_);
 174
 175     my $object = bless {}, $self->name;
 176
 177     $self->_initialize_object($object, \%args);
 178     return $object;
 179 }
 180
 181 sub _initialize_object{
 182     my($self, $object, $args) = @_;
 183
 184     my @triggers_queue;
 185
 186     foreach my $attribute ($self->get_all_attributes) {
 187         my $from = $attribute->init_arg;
 188         my $key  = $attribute->name;
 189
 190         if (defined($from) && exists($args->{$from})) {
 191             $object->{$key} = $attribute->_coerce_and_verify($args->{$from}, $object);
 192
 193             weaken($object->{$key})
 194                 if ref($object->{$key}) && $attribute->is_weak_ref;
 195
 196             if ($attribute->has_trigger) {
 197                 push @triggers_queue, [ $attribute->trigger, $object->{$key} ];
 198             }
 199         }
 200         else {
 201             if ($attribute->has_default || $attribute->has_builder) {
 202                 unless ($attribute->is_lazy) {
 203                     my $default = $attribute->default;
 204                     my $builder = $attribute->builder;
 205                     my $value =   $builder                ? $object->$builder()
 206                                 : ref($default) eq 'CODE' ? $object->$default()
 207                                 :                           $default;
 208
 209                     $object->{$key} = $attribute->_coerce_and_verify($value, $object);
 210
 211                     weaken($object->{$key})
 212                         if ref($object->{$key}) && $attribute->is_weak_ref;
 213                 }
 214             }
 215             else {
 216                 if ($attribute->is_required) {
 217                     $self->throw_error("Attribute (".$attribute->name.") is required");
 218                 }
 219             }
 220         }
 221     }
 222
 223     foreach my $trigger_and_value(@triggers_queue){
 224         my($trigger, $value) = @{$trigger_and_value};
 225         $trigger->($object, $value);
 226     }
 227
 228     if($self->is_anon_class){
 229         $object->{__METACLASS__} = $self;
 230     }
 231
 232     return $object;
 233 }
 234
 235 sub clone_object {
 236     my $class  = shift;
 237     my $object = shift;
 238     my %params = (@_ == 1) ? %{$_[0]} : @_;
 239
 240     (blessed($object) && $object->isa($class->name))
 241         || $class->throw_error("You must pass an instance of the metaclass (" . $class->name . "), not ($object)");
 242
 243     my $cloned = bless { %$object }, ref $object;
 244     $class->_initialize_object($cloned, \%params);
 245
 246     return $cloned;
 247 }
 248
 249 sub clone_instance {
 250     my ($class, $instance, %params) = @_;
 251
 252     Carp::cluck('clone_instance has been deprecated. Use clone_object instead')
 253         if _MOUSE_VERBOSE;
 254     return $class->clone_object($instance, %params);
 255 }
 256
 257 sub make_immutable {
 258     my $self = shift;
 259     my %args = (
 260         inline_constructor => 1,
 261         inline_destructor  => 1,
 262         constructor_name   => 'new',
 263         @_,
 264     );
 265
 266     $self->{is_immutable}++;
 267
 268     if ($args{inline_constructor}) {
 269         $self->add_method($args{constructor_name} =>
 270             $self->constructor_class->_generate_constructor($self, \%args));
 271     }
 272
 273     if ($args{inline_destructor}) {
 274         $self->add_method(DESTROY =>
 275             $self->destructor_class->_generate_destructor($self, \%args));
 276     }
 277
 278     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 279     # at the end of a source file.
 280     return 1;
 281 }
 282
 283 sub make_mutable { not_supported }
 284
 285 sub is_immutable {  $_[0]->{is_immutable} }
 286 sub is_mutable   { !$_[0]->{is_immutable} }
 287
 288 sub _install_modifier_pp{
 289     my( $self, $type, $name, $code ) = @_;
 290     my $into = $self->name;
 291
 292     my $original = $into->can($name)
 293         or $self->throw_error("The method '$name' is not found in the inheritance hierarchy for class $into");
 294
 295     my $modifier_table = $self->{modifiers}{$name};
 296
 297     if(!$modifier_table){
 298         my(@before, @after, @around, $cache, $modified);
 299
 300         $cache = $original;
 301
 302         $modified = sub {
 303             for my $c (@before) { $c->(@_) }
 304
 305             if(wantarray){ # list context
 306                 my @rval = $cache->(@_);
 307
 308                 for my $c(@after){ $c->(@_) }
 309                 return @rval;
 310             }
 311             elsif(defined wantarray){ # scalar context
 312                 my $rval = $cache->(@_);
 313
 314                 for my $c(@after){ $c->(@_) }
 315                 return $rval;
 316             }
 317             else{ # void context
 318                 $cache->(@_);
 319
 320                 for my $c(@after){ $c->(@_) }
 321                 return;
 322             }
 323         };
 324
 325         $self->{modifiers}{$name} = $modifier_table = {
 326             original => $original,
 327
 328             before   => \@before,
 329             after    => \@after,
 330             around   => \@around,
 331
 332             cache    => \$cache, # cache for around modifiers
 333         };
 334
 335         $self->add_method($name => $modified);
 336     }
 337
 338     if($type eq 'before'){
 339         unshift @{$modifier_table->{before}}, $code;
 340     }
 341     elsif($type eq 'after'){
 342         push @{$modifier_table->{after}}, $code;
 343     }
 344     else{ # around
 345         push @{$modifier_table->{around}}, $code;
 346
 347         my $next = ${ $modifier_table->{cache} };
 348         ${ $modifier_table->{cache} } = sub{ $code->($next, @_) };
 349     }
 350
 351     return;
 352 }
 353
 354 sub _install_modifier {
 355     my ( $self, $type, $name, $code ) = @_;
 356
 357     # load Class::Method::Modifiers first
 358     my $no_cmm_fast = do{
 359         local $@;
 360         eval q{ require Class::Method::Modifiers::Fast };
 361         $@;
 362     };
 363
 364     my $impl;
 365     if($no_cmm_fast){
 366         $impl = \&_install_modifier_pp;
 367     }
 368     else{
 369         my $install_modifier = Class::Method::Modifiers::Fast->can('_install_modifier');
 370         $impl = sub {
 371             my ( $self, $type, $name, $code ) = @_;
 372             my $into = $self->name;
 373             $install_modifier->($into, $type, $name, $code);
 374
 375             $self->add_method($name => do{
 376                 no strict 'refs';
 377                 \&{ $into . '::' . $name };
 378             });
 379             return;
 380         };
 381     }
 382
 383     # replace this method itself :)
 384     {
 385         no warnings 'redefine';
 386         *_install_modifier = $impl;
 387     }
 388
 389     $self->$impl( $type, $name, $code );
 390 }
 391
 392 sub add_before_method_modifier {
 393     my ( $self, $name, $code ) = @_;
 394     $self->_install_modifier( 'before', $name, $code );
 395 }
 396
 397 sub add_around_method_modifier {
 398     my ( $self, $name, $code ) = @_;
 399     $self->_install_modifier( 'around', $name, $code );
 400 }
 401
 402 sub add_after_method_modifier {
 403     my ( $self, $name, $code ) = @_;
 404     $self->_install_modifier( 'after', $name, $code );
 405 }
 406
 407 sub add_override_method_modifier {
 408     my ($self, $name, $code) = @_;
 409
 410     if($self->has_method($name)){
 411         $self->throw_error("Cannot add an override method if a local method is already present");
 412     }
 413
 414     my $package = $self->name;
 415
 416     my $super_body = $package->can($name)
 417         or $self->throw_error("You cannot override '$name' because it has no super method");
 418
 419     $self->add_method($name => sub {
 420         local $Mouse::SUPER_PACKAGE = $package;
 421         local $Mouse::SUPER_BODY    = $super_body;
 422         local @Mouse::SUPER_ARGS    = @_;
 423
 424         $code->(@_);
 425     });
 426     return;
 427 }
 428
 429 sub add_augment_method_modifier {
 430     my ($self, $name, $code) = @_;
 431     if($self->has_method($name)){
 432         $self->throw_error("Cannot add an augment method if a local method is already present");
 433     }
 434
 435     my $super = $self->find_method_by_name($name)
 436         or $self->throw_error("You cannot augment '$name' because it has no super method");
 437
 438     my $super_package = $super->package_name;
 439     my $super_body    = $super->body;
 440
 441     $self->add_method($name => sub{
 442         local $Mouse::INNER_BODY{$super_package} = $code;
 443         local $Mouse::INNER_ARGS{$super_package} = [@_];
 444         $super_body->(@_);
 445     });
 446     return;
 447 }
 448
 449 sub does_role {
 450     my ($self, $role_name) = @_;
 451
 452     (defined $role_name)
 453         || $self->throw_error("You must supply a role name to look for");
 454
 455     for my $class ($self->linearized_isa) {
 456         my $meta = Mouse::Util::get_metaclass_by_name($class)
 457             or next;
 458
 459         for my $role (@{ $meta->roles }) {
 460
 461             return 1 if $role->does_role($role_name);
 462         }
 463     }
 464
 465     return 0;
 466 }
 467
 468 1;
 469 __END__
 470
 471 =head1 NAME
 472
 473 Mouse::Meta::Class - The Mouse class metaclass
 474
 475 =head1 VERSION
 476
 477 This document describes Mouse version 0.38
 478
 479 =head1 METHODS
 480
 481 =head2 C<< initialize(ClassName) -> Mouse::Meta::Class >>
 482
 483 Finds or creates a C<Mouse::Meta::Class> instance for the given ClassName. Only
 484 one instance should exist for a given class.
 485
 486 =head2 C<< name -> ClassName >>
 487
 488 Returns the name of the owner class.
 489
 490 =head2 C<< superclasses -> ClassNames >> C<< superclass(ClassNames) >>
 491
 492 Gets (or sets) the list of superclasses of the owner class.
 493
 494 =head2 C<< add_method(name => CodeRef) >>
 495
 496 Adds a method to the owner class.
 497
 498 =head2 C<< has_method(name) -> Bool >>
 499
 500 Returns whether we have a method with the given name.
 501
 502 =head2 C<< get_method(name) -> Mouse::Meta::Method | undef >>
 503
 504 Returns a L<Mouse::Meta::Method> with the given name.
 505
 506 Note that you can also use C<< $metaclass->name->can($name) >> for a method body.
 507
 508 =head2 C<< get_method_list -> Names >>
 509
 510 Returns a list of method names which are defined in the local class.
 511 If you want a list of all applicable methods for a class, use the
 512 C<get_all_methods> method.
 513
 514 =head2 C<< get_all_methods -> (Mouse::Meta::Method) >>
 515
 516 Return the list of all L<Mouse::Meta::Method> instances associated with
 517 the class and its superclasses.
 518
 519 =head2 C<< add_attribute(name => spec | Mouse::Meta::Attribute) >>
 520
 521 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 522 class.
 523
 524 =head2 C<< has_attribute(Name) -> Bool >>
 525
 526 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 527
 528 =head2 C<< get_attribute Name -> Mouse::Meta::Attribute | undef >>
 529
 530 Returns the L<Mouse::Meta::Attribute> with the given name.
 531
 532 =head2 C<< get_attribute_list -> Names >>
 533
 534 Returns a list of attribute names which are defined in the local
 535 class. If you want a list of all applicable attributes for a class,
 536 use the C<get_all_attributes> method.
 537
 538 =head2 C<< get_all_attributes -> (Mouse::Meta::Attribute) >>
 539
 540 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 541 this class and its superclasses.
 542
 543 =head2 C<< linearized_isa -> [ClassNames] >>
 544
 545 Returns the list of classes in method dispatch order, with duplicates removed.
 546
 547 =head2 C<< new_object(Parameters) -> Instance >>
 548
 549 Creates a new instance.
 550
 551 =head2 C<< clone_object(Instance, Parameters) -> Instance >>
 552
 553 Clones the given instance which must be an instance governed by this
 554 metaclass.
 555
 556 =head2 C<< throw_error(Message, Parameters) >>
 557
 558 Throws an error with the given message.
 559
 560 =head1 SEE ALSO
 561
 562 L<Moose::Meta::Class>
 563
 564 L<Class::MOP::Class>
 565
 566 =cut
 567