lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use Mouse::Util qw/:meta get_linear_isa not_supported/; # enables strict and warnings
   3
   4 use Scalar::Util qw/blessed weaken/;
   5
   6 use Mouse::Meta::Method::Constructor;
   7 use Mouse::Meta::Method::Destructor;
   8 use Mouse::Meta::Module;
   9 our @ISA = qw(Mouse::Meta::Module);
  10
  11 sub method_metaclass()    { 'Mouse::Meta::Method'    }
  12 sub attribute_metaclass() { 'Mouse::Meta::Attribute' }
  13
  14 sub constructor_class()   { 'Mouse::Meta::Method::Constructor' }
  15 sub destructor_class()    { 'Mouse::Meta::Method::Destructor'  }
  16
  17 sub _construct_meta {
  18     my($class, %args) = @_;
  19
  20     $args{attributes} = {};
  21     $args{methods}    = {};
  22     $args{roles}      = [];
  23
  24     $args{superclasses} = do {
  25         no strict 'refs';
  26         \@{ $args{package} . '::ISA' };
  27     };
  28
  29     my $self = bless \%args, ref($class) || $class;
  30     if(ref($self) ne __PACKAGE__){
  31         $self->meta->_initialize_object($self, \%args);
  32     }
  33     return $self;
  34 }
  35
  36 sub create_anon_class{
  37     my $self = shift;
  38     return $self->create(undef, @_);
  39 }
  40
  41 sub is_anon_class;
  42
  43 sub roles;
  44
  45 sub calculate_all_roles {
  46     my $self = shift;
  47     my %seen;
  48     return grep { !$seen{ $_->name }++ }
  49            map  { $_->calculate_all_roles } @{ $self->roles };
  50 }
  51
  52 sub superclasses {
  53     my $self = shift;
  54
  55     if (@_) {
  56         foreach my $super(@_){
  57             Mouse::Util::load_class($super);
  58             my $meta = Mouse::Util::get_metaclass_by_name($super);
  59             if(Mouse::Util::is_a_metarole($meta)){
  60                 $self->throw_error("You cannot inherit from a Mouse Role ($super)");
  61             }
  62         }
  63         @{ $self->{superclasses} } = @_;
  64     }
  65
  66     return @{ $self->{superclasses} };
  67 }
  68
  69 sub find_method_by_name{
  70     my($self, $method_name) = @_;
  71     defined($method_name)
  72         or $self->throw_error('You must define a method name to find');
  73
  74     foreach my $class( $self->linearized_isa ){
  75         my $method = $self->initialize($class)->get_method($method_name);
  76         return $method if defined $method;
  77     }
  78     return undef;
  79 }
  80
  81 sub get_all_methods {
  82     my($self) = @_;
  83     return map{ $self->find_method_by_name($_) } $self->get_all_method_names;
  84 }
  85
  86 sub get_all_method_names {
  87     my $self = shift;
  88     my %uniq;
  89     return grep { $uniq{$_}++ == 0 }
  90             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
  91             $self->linearized_isa;
  92 }
  93
  94 sub find_attribute_by_name{
  95     my($self, $name) = @_;
  96     my $attr;
  97     foreach my $class($self->linearized_isa){
  98         my $meta = Mouse::Util::get_metaclass_by_name($class) or next;
  99         $attr = $meta->get_attribute($name) and last;
 100     }
 101     return $attr;
 102 }
 103
 104 sub add_attribute {
 105     my $self = shift;
 106
 107     my($attr, $name);
 108
 109     if(blessed $_[0]){
 110         $attr = $_[0];
 111
 112         $attr->isa('Mouse::Meta::Attribute')
 113             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
 114
 115         $name = $attr->name;
 116     }
 117     else{
 118         # _process_attribute
 119         $name = shift;
 120
 121         my %args = (@_ == 1) ? %{$_[0]} : @_;
 122
 123         defined($name)
 124             or $self->throw_error('You must provide a name for the attribute');
 125
 126         if ($name =~ s/^\+//) { # inherited attributes
 127             my $inherited_attr = $self->find_attribute_by_name($name)
 128                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 129
 130             $attr = $inherited_attr->clone_and_inherit_options(%args);
 131         }
 132         else{
 133             my($attribute_class, @traits) = $self->attribute_metaclass->interpolate_class(\%args);
 134             $args{traits} = \@traits if @traits;
 135
 136             $attr = $attribute_class->new($name, %args);
 137         }
 138     }
 139
 140     weaken( $attr->{associated_class} = $self );
 141
 142     $self->{attributes}{$attr->name} = $attr;
 143     $attr->install_accessors();
 144
 145     if(_MOUSE_VERBOSE && !$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 146         Carp::cluck(qq{Attribute (}.$attr->name.qq{) of class }.$self->name.qq{ has no associated methods (did you mean to provide an "is" argument?)});
 147     }
 148     return $attr;
 149 }
 150
 151 sub compute_all_applicable_attributes {
 152     Carp::cluck('compute_all_applicable_attributes() has been deprecated')
 153         if _MOUSE_VERBOSE;
 154     return shift->get_all_attributes(@_)
 155 }
 156
 157 sub linearized_isa;
 158
 159 sub new_object {
 160     my $self = shift;
 161     my %args = (@_ == 1 ? %{$_[0]} : @_);
 162
 163     my $object = bless {}, $self->name;
 164
 165     $self->_initialize_object($object, \%args);
 166     return $object;
 167 }
 168
 169 sub _initialize_object{
 170     my($self, $object, $args) = @_;
 171
 172     my @triggers_queue;
 173
 174     foreach my $attribute ($self->get_all_attributes) {
 175         my $from = $attribute->init_arg;
 176         my $key  = $attribute->name;
 177
 178         if (defined($from) && exists($args->{$from})) {
 179             $object->{$key} = $attribute->_coerce_and_verify($args->{$from}, $object);
 180
 181             weaken($object->{$key})
 182                 if ref($object->{$key}) && $attribute->is_weak_ref;
 183
 184             if ($attribute->has_trigger) {
 185                 push @triggers_queue, [ $attribute->trigger, $object->{$key} ];
 186             }
 187         }
 188         else {
 189             if ($attribute->has_default || $attribute->has_builder) {
 190                 unless ($attribute->is_lazy) {
 191                     my $default = $attribute->default;
 192                     my $builder = $attribute->builder;
 193                     my $value =   $builder                ? $object->$builder()
 194                                 : ref($default) eq 'CODE' ? $object->$default()
 195                                 :                           $default;
 196
 197                     $object->{$key} = $attribute->_coerce_and_verify($value, $object);
 198
 199                     weaken($object->{$key})
 200                         if ref($object->{$key}) && $attribute->is_weak_ref;
 201                 }
 202             }
 203             else {
 204                 if ($attribute->is_required) {
 205                     $self->throw_error("Attribute (".$attribute->name.") is required");
 206                 }
 207             }
 208         }
 209     }
 210
 211     foreach my $trigger_and_value(@triggers_queue){
 212         my($trigger, $value) = @{$trigger_and_value};
 213         $trigger->($object, $value);
 214     }
 215
 216     if($self->is_anon_class){
 217         $object->{__METACLASS__} = $self;
 218     }
 219
 220     return $object;
 221 }
 222
 223 sub clone_object {
 224     my $class  = shift;
 225     my $object = shift;
 226     my %params = (@_ == 1) ? %{$_[0]} : @_;
 227
 228     (blessed($object) && $object->isa($class->name))
 229         || $class->throw_error("You must pass an instance of the metaclass (" . $class->name . "), not ($object)");
 230
 231     my $cloned = bless { %$object }, ref $object;
 232     $class->_initialize_object($cloned, \%params);
 233
 234     return $cloned;
 235 }
 236
 237 sub clone_instance {
 238     my ($class, $instance, %params) = @_;
 239
 240     Carp::cluck('clone_instance has been deprecated. Use clone_object instead')
 241         if _MOUSE_VERBOSE;
 242     return $class->clone_object($instance, %params);
 243 }
 244
 245 sub make_immutable {
 246     my $self = shift;
 247     my %args = (
 248         inline_constructor => 1,
 249         inline_destructor  => 1,
 250         constructor_name   => 'new',
 251         @_,
 252     );
 253
 254     $self->{is_immutable}++;
 255
 256     if ($args{inline_constructor}) {
 257         $self->add_method($args{constructor_name} =>
 258             $self->constructor_class->_generate_constructor($self, \%args));
 259     }
 260
 261     if ($args{inline_destructor}) {
 262         $self->add_method(DESTROY =>
 263             $self->destructor_class->_generate_destructor($self, \%args));
 264     }
 265
 266     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 267     # at the end of a source file.
 268     return 1;
 269 }
 270
 271 sub make_mutable { not_supported }
 272
 273 sub is_immutable {  $_[0]->{is_immutable} }
 274 sub is_mutable   { !$_[0]->{is_immutable} }
 275
 276 sub _install_modifier_pp{
 277     my( $self, $type, $name, $code ) = @_;
 278     my $into = $self->name;
 279
 280     my $original = $into->can($name)
 281         or $self->throw_error("The method '$name' is not found in the inheritance hierarchy for class $into");
 282
 283     my $modifier_table = $self->{modifiers}{$name};
 284
 285     if(!$modifier_table){
 286         my(@before, @after, @around, $cache, $modified);
 287
 288         $cache = $original;
 289
 290         $modified = sub {
 291             for my $c (@before) { $c->(@_) }
 292
 293             if(wantarray){ # list context
 294                 my @rval = $cache->(@_);
 295
 296                 for my $c(@after){ $c->(@_) }
 297                 return @rval;
 298             }
 299             elsif(defined wantarray){ # scalar context
 300                 my $rval = $cache->(@_);
 301
 302                 for my $c(@after){ $c->(@_) }
 303                 return $rval;
 304             }
 305             else{ # void context
 306                 $cache->(@_);
 307
 308                 for my $c(@after){ $c->(@_) }
 309                 return;
 310             }
 311         };
 312
 313         $self->{modifiers}{$name} = $modifier_table = {
 314             original => $original,
 315
 316             before   => \@before,
 317             after    => \@after,
 318             around   => \@around,
 319
 320             cache    => \$cache, # cache for around modifiers
 321         };
 322
 323         $self->add_method($name => $modified);
 324     }
 325
 326     if($type eq 'before'){
 327         unshift @{$modifier_table->{before}}, $code;
 328     }
 329     elsif($type eq 'after'){
 330         push @{$modifier_table->{after}}, $code;
 331     }
 332     else{ # around
 333         push @{$modifier_table->{around}}, $code;
 334
 335         my $next = ${ $modifier_table->{cache} };
 336         ${ $modifier_table->{cache} } = sub{ $code->($next, @_) };
 337     }
 338
 339     return;
 340 }
 341
 342 sub _install_modifier {
 343     my ( $self, $type, $name, $code ) = @_;
 344
 345     # load Class::Method::Modifiers first
 346     my $no_cmm_fast = do{
 347         local $@;
 348         eval q{ require Class::Method::Modifiers::Fast };
 349         $@;
 350     };
 351
 352     my $impl;
 353     if($no_cmm_fast){
 354         $impl = \&_install_modifier_pp;
 355     }
 356     else{
 357         my $install_modifier = Class::Method::Modifiers::Fast->can('_install_modifier');
 358         $impl = sub {
 359             my ( $self, $type, $name, $code ) = @_;
 360             my $into = $self->name;
 361             $install_modifier->($into, $type, $name, $code);
 362
 363             $self->add_method($name => do{
 364                 no strict 'refs';
 365                 \&{ $into . '::' . $name };
 366             });
 367             return;
 368         };
 369     }
 370
 371     # replace this method itself :)
 372     {
 373         no warnings 'redefine';
 374         *_install_modifier = $impl;
 375     }
 376
 377     $self->$impl( $type, $name, $code );
 378 }
 379
 380 sub add_before_method_modifier {
 381     my ( $self, $name, $code ) = @_;
 382     $self->_install_modifier( 'before', $name, $code );
 383 }
 384
 385 sub add_around_method_modifier {
 386     my ( $self, $name, $code ) = @_;
 387     $self->_install_modifier( 'around', $name, $code );
 388 }
 389
 390 sub add_after_method_modifier {
 391     my ( $self, $name, $code ) = @_;
 392     $self->_install_modifier( 'after', $name, $code );
 393 }
 394
 395 sub add_override_method_modifier {
 396     my ($self, $name, $code) = @_;
 397
 398     if($self->has_method($name)){
 399         $self->throw_error("Cannot add an override method if a local method is already present");
 400     }
 401
 402     my $package = $self->name;
 403
 404     my $super_body = $package->can($name)
 405         or $self->throw_error("You cannot override '$name' because it has no super method");
 406
 407     $self->add_method($name => sub {
 408         local $Mouse::SUPER_PACKAGE = $package;
 409         local $Mouse::SUPER_BODY    = $super_body;
 410         local @Mouse::SUPER_ARGS    = @_;
 411
 412         $code->(@_);
 413     });
 414     return;
 415 }
 416
 417 sub add_augment_method_modifier {
 418     my ($self, $name, $code) = @_;
 419     if($self->has_method($name)){
 420         $self->throw_error("Cannot add an augment method if a local method is already present");
 421     }
 422
 423     my $super = $self->find_method_by_name($name)
 424         or $self->throw_error("You cannot augment '$name' because it has no super method");
 425
 426     my $super_package = $super->package_name;
 427     my $super_body    = $super->body;
 428
 429     $self->add_method($name => sub{
 430         local $Mouse::INNER_BODY{$super_package} = $code;
 431         local $Mouse::INNER_ARGS{$super_package} = [@_];
 432         $super_body->(@_);
 433     });
 434     return;
 435 }
 436
 437 sub does_role {
 438     my ($self, $role_name) = @_;
 439
 440     (defined $role_name)
 441         || $self->throw_error("You must supply a role name to look for");
 442
 443     for my $class ($self->linearized_isa) {
 444         my $meta = Mouse::Util::get_metaclass_by_name($class)
 445             or next;
 446
 447         for my $role (@{ $meta->roles }) {
 448
 449             return 1 if $role->does_role($role_name);
 450         }
 451     }
 452
 453     return 0;
 454 }
 455
 456 1;
 457 __END__
 458
 459 =head1 NAME
 460
 461 Mouse::Meta::Class - The Mouse class metaclass
 462
 463 =head1 VERSION
 464
 465 This document describes Mouse version 0.40_05
 466
 467 =head1 METHODS
 468
 469 =head2 C<< initialize(ClassName) -> Mouse::Meta::Class >>
 470
 471 Finds or creates a C<Mouse::Meta::Class> instance for the given ClassName. Only
 472 one instance should exist for a given class.
 473
 474 =head2 C<< name -> ClassName >>
 475
 476 Returns the name of the owner class.
 477
 478 =head2 C<< superclasses -> ClassNames >> C<< superclass(ClassNames) >>
 479
 480 Gets (or sets) the list of superclasses of the owner class.
 481
 482 =head2 C<< add_method(name => CodeRef) >>
 483
 484 Adds a method to the owner class.
 485
 486 =head2 C<< has_method(name) -> Bool >>
 487
 488 Returns whether we have a method with the given name.
 489
 490 =head2 C<< get_method(name) -> Mouse::Meta::Method | undef >>
 491
 492 Returns a L<Mouse::Meta::Method> with the given name.
 493
 494 Note that you can also use C<< $metaclass->name->can($name) >> for a method body.
 495
 496 =head2 C<< get_method_list -> Names >>
 497
 498 Returns a list of method names which are defined in the local class.
 499 If you want a list of all applicable methods for a class, use the
 500 C<get_all_methods> method.
 501
 502 =head2 C<< get_all_methods -> (Mouse::Meta::Method) >>
 503
 504 Return the list of all L<Mouse::Meta::Method> instances associated with
 505 the class and its superclasses.
 506
 507 =head2 C<< add_attribute(name => spec | Mouse::Meta::Attribute) >>
 508
 509 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 510 class.
 511
 512 =head2 C<< has_attribute(Name) -> Bool >>
 513
 514 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 515
 516 =head2 C<< get_attribute Name -> Mouse::Meta::Attribute | undef >>
 517
 518 Returns the L<Mouse::Meta::Attribute> with the given name.
 519
 520 =head2 C<< get_attribute_list -> Names >>
 521
 522 Returns a list of attribute names which are defined in the local
 523 class. If you want a list of all applicable attributes for a class,
 524 use the C<get_all_attributes> method.
 525
 526 =head2 C<< get_all_attributes -> (Mouse::Meta::Attribute) >>
 527
 528 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 529 this class and its superclasses.
 530
 531 =head2 C<< linearized_isa -> [ClassNames] >>
 532
 533 Returns the list of classes in method dispatch order, with duplicates removed.
 534
 535 =head2 C<< new_object(Parameters) -> Instance >>
 536
 537 Creates a new instance.
 538
 539 =head2 C<< clone_object(Instance, Parameters) -> Instance >>
 540
 541 Clones the given instance which must be an instance governed by this
 542 metaclass.
 543
 544 =head2 C<< throw_error(Message, Parameters) >>
 545
 546 Throws an error with the given message.
 547
 548 =head1 SEE ALSO
 549
 550 L<Moose::Meta::Class>
 551
 552 L<Class::MOP::Class>
 553
 554 =cut
 555