lib/Mouse/Meta/Class.pm

   1 #!/usr/bin/env perl
   2 package Mouse::Meta::Class;
   3 use strict;
   4 use warnings;
   5
   6 use Mouse::Util 'get_linear_isa';
   7 use Scalar::Util 'blessed';
   8 use Carp 'confess';
   9
  10 use Class::Method::Modifiers ();
  11
  12 do {
  13     my %METACLASS_CACHE;
  14
  15     # because Mouse doesn't introspect existing classes, we're forced to
  16     # only pay attention to other Mouse classes
  17     sub _metaclass_cache {
  18         my $class = shift;
  19         my $name  = shift;
  20         return $METACLASS_CACHE{$name};
  21     }
  22
  23     sub initialize {
  24         my $class = shift;
  25         my $name  = shift;
  26         $METACLASS_CACHE{$name} = $class->new(name => $name)
  27             if !exists($METACLASS_CACHE{$name});
  28         return $METACLASS_CACHE{$name};
  29     }
  30 };
  31
  32 sub new {
  33     my $class = shift;
  34     my %args  = @_;
  35
  36     $args{attributes} = {};
  37     $args{superclasses} = do {
  38         no strict 'refs';
  39         \@{ $args{name} . '::ISA' };
  40     };
  41
  42     bless \%args, $class;
  43 }
  44
  45 sub name { $_[0]->{name} }
  46
  47 sub superclasses {
  48     my $self = shift;
  49
  50     if (@_) {
  51         Mouse::load_class($_) for @_;
  52         @{ $self->{superclasses} } = @_;
  53     }
  54
  55     @{ $self->{superclasses} };
  56 }
  57
  58 sub add_method {
  59     my $self = shift;
  60     my $name = shift;
  61     my $code = shift;
  62
  63     my $pkg = $self->name;
  64
  65     no strict 'refs';
  66     *{ $pkg . '::' . $name } = $code;
  67 }
  68
  69 sub add_attribute {
  70     my $self = shift;
  71     my $attr = shift;
  72
  73     $self->{'attributes'}{$attr->name} = $attr;
  74 }
  75
  76 sub compute_all_applicable_attributes {
  77     my $self = shift;
  78     my (@attr, %seen);
  79
  80     for my $class ($self->linearized_isa) {
  81         my $meta = $self->_metaclass_cache($class)
  82             or next;
  83
  84         for my $name (keys %{ $meta->get_attribute_map }) {
  85             next if $seen{$name}++;
  86             push @attr, $meta->get_attribute($name);
  87         }
  88     }
  89
  90     return @attr;
  91 }
  92
  93 sub get_attribute_map { $_[0]->{attributes} }
  94 sub has_attribute     { exists $_[0]->{attributes}->{$_[1]} }
  95 sub get_attribute     { $_[0]->{attributes}->{$_[1]} }
  96
  97 sub linearized_isa { @{ get_linear_isa($_[0]->name) } }
  98
  99 sub clone_object {
 100     my $class    = shift;
 101     my $instance = shift;
 102
 103     (blessed($instance) && $instance->isa($class->name))
 104         || confess "You must pass an instance of the metaclass (" . $class->name . "), not ($instance)";
 105
 106     $class->clone_instance($instance, @_);
 107 }
 108
 109 sub clone_instance {
 110     my ($class, $instance, %params) = @_;
 111
 112     (blessed($instance))
 113         || confess "You can only clone instances, ($instance) is not a blessed instance";
 114
 115     my $clone = bless { %$instance }, ref $instance;
 116
 117     foreach my $attr ($class->compute_all_applicable_attributes()) {
 118         if ( defined( my $init_arg = $attr->init_arg ) ) {
 119             if (exists $params{$init_arg}) {
 120                 $clone->{ $attr->name } = $params{$init_arg};
 121             }
 122         }
 123     }
 124
 125     return $clone;
 126
 127 }
 128
 129 sub make_immutable {}
 130 sub is_immutable { 0 }
 131
 132 sub attribute_metaclass { "Mouse::Meta::Class" }
 133
 134 sub add_before_method_modifier {
 135     my ($self, $name, $code) = @_;
 136     Class::Method::Modifiers::_install_modifier(
 137         $self->name,
 138         'before',
 139         $name,
 140         $code,
 141     );
 142 }
 143
 144 sub add_around_method_modifier {
 145     my ($self, $name, $code) = @_;
 146     Class::Method::Modifiers::_install_modifier(
 147         $self->name,
 148         'around',
 149         $name,
 150         $code,
 151     );
 152 }
 153
 154 sub add_after_method_modifier {
 155     my ($self, $name, $code) = @_;
 156     Class::Method::Modifiers::_install_modifier(
 157         $self->name,
 158         'after',
 159         $name,
 160         $code,
 161     );
 162 }
 163
 164 1;
 165
 166 __END__
 167
 168 =head1 NAME
 169
 170 Mouse::Meta::Class - hook into the Mouse MOP
 171
 172 =head1 METHODS
 173
 174 =head2 initialize ClassName -> Mouse::Meta::Class
 175
 176 Finds or creates a Mouse::Meta::Class instance for the given ClassName. Only
 177 one instance should exist for a given class.
 178
 179 =head2 new %args -> Mouse::Meta::Class
 180
 181 Creates a new Mouse::Meta::Class. Don't call this directly.
 182
 183 =head2 name -> ClassName
 184
 185 Returns the name of the owner class.
 186
 187 =head2 superclasses -> [ClassName]
 188
 189 Gets (or sets) the list of superclasses of the owner class.
 190
 191 =head2 add_attribute Mouse::Meta::Attribute
 192
 193 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 194 class.
 195
 196 =head2 compute_all_applicable_attributes -> (Mouse::Meta::Attribute)
 197
 198 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 199 this class and its superclasses.
 200
 201 =head2 get_attribute_map -> { name => Mouse::Meta::Attribute }
 202
 203 Returns a mapping of attribute names to their corresponding
 204 L<Mouse::Meta::Attribute> objects.
 205
 206 =head2 has_attribute Name -> Boool
 207
 208 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 209
 210 =head2 get_attribute Name -> Mouse::Meta::Attribute | undef
 211
 212 Returns the L<Mouse::Meta::Attribute> with the given name.
 213
 214 =head2 linearized_isa -> [ClassNames]
 215
 216 Returns the list of classes in method dispatch order, with duplicates removed.
 217
 218 =head2 clone_object Instance -> Instance
 219
 220 Clones the given C<Instance> which must be an instance governed by this
 221 metaclass.
 222
 223 =head2 clone_instance Instance, Parameters -> Instance
 224
 225 Clones the given C<Instance> and sets any additional parameters.
 226
 227 =cut
 228