lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use Mouse::Util qw/:meta get_linear_isa not_supported/; # enables strict and warnings
   3
   4 use Scalar::Util qw/blessed weaken/;
   5
   6 use Mouse::Meta::Module;
   7 our @ISA = qw(Mouse::Meta::Module);
   8
   9 our @CARP_NOT = qw(Mouse); # trust Mouse
  10
  11 sub attribute_metaclass;
  12 sub method_metaclass;
  13
  14 sub constructor_class;
  15 sub destructor_class;
  16
  17
  18 sub _construct_meta {
  19     my($class, %args) = @_;
  20
  21     $args{attributes} = {};
  22     $args{methods}    = {};
  23     $args{roles}      = [];
  24
  25     $args{superclasses} = do {
  26         no strict 'refs';
  27         \@{ $args{package} . '::ISA' };
  28     };
  29
  30     my $self = bless \%args, ref($class) || $class;
  31     if(ref($self) ne __PACKAGE__){
  32         $self->meta->_initialize_object($self, \%args);
  33     }
  34     return $self;
  35 }
  36
  37 sub create_anon_class{
  38     my $self = shift;
  39     return $self->create(undef, @_);
  40 }
  41
  42 sub is_anon_class;
  43
  44 sub roles;
  45
  46 sub calculate_all_roles {
  47     my $self = shift;
  48     my %seen;
  49     return grep { !$seen{ $_->name }++ }
  50            map  { $_->calculate_all_roles } @{ $self->roles };
  51 }
  52
  53 sub superclasses {
  54     my $self = shift;
  55
  56     if (@_) {
  57         foreach my $super(@_){
  58             Mouse::Util::load_class($super);
  59             my $meta = Mouse::Util::get_metaclass_by_name($super);
  60
  61             next if not defined $meta;
  62
  63             if(Mouse::Util::is_a_metarole($meta)){
  64                 $self->throw_error("You cannot inherit from a Mouse Role ($super)");
  65             }
  66
  67             next if $self->isa(ref $meta); # _superclass_meta_is_compatible
  68
  69             $self->_reconcile_with_superclass_meta($meta);
  70         }
  71         @{ $self->{superclasses} } = @_;
  72     }
  73
  74     return @{ $self->{superclasses} };
  75 }
  76 my @MetaClassTypes = (
  77     'attribute',   # Mouse::Meta::Attribute
  78     'method',      # Mouse::Meta::Method
  79     'constructor', # Mouse::Meta::Method::Constructor
  80     'destructor',  # Mouse::Meta::Method::Destructor
  81 );
  82
  83 sub _reconcile_with_superclass_meta {
  84     my($self, $other) = @_;
  85
  86     # find incompatible traits
  87     my %metaroles;
  88     foreach my $metaclass_type(@MetaClassTypes){
  89         my $accessor = $self->can($metaclass_type . '_metaclass')
  90             || $self->can($metaclass_type . '_class');
  91
  92         my $other_c = $other->$accessor();
  93         my $self_c  = $self->$accessor();
  94
  95         if(!$self_c->isa($other_c)){
  96             $metaroles{$metaclass_type}
  97                 = [ $self_c->meta->_collect_roles($other_c->meta) ];
  98         }
  99     }
 100
 101     $metaroles{class} = [$self->meta->_collect_roles($other->meta)];
 102
 103     #use Data::Dumper; print Data::Dumper->new([\%metaroles], ['*metaroles'])->Indent(1)->Dump;
 104
 105     require Mouse::Util::MetaRole;
 106     $_[0] = Mouse::Util::MetaRole::apply_metaroles(
 107         for             => $self,
 108         class_metaroles => \%metaroles,
 109     );
 110     return;
 111 }
 112
 113 sub _collect_roles {
 114     my ($self, $other) = @_;
 115
 116     # find common ancestor
 117     my @self_lin_isa  = $self->linearized_isa;
 118     my @other_lin_isa = $other->linearized_isa;
 119
 120     my(@self_anon_supers, @other_anon_supers);
 121     push @self_anon_supers,  shift @self_lin_isa  while $self_lin_isa[0]->meta->is_anon_class;
 122     push @other_anon_supers, shift @other_lin_isa while $other_lin_isa[0]->meta->is_anon_class;
 123
 124     my $common_ancestor = $self_lin_isa[0] eq $other_lin_isa[0] && $self_lin_isa[0];
 125
 126     if(!$common_ancestor){
 127         $self->throw_error(sprintf '%s cannot have %s as a super class because of their metaclass incompatibility',
 128             $self->name, $other->name);
 129     }
 130
 131     my %seen;
 132     return sort grep { !$seen{$_}++ } ## no critic
 133         (map{ $_->name } map{ $_->meta->calculate_all_roles } @self_anon_supers),
 134         (map{ $_->name } map{ $_->meta->calculate_all_roles } @other_anon_supers),
 135     ;
 136 }
 137
 138
 139 sub find_method_by_name{
 140     my($self, $method_name) = @_;
 141     defined($method_name)
 142         or $self->throw_error('You must define a method name to find');
 143
 144     foreach my $class( $self->linearized_isa ){
 145         my $method = $self->initialize($class)->get_method($method_name);
 146         return $method if defined $method;
 147     }
 148     return undef;
 149 }
 150
 151 sub get_all_methods {
 152     my($self) = @_;
 153     return map{ $self->find_method_by_name($_) } $self->get_all_method_names;
 154 }
 155
 156 sub get_all_method_names {
 157     my $self = shift;
 158     my %uniq;
 159     return grep { $uniq{$_}++ == 0 }
 160             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
 161             $self->linearized_isa;
 162 }
 163
 164 sub find_attribute_by_name{
 165     my($self, $name) = @_;
 166     my $attr;
 167     foreach my $class($self->linearized_isa){
 168         my $meta = Mouse::Util::get_metaclass_by_name($class) or next;
 169         $attr = $meta->get_attribute($name) and last;
 170     }
 171     return $attr;
 172 }
 173
 174 sub add_attribute {
 175     my $self = shift;
 176
 177     my($attr, $name);
 178
 179     if(blessed $_[0]){
 180         $attr = $_[0];
 181
 182         $attr->isa('Mouse::Meta::Attribute')
 183             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
 184
 185         $name = $attr->name;
 186     }
 187     else{
 188         # _process_attribute
 189         $name = shift;
 190
 191         my %args = (@_ == 1) ? %{$_[0]} : @_;
 192
 193         defined($name)
 194             or $self->throw_error('You must provide a name for the attribute');
 195
 196         if ($name =~ s/^\+//) { # inherited attributes
 197             my $inherited_attr = $self->find_attribute_by_name($name)
 198                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 199
 200             $attr = $inherited_attr->clone_and_inherit_options(%args);
 201         }
 202         else{
 203             my($attribute_class, @traits) = $self->attribute_metaclass->interpolate_class(\%args);
 204             $args{traits} = \@traits if @traits;
 205
 206             $attr = $attribute_class->new($name, %args);
 207         }
 208     }
 209
 210     weaken( $attr->{associated_class} = $self );
 211
 212     # install accessors first
 213     $attr->install_accessors();
 214
 215     # then register the attribute to the metaclass
 216     $attr->{insertion_order} = keys %{ $self->{attributes} };
 217     $self->{attributes}{$attr->name} = $attr;
 218
 219     if(!$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 220         Carp::carp(qq{Attribute ($name) of class }.$self->name
 221             .qq{ has no associated methods (did you mean to provide an "is" argument?)});
 222     }
 223     return $attr;
 224 }
 225
 226 sub linearized_isa;
 227
 228 sub new_object;
 229 sub clone_object;
 230
 231 sub immutable_options {
 232     my ( $self, @args ) = @_;
 233
 234     return (
 235         inline_constructor => 1,
 236         inline_destructor  => 1,
 237         constructor_name   => 'new',
 238         @args,
 239     );
 240 }
 241
 242 sub make_immutable {
 243     my $self = shift;
 244     my %args = $self->immutable_options(@_);
 245
 246     $self->{is_immutable}++;
 247
 248     if ($args{inline_constructor}) {
 249         $self->add_method($args{constructor_name} =>
 250             Mouse::Util::load_class($self->constructor_class)
 251                 ->_generate_constructor($self, \%args));
 252     }
 253
 254     if ($args{inline_destructor}) {
 255         $self->add_method(DESTROY =>
 256             Mouse::Util::load_class($self->destructor_class)
 257                 ->_generate_destructor($self, \%args));
 258     }
 259
 260     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 261     # at the end of a source file.
 262     return 1;
 263 }
 264
 265 sub make_mutable {
 266     my($self) = @_;
 267     $self->{is_immutable} = 0;
 268     return;
 269 }
 270
 271 sub is_immutable;
 272 sub is_mutable   { !$_[0]->is_immutable }
 273
 274 sub _install_modifier {
 275     my( $self, $type, $name, $code ) = @_;
 276     my $into = $self->name;
 277
 278     my $original = $into->can($name)
 279         or $self->throw_error("The method '$name' was not found in the inheritance hierarchy for $into");
 280
 281     my $modifier_table = $self->{modifiers}{$name};
 282
 283     if(!$modifier_table){
 284         my(@before, @after, $cache);
 285
 286         $cache = $original;
 287
 288         my $around_only = ($type eq 'around');
 289
 290         my $modified = sub {
 291             if($around_only) {
 292                 return $cache->(@_);
 293             }
 294
 295             for my $c (@before) { $c->(@_) }
 296
 297             if(wantarray){ # list context
 298                 my @rval = $cache->(@_);
 299
 300                 for my $c(@after){ $c->(@_) }
 301                 return @rval;
 302             }
 303             elsif(defined wantarray){ # scalar context
 304                 my $rval = $cache->(@_);
 305
 306                 for my $c(@after){ $c->(@_) }
 307                 return $rval;
 308             }
 309             else{ # void context
 310                 $cache->(@_);
 311
 312                 for my $c(@after){ $c->(@_) }
 313                 return;
 314             }
 315         };
 316
 317         $self->{modifiers}{$name} = $modifier_table = {
 318             original => $original,
 319
 320             before   => \@before,
 321             after    => \@after,
 322             around   => \my @around,
 323             around_only => \$around_only,
 324
 325             cache    => \$cache, # cache for around modifiers
 326         };
 327
 328         $self->add_method($name => $modified);
 329     }
 330
 331     if($type eq 'before'){
 332         ${$modifier_table->{around_only}} = 0;
 333         unshift @{$modifier_table->{before}}, $code;
 334     }
 335     elsif($type eq 'after'){
 336         ${$modifier_table->{around_only}} = 0;
 337         push @{$modifier_table->{after}}, $code;
 338     }
 339     else{ # around
 340         push @{$modifier_table->{around}}, $code;
 341
 342         my $next = ${ $modifier_table->{cache} };
 343         ${ $modifier_table->{cache} } = sub{ $code->($next, @_) };
 344     }
 345
 346     return;
 347 }
 348
 349 sub add_before_method_modifier {
 350     my ( $self, $name, $code ) = @_;
 351     $self->_install_modifier( 'before', $name, $code );
 352 }
 353
 354 sub add_around_method_modifier {
 355     my ( $self, $name, $code ) = @_;
 356     $self->_install_modifier( 'around', $name, $code );
 357 }
 358
 359 sub add_after_method_modifier {
 360     my ( $self, $name, $code ) = @_;
 361     $self->_install_modifier( 'after', $name, $code );
 362 }
 363
 364 sub add_override_method_modifier {
 365     my ($self, $name, $code) = @_;
 366
 367     if($self->has_method($name)){
 368         $self->throw_error("Cannot add an override method if a local method is already present");
 369     }
 370
 371     my $package = $self->name;
 372
 373     my $super_body = $package->can($name)
 374         or $self->throw_error("You cannot override '$name' because it has no super method");
 375
 376     $self->add_method($name => sub {
 377         local $Mouse::SUPER_PACKAGE = $package;
 378         local $Mouse::SUPER_BODY    = $super_body;
 379         local @Mouse::SUPER_ARGS    = @_;
 380
 381         $code->(@_);
 382     });
 383     return;
 384 }
 385
 386 sub add_augment_method_modifier {
 387     my ($self, $name, $code) = @_;
 388     if($self->has_method($name)){
 389         $self->throw_error("Cannot add an augment method if a local method is already present");
 390     }
 391
 392     my $super = $self->find_method_by_name($name)
 393         or $self->throw_error("You cannot augment '$name' because it has no super method");
 394
 395     my $super_package = $super->package_name;
 396     my $super_body    = $super->body;
 397
 398     $self->add_method($name => sub{
 399         local $Mouse::INNER_BODY{$super_package} = $code;
 400         local $Mouse::INNER_ARGS{$super_package} = [@_];
 401         $super_body->(@_);
 402     });
 403     return;
 404 }
 405
 406 sub does_role {
 407     my ($self, $role_name) = @_;
 408
 409     (defined $role_name)
 410         || $self->throw_error("You must supply a role name to look for");
 411
 412     $role_name = $role_name->name if ref $role_name;
 413
 414     for my $class ($self->linearized_isa) {
 415         my $meta = Mouse::Util::get_metaclass_by_name($class)
 416             or next;
 417
 418         for my $role (@{ $meta->roles }) {
 419
 420             return 1 if $role->does_role($role_name);
 421         }
 422     }
 423
 424     return 0;
 425 }
 426
 427 1;
 428 __END__
 429
 430 =head1 NAME
 431
 432 Mouse::Meta::Class - The Mouse class metaclass
 433
 434 =head1 VERSION
 435
 436 This document describes Mouse version 0.67
 437
 438 =head1 METHODS
 439
 440 =head2 C<< initialize(ClassName) -> Mouse::Meta::Class >>
 441
 442 Finds or creates a C<Mouse::Meta::Class> instance for the given ClassName. Only
 443 one instance should exist for a given class.
 444
 445 =head2 C<< name -> ClassName >>
 446
 447 Returns the name of the owner class.
 448
 449 =head2 C<< superclasses -> ClassNames >> C<< superclass(ClassNames) >>
 450
 451 Gets (or sets) the list of superclasses of the owner class.
 452
 453 =head2 C<< add_method(name => CodeRef) >>
 454
 455 Adds a method to the owner class.
 456
 457 =head2 C<< has_method(name) -> Bool >>
 458
 459 Returns whether we have a method with the given name.
 460
 461 =head2 C<< get_method(name) -> Mouse::Meta::Method | undef >>
 462
 463 Returns a L<Mouse::Meta::Method> with the given name.
 464
 465 Note that you can also use C<< $metaclass->name->can($name) >> for a method body.
 466
 467 =head2 C<< get_method_list -> Names >>
 468
 469 Returns a list of method names which are defined in the local class.
 470 If you want a list of all applicable methods for a class, use the
 471 C<get_all_methods> method.
 472
 473 =head2 C<< get_all_methods -> (Mouse::Meta::Method) >>
 474
 475 Return the list of all L<Mouse::Meta::Method> instances associated with
 476 the class and its superclasses.
 477
 478 =head2 C<< add_attribute(name => spec | Mouse::Meta::Attribute) >>
 479
 480 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 481 class.
 482
 483 =head2 C<< has_attribute(Name) -> Bool >>
 484
 485 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 486
 487 =head2 C<< get_attribute Name -> Mouse::Meta::Attribute | undef >>
 488
 489 Returns the L<Mouse::Meta::Attribute> with the given name.
 490
 491 =head2 C<< get_attribute_list -> Names >>
 492
 493 Returns a list of attribute names which are defined in the local
 494 class. If you want a list of all applicable attributes for a class,
 495 use the C<get_all_attributes> method.
 496
 497 =head2 C<< get_all_attributes -> (Mouse::Meta::Attribute) >>
 498
 499 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 500 this class and its superclasses.
 501
 502 =head2 C<< linearized_isa -> [ClassNames] >>
 503
 504 Returns the list of classes in method dispatch order, with duplicates removed.
 505
 506 =head2 C<< new_object(Parameters) -> Instance >>
 507
 508 Creates a new instance.
 509
 510 =head2 C<< clone_object(Instance, Parameters) -> Instance >>
 511
 512 Clones the given instance which must be an instance governed by this
 513 metaclass.
 514
 515 =head2 C<< throw_error(Message, Parameters) >>
 516
 517 Throws an error with the given message.
 518
 519 =head1 SEE ALSO
 520
 521 L<Mouse::Meta::Module>
 522
 523 L<Moose::Meta::Class>
 524
 525 L<Class::MOP::Class>
 526
 527 =cut
 528