lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use Mouse::Util qw/:meta get_linear_isa not_supported/; # enables strict and warnings
   3
   4 use Scalar::Util qw/blessed weaken/;
   5
   6 use Mouse::Meta::Module;
   7 our @ISA = qw(Mouse::Meta::Module);
   8
   9 our @CARP_NOT = qw(Mouse); # trust Mouse
  10
  11 sub attribute_metaclass;
  12 sub method_metaclass;
  13
  14 sub constructor_class;
  15 sub destructor_class;
  16
  17
  18 sub _construct_meta {
  19     my($class, %args) = @_;
  20
  21     $args{attributes} = {};
  22     $args{methods}    = {};
  23     $args{roles}      = [];
  24
  25     $args{superclasses} = do {
  26         no strict 'refs';
  27         \@{ $args{package} . '::ISA' };
  28     };
  29
  30     my $self = bless \%args, ref($class) || $class;
  31     if(ref($self) ne __PACKAGE__){
  32         $self->meta->_initialize_object($self, \%args);
  33     }
  34     return $self;
  35 }
  36
  37 sub create_anon_class{
  38     my $self = shift;
  39     return $self->create(undef, @_);
  40 }
  41
  42 sub is_anon_class;
  43
  44 sub roles;
  45
  46 sub calculate_all_roles {
  47     my $self = shift;
  48     my %seen;
  49     return grep { !$seen{ $_->name }++ }
  50            map  { $_->calculate_all_roles } @{ $self->roles };
  51 }
  52
  53 sub superclasses {
  54     my $self = shift;
  55
  56     if (@_) {
  57         foreach my $super(@_){
  58             Mouse::Util::load_class($super);
  59             my $meta = Mouse::Util::get_metaclass_by_name($super);
  60
  61             next if not defined $meta;
  62
  63             if(Mouse::Util::is_a_metarole($meta)){
  64                 $self->throw_error("You cannot inherit from a Mouse Role ($super)");
  65             }
  66
  67             next if $self->isa(ref $meta); # _superclass_meta_is_compatible
  68
  69             $self->_reconcile_with_superclass_meta($meta);
  70         }
  71         @{ $self->{superclasses} } = @_;
  72     }
  73
  74     return @{ $self->{superclasses} };
  75 }
  76 my @MetaClassTypes = (
  77     'attribute',   # Mouse::Meta::Attribute
  78     'method',      # Mouse::Meta::Method
  79     'constructor', # Mouse::Meta::Method::Constructor
  80     'destructor',  # Mouse::Meta::Method::Destructor
  81 );
  82
  83 sub _reconcile_with_superclass_meta {
  84     my($self, $other) = @_;
  85
  86     # find incompatible traits
  87     my %metaroles;
  88     foreach my $metaclass_type(@MetaClassTypes){
  89         my $accessor = $self->can($metaclass_type . '_metaclass')
  90             || $self->can($metaclass_type . '_class');
  91
  92         my $other_c = $other->$accessor();
  93         my $self_c  = $self->$accessor();
  94
  95         if(!$self_c->isa($other_c)){
  96             $metaroles{$metaclass_type}
  97                 = [ $self_c->meta->_collect_roles($other_c->meta) ];
  98         }
  99     }
 100
 101     $metaroles{class} = [$self->meta->_collect_roles($other->meta)];
 102
 103     #use Data::Dumper; print Data::Dumper->new([\%metaroles], ['*metaroles'])->Indent(1)->Dump;
 104
 105     require Mouse::Util::MetaRole;
 106     $_[0] = Mouse::Util::MetaRole::apply_metaroles(
 107         for             => $self,
 108         class_metaroles => \%metaroles,
 109     );
 110     return;
 111 }
 112
 113 sub _collect_roles {
 114     my ($self, $other) = @_;
 115
 116     # find common ancestor
 117     my @self_lin_isa  = $self->linearized_isa;
 118     my @other_lin_isa = $other->linearized_isa;
 119
 120     my(@self_anon_supers, @other_anon_supers);
 121     push @self_anon_supers,  shift @self_lin_isa  while $self_lin_isa[0]->meta->is_anon_class;
 122     push @other_anon_supers, shift @other_lin_isa while $other_lin_isa[0]->meta->is_anon_class;
 123
 124     my $common_ancestor = $self_lin_isa[0] eq $other_lin_isa[0] && $self_lin_isa[0];
 125
 126     if(!$common_ancestor){
 127         $self->throw_error(sprintf '%s cannot have %s as a super class because of their metaclass incompatibility',
 128             $self->name, $other->name);
 129     }
 130
 131     my %seen;
 132     return sort grep { !$seen{$_}++ } ## no critic
 133         (map{ $_->name } map{ $_->meta->calculate_all_roles } @self_anon_supers),
 134         (map{ $_->name } map{ $_->meta->calculate_all_roles } @other_anon_supers),
 135     ;
 136 }
 137
 138
 139 sub find_method_by_name{
 140     my($self, $method_name) = @_;
 141     defined($method_name)
 142         or $self->throw_error('You must define a method name to find');
 143
 144     foreach my $class( $self->linearized_isa ){
 145         my $method = $self->initialize($class)->get_method($method_name);
 146         return $method if defined $method;
 147     }
 148     return undef;
 149 }
 150
 151 sub get_all_methods {
 152     my($self) = @_;
 153     return map{ $self->find_method_by_name($_) } $self->get_all_method_names;
 154 }
 155
 156 sub get_all_method_names {
 157     my $self = shift;
 158     my %uniq;
 159     return grep { $uniq{$_}++ == 0 }
 160             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
 161             $self->linearized_isa;
 162 }
 163
 164 sub find_attribute_by_name{
 165     my($self, $name) = @_;
 166     my $attr;
 167     foreach my $class($self->linearized_isa){
 168         my $meta = Mouse::Util::get_metaclass_by_name($class) or next;
 169         $attr = $meta->get_attribute($name) and last;
 170     }
 171     return $attr;
 172 }
 173
 174 sub add_attribute {
 175     my $self = shift;
 176
 177     my($attr, $name);
 178
 179     if(blessed $_[0]){
 180         $attr = $_[0];
 181
 182         $attr->isa('Mouse::Meta::Attribute')
 183             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
 184
 185         $name = $attr->name;
 186     }
 187     else{
 188         # _process_attribute
 189         $name = shift;
 190
 191         my %args = (@_ == 1) ? %{$_[0]} : @_;
 192
 193         defined($name)
 194             or $self->throw_error('You must provide a name for the attribute');
 195
 196         if ($name =~ s/^\+//) { # inherited attributes
 197             my $inherited_attr = $self->find_attribute_by_name($name)
 198                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 199
 200             $attr = $inherited_attr->clone_and_inherit_options(%args);
 201         }
 202         else{
 203             my($attribute_class, @traits) = $self->attribute_metaclass->interpolate_class(\%args);
 204             $args{traits} = \@traits if @traits;
 205
 206             $attr = $attribute_class->new($name, %args);
 207         }
 208     }
 209
 210     weaken( $attr->{associated_class} = $self );
 211
 212     $attr->{insertion_order} = keys %{ $self->{attributes} };
 213     $self->{attributes}{$attr->name} = $attr;
 214     $attr->install_accessors();
 215
 216     if(!$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 217         Carp::carp(qq{Attribute ($name) of class }.$self->name
 218             .qq{ has no associated methods (did you mean to provide an "is" argument?)});
 219     }
 220     return $attr;
 221 }
 222
 223 sub compute_all_applicable_attributes { # DEPRECATED
 224     Carp::cluck('compute_all_applicable_attributes() has been deprecated. Use get_all_attributes() instead');
 225
 226     return shift->get_all_attributes(@_)
 227 }
 228
 229 sub linearized_isa;
 230
 231 sub new_object;
 232 sub clone_object;
 233
 234
 235 sub clone_instance { # DEPRECATED
 236     my ($class, $instance, %params) = @_;
 237
 238     Carp::cluck('clone_instance() has been deprecated. Use clone_object() instead');
 239
 240     return $class->clone_object($instance, %params);
 241 }
 242
 243
 244 sub immutable_options {
 245     my ( $self, @args ) = @_;
 246
 247     return (
 248         inline_constructor => 1,
 249         inline_destructor  => 1,
 250         constructor_name   => 'new',
 251         @args,
 252     );
 253 }
 254
 255
 256 sub make_immutable {
 257     my $self = shift;
 258     my %args = $self->immutable_options(@_);
 259
 260     $self->{is_immutable}++;
 261
 262     if ($args{inline_constructor}) {
 263         $self->add_method($args{constructor_name} =>
 264             Mouse::Util::load_class($self->constructor_class)
 265                 ->_generate_constructor($self, \%args));
 266     }
 267
 268     if ($args{inline_destructor}) {
 269         $self->add_method(DESTROY =>
 270             Mouse::Util::load_class($self->destructor_class)
 271                 ->_generate_destructor($self, \%args));
 272     }
 273
 274     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 275     # at the end of a source file.
 276     return 1;
 277 }
 278
 279 sub make_mutable {
 280     my($self) = @_;
 281     $self->{is_immutable} = 0;
 282     return;
 283 }
 284
 285 sub is_immutable;
 286 sub is_mutable   { !$_[0]->is_immutable }
 287
 288 sub _install_modifier_pp{
 289     my( $self, $type, $name, $code ) = @_;
 290     my $into = $self->name;
 291
 292     my $original = $into->can($name)
 293         or $self->throw_error("The method '$name' is not found in the inheritance hierarchy for class $into");
 294
 295     my $modifier_table = $self->{modifiers}{$name};
 296
 297     if(!$modifier_table){
 298         my(@before, @after, @around, $cache, $modified);
 299
 300         $cache = $original;
 301
 302         $modified = sub {
 303             for my $c (@before) { $c->(@_) }
 304
 305             if(wantarray){ # list context
 306                 my @rval = $cache->(@_);
 307
 308                 for my $c(@after){ $c->(@_) }
 309                 return @rval;
 310             }
 311             elsif(defined wantarray){ # scalar context
 312                 my $rval = $cache->(@_);
 313
 314                 for my $c(@after){ $c->(@_) }
 315                 return $rval;
 316             }
 317             else{ # void context
 318                 $cache->(@_);
 319
 320                 for my $c(@after){ $c->(@_) }
 321                 return;
 322             }
 323         };
 324
 325         $self->{modifiers}{$name} = $modifier_table = {
 326             original => $original,
 327
 328             before   => \@before,
 329             after    => \@after,
 330             around   => \@around,
 331
 332             cache    => \$cache, # cache for around modifiers
 333         };
 334
 335         $self->add_method($name => $modified);
 336     }
 337
 338     if($type eq 'before'){
 339         unshift @{$modifier_table->{before}}, $code;
 340     }
 341     elsif($type eq 'after'){
 342         push @{$modifier_table->{after}}, $code;
 343     }
 344     else{ # around
 345         push @{$modifier_table->{around}}, $code;
 346
 347         my $next = ${ $modifier_table->{cache} };
 348         ${ $modifier_table->{cache} } = sub{ $code->($next, @_) };
 349     }
 350
 351     return;
 352 }
 353
 354 sub _install_modifier {
 355     my ( $self, $type, $name, $code ) = @_;
 356
 357     # load Data::Util first
 358     my $no_cmm_fast = do{
 359         local $@;
 360         eval q{ use Data::Util 0.55 () };
 361         $@;
 362     };
 363
 364     my $impl;
 365     if($no_cmm_fast){
 366         $impl = \&_install_modifier_pp;
 367     }
 368     else{
 369         $impl = sub {
 370             my ( $self, $type, $name, $code ) = @_;
 371             my $into = $self->name;
 372
 373             my $method = Mouse::Util::get_code_ref( $into, $name );
 374
 375             if ( !$method || !Data::Util::subroutine_modifier($method) ) {
 376                 unless ($method) {
 377                     $method = $into->can($name)
 378                         or Carp::confess("The method '$name' is not found in the inheritance hierarchy for class $into");
 379                 }
 380                 $method = Data::Util::modify_subroutine( $method,
 381                     $type => [$code] );
 382
 383                 $self->add_method($name => $method);
 384             }
 385             else {
 386                 Data::Util::subroutine_modifier( $method, $type => $code );
 387                 $self->add_method($name => Mouse::Util::get_code_ref($into, $name));
 388             }
 389
 390             return;
 391         };
 392     }
 393
 394     # replace this method itself :)
 395     {
 396         no warnings 'redefine';
 397         *_install_modifier = $impl;
 398     }
 399
 400     $self->$impl( $type, $name, $code );
 401 }
 402
 403 sub add_before_method_modifier {
 404     my ( $self, $name, $code ) = @_;
 405     $self->_install_modifier( 'before', $name, $code );
 406 }
 407
 408 sub add_around_method_modifier {
 409     my ( $self, $name, $code ) = @_;
 410     $self->_install_modifier( 'around', $name, $code );
 411 }
 412
 413 sub add_after_method_modifier {
 414     my ( $self, $name, $code ) = @_;
 415     $self->_install_modifier( 'after', $name, $code );
 416 }
 417
 418 sub add_override_method_modifier {
 419     my ($self, $name, $code) = @_;
 420
 421     if($self->has_method($name)){
 422         $self->throw_error("Cannot add an override method if a local method is already present");
 423     }
 424
 425     my $package = $self->name;
 426
 427     my $super_body = $package->can($name)
 428         or $self->throw_error("You cannot override '$name' because it has no super method");
 429
 430     $self->add_method($name => sub {
 431         local $Mouse::SUPER_PACKAGE = $package;
 432         local $Mouse::SUPER_BODY    = $super_body;
 433         local @Mouse::SUPER_ARGS    = @_;
 434
 435         $code->(@_);
 436     });
 437     return;
 438 }
 439
 440 sub add_augment_method_modifier {
 441     my ($self, $name, $code) = @_;
 442     if($self->has_method($name)){
 443         $self->throw_error("Cannot add an augment method if a local method is already present");
 444     }
 445
 446     my $super = $self->find_method_by_name($name)
 447         or $self->throw_error("You cannot augment '$name' because it has no super method");
 448
 449     my $super_package = $super->package_name;
 450     my $super_body    = $super->body;
 451
 452     $self->add_method($name => sub{
 453         local $Mouse::INNER_BODY{$super_package} = $code;
 454         local $Mouse::INNER_ARGS{$super_package} = [@_];
 455         $super_body->(@_);
 456     });
 457     return;
 458 }
 459
 460 sub does_role {
 461     my ($self, $role_name) = @_;
 462
 463     (defined $role_name)
 464         || $self->throw_error("You must supply a role name to look for");
 465
 466     $role_name = $role_name->name if ref $role_name;
 467
 468     for my $class ($self->linearized_isa) {
 469         my $meta = Mouse::Util::get_metaclass_by_name($class)
 470             or next;
 471
 472         for my $role (@{ $meta->roles }) {
 473
 474             return 1 if $role->does_role($role_name);
 475         }
 476     }
 477
 478     return 0;
 479 }
 480
 481 1;
 482 __END__
 483
 484 =head1 NAME
 485
 486 Mouse::Meta::Class - The Mouse class metaclass
 487
 488 =head1 VERSION
 489
 490 This document describes Mouse version 0.63
 491
 492 =head1 METHODS
 493
 494 =head2 C<< initialize(ClassName) -> Mouse::Meta::Class >>
 495
 496 Finds or creates a C<Mouse::Meta::Class> instance for the given ClassName. Only
 497 one instance should exist for a given class.
 498
 499 =head2 C<< name -> ClassName >>
 500
 501 Returns the name of the owner class.
 502
 503 =head2 C<< superclasses -> ClassNames >> C<< superclass(ClassNames) >>
 504
 505 Gets (or sets) the list of superclasses of the owner class.
 506
 507 =head2 C<< add_method(name => CodeRef) >>
 508
 509 Adds a method to the owner class.
 510
 511 =head2 C<< has_method(name) -> Bool >>
 512
 513 Returns whether we have a method with the given name.
 514
 515 =head2 C<< get_method(name) -> Mouse::Meta::Method | undef >>
 516
 517 Returns a L<Mouse::Meta::Method> with the given name.
 518
 519 Note that you can also use C<< $metaclass->name->can($name) >> for a method body.
 520
 521 =head2 C<< get_method_list -> Names >>
 522
 523 Returns a list of method names which are defined in the local class.
 524 If you want a list of all applicable methods for a class, use the
 525 C<get_all_methods> method.
 526
 527 =head2 C<< get_all_methods -> (Mouse::Meta::Method) >>
 528
 529 Return the list of all L<Mouse::Meta::Method> instances associated with
 530 the class and its superclasses.
 531
 532 =head2 C<< add_attribute(name => spec | Mouse::Meta::Attribute) >>
 533
 534 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 535 class.
 536
 537 =head2 C<< has_attribute(Name) -> Bool >>
 538
 539 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 540
 541 =head2 C<< get_attribute Name -> Mouse::Meta::Attribute | undef >>
 542
 543 Returns the L<Mouse::Meta::Attribute> with the given name.
 544
 545 =head2 C<< get_attribute_list -> Names >>
 546
 547 Returns a list of attribute names which are defined in the local
 548 class. If you want a list of all applicable attributes for a class,
 549 use the C<get_all_attributes> method.
 550
 551 =head2 C<< get_all_attributes -> (Mouse::Meta::Attribute) >>
 552
 553 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 554 this class and its superclasses.
 555
 556 =head2 C<< linearized_isa -> [ClassNames] >>
 557
 558 Returns the list of classes in method dispatch order, with duplicates removed.
 559
 560 =head2 C<< new_object(Parameters) -> Instance >>
 561
 562 Creates a new instance.
 563
 564 =head2 C<< clone_object(Instance, Parameters) -> Instance >>
 565
 566 Clones the given instance which must be an instance governed by this
 567 metaclass.
 568
 569 =head2 C<< throw_error(Message, Parameters) >>
 570
 571 Throws an error with the given message.
 572
 573 =head1 SEE ALSO
 574
 575 L<Mouse::Meta::Module>
 576
 577 L<Moose::Meta::Class>
 578
 579 L<Class::MOP::Class>
 580
 581 =cut
 582