lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use Mouse::Util qw/:meta get_linear_isa not_supported/; # enables strict and warnings
   3
   4 use Scalar::Util qw/blessed weaken/;
   5
   6 use Mouse::Meta::Module;
   7 our @ISA = qw(Mouse::Meta::Module);
   8
   9 sub attribute_metaclass;
  10 sub method_metaclass;
  11
  12 sub constructor_class;
  13 sub destructor_class;
  14
  15 my @MetaClassTypes = qw(
  16     attribute_metaclass
  17     method_metaclass
  18     constructor_class
  19     destructor_class
  20 );
  21
  22 sub _construct_meta {
  23     my($class, %args) = @_;
  24
  25     $args{attributes} = {};
  26     $args{methods}    = {};
  27     $args{roles}      = [];
  28
  29     $args{superclasses} = do {
  30         no strict 'refs';
  31         \@{ $args{package} . '::ISA' };
  32     };
  33
  34     my $self = bless \%args, ref($class) || $class;
  35     if(ref($self) ne __PACKAGE__){
  36         $self->meta->_initialize_object($self, \%args);
  37     }
  38     return $self;
  39 }
  40
  41 sub create_anon_class{
  42     my $self = shift;
  43     return $self->create(undef, @_);
  44 }
  45
  46 sub is_anon_class;
  47
  48 sub roles;
  49
  50 sub calculate_all_roles {
  51     my $self = shift;
  52     my %seen;
  53     return grep { !$seen{ $_->name }++ }
  54            map  { $_->calculate_all_roles } @{ $self->roles };
  55 }
  56
  57 sub superclasses {
  58     my $self = shift;
  59
  60     if (@_) {
  61         foreach my $super(@_){
  62             Mouse::Util::load_class($super);
  63             my $meta = Mouse::Util::get_metaclass_by_name($super);
  64
  65             next if not defined $meta;
  66
  67             if(Mouse::Util::is_a_metarole($meta)){
  68                 $self->throw_error("You cannot inherit from a Mouse Role ($super)");
  69             }
  70
  71             next if $self->isa(ref $meta); # _superclass_meta_is_compatible
  72
  73             $self->_reconcile_with_superclass_meta($meta);
  74         }
  75         @{ $self->{superclasses} } = @_;
  76     }
  77
  78     return @{ $self->{superclasses} };
  79 }
  80
  81 sub _reconcile_with_superclass_meta {
  82     my($self, $super_meta) = @_;
  83
  84     my @incompatibles;
  85
  86     foreach my $metaclass_type(@MetaClassTypes){
  87         my $super_c = $super_meta->$metaclass_type();
  88         my $self_c  = $self->$metaclass_type();
  89
  90         if(!$super_c->isa($self_c)){
  91             push @incompatibles, ($metaclass_type => $super_c);
  92         }
  93     }
  94
  95     my @roles;
  96
  97     foreach my $role($self->meta->calculate_all_roles){
  98         if(!$super_meta->meta->does_role($role->name)){
  99             push @roles, $role->name;
 100         }
 101     }
 102
 103     #print "reconcile($self vs. $super_meta; @roles; @incompatibles)\n";
 104
 105     require Mouse::Util::MetaRole;
 106     Mouse::Util::MetaRole::apply_metaclass_roles(
 107         for_class       => $self,
 108         metaclass       => ref $super_meta,
 109         metaclass_roles => \@roles,
 110         @incompatibles,
 111     );
 112     return;
 113 }
 114
 115 sub find_method_by_name{
 116     my($self, $method_name) = @_;
 117     defined($method_name)
 118         or $self->throw_error('You must define a method name to find');
 119
 120     foreach my $class( $self->linearized_isa ){
 121         my $method = $self->initialize($class)->get_method($method_name);
 122         return $method if defined $method;
 123     }
 124     return undef;
 125 }
 126
 127 sub get_all_methods {
 128     my($self) = @_;
 129     return map{ $self->find_method_by_name($_) } $self->get_all_method_names;
 130 }
 131
 132 sub get_all_method_names {
 133     my $self = shift;
 134     my %uniq;
 135     return grep { $uniq{$_}++ == 0 }
 136             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
 137             $self->linearized_isa;
 138 }
 139
 140 sub find_attribute_by_name{
 141     my($self, $name) = @_;
 142     my $attr;
 143     foreach my $class($self->linearized_isa){
 144         my $meta = Mouse::Util::get_metaclass_by_name($class) or next;
 145         $attr = $meta->get_attribute($name) and last;
 146     }
 147     return $attr;
 148 }
 149
 150 sub add_attribute {
 151     my $self = shift;
 152
 153     my($attr, $name);
 154
 155     if(blessed $_[0]){
 156         $attr = $_[0];
 157
 158         $attr->isa('Mouse::Meta::Attribute')
 159             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
 160
 161         $name = $attr->name;
 162     }
 163     else{
 164         # _process_attribute
 165         $name = shift;
 166
 167         my %args = (@_ == 1) ? %{$_[0]} : @_;
 168
 169         defined($name)
 170             or $self->throw_error('You must provide a name for the attribute');
 171
 172         if ($name =~ s/^\+//) { # inherited attributes
 173             my $inherited_attr = $self->find_attribute_by_name($name)
 174                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 175
 176             $attr = $inherited_attr->clone_and_inherit_options(%args);
 177         }
 178         else{
 179             my($attribute_class, @traits) = $self->attribute_metaclass->interpolate_class(\%args);
 180             $args{traits} = \@traits if @traits;
 181
 182             $attr = $attribute_class->new($name, %args);
 183         }
 184     }
 185
 186     weaken( $attr->{associated_class} = $self );
 187
 188     $self->{attributes}{$attr->name} = $attr;
 189     $attr->install_accessors();
 190
 191     if(Mouse::Util::_MOUSE_VERBOSE && !$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 192         Carp::cluck(qq{Attribute (}.$attr->name.qq{) of class }.$self->name.qq{ has no associated methods (did you mean to provide an "is" argument?)});
 193     }
 194     return $attr;
 195 }
 196
 197 sub compute_all_applicable_attributes {
 198     Carp::cluck('compute_all_applicable_attributes() has been deprecated')
 199         if Mouse::Util::_MOUSE_VERBOSE;
 200     return shift->get_all_attributes(@_)
 201 }
 202
 203 sub linearized_isa;
 204
 205 sub new_object;
 206
 207 sub clone_object {
 208     my $class  = shift;
 209     my $object = shift;
 210     my %params = (@_ == 1) ? %{$_[0]} : @_;
 211
 212     (blessed($object) && $object->isa($class->name))
 213         || $class->throw_error("You must pass an instance of the metaclass (" . $class->name . "), not ($object)");
 214
 215     my $cloned = bless { %$object }, ref $object;
 216     $class->_initialize_object($cloned, \%params);
 217
 218     return $cloned;
 219 }
 220
 221 sub clone_instance {
 222     my ($class, $instance, %params) = @_;
 223
 224     Carp::cluck('clone_instance has been deprecated. Use clone_object instead')
 225         if Mouse::Util::_MOUSE_VERBOSE;
 226     return $class->clone_object($instance, %params);
 227 }
 228
 229
 230 sub immutable_options {
 231     my ( $self, @args ) = @_;
 232
 233     return (
 234         inline_constructor => 1,
 235         inline_destructor  => 1,
 236         constructor_name   => 'new',
 237         @args,
 238     );
 239 }
 240
 241
 242 sub make_immutable {
 243     my $self = shift;
 244     my %args = $self->immutable_options(@_);
 245
 246     $self->{is_immutable}++;
 247
 248     $self->{_strict_constructor} = $args{strict_constructor};
 249
 250     if ($args{inline_constructor}) {
 251         my $c = $self->constructor_class;
 252         Mouse::Util::load_class($c);
 253         $self->add_method($args{constructor_name} =>
 254             $c->_generate_constructor($self, \%args));
 255     }
 256
 257     if ($args{inline_destructor}) {
 258         my $c = $self->destructor_class;
 259         Mouse::Util::load_class($c);
 260         $self->add_method(DESTROY =>
 261             $c->_generate_destructor($self, \%args));
 262     }
 263
 264     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 265     # at the end of a source file.
 266     return 1;
 267 }
 268
 269 sub make_mutable {
 270     my($self) = @_;
 271     $self->{is_immutable} = 0;
 272     return;
 273 }
 274
 275 sub is_immutable;
 276 sub is_mutable   { !$_[0]->is_immutable }
 277
 278 sub _install_modifier_pp{
 279     my( $self, $type, $name, $code ) = @_;
 280     my $into = $self->name;
 281
 282     my $original = $into->can($name)
 283         or $self->throw_error("The method '$name' is not found in the inheritance hierarchy for class $into");
 284
 285     my $modifier_table = $self->{modifiers}{$name};
 286
 287     if(!$modifier_table){
 288         my(@before, @after, @around, $cache, $modified);
 289
 290         $cache = $original;
 291
 292         $modified = sub {
 293             for my $c (@before) { $c->(@_) }
 294
 295             if(wantarray){ # list context
 296                 my @rval = $cache->(@_);
 297
 298                 for my $c(@after){ $c->(@_) }
 299                 return @rval;
 300             }
 301             elsif(defined wantarray){ # scalar context
 302                 my $rval = $cache->(@_);
 303
 304                 for my $c(@after){ $c->(@_) }
 305                 return $rval;
 306             }
 307             else{ # void context
 308                 $cache->(@_);
 309
 310                 for my $c(@after){ $c->(@_) }
 311                 return;
 312             }
 313         };
 314
 315         $self->{modifiers}{$name} = $modifier_table = {
 316             original => $original,
 317
 318             before   => \@before,
 319             after    => \@after,
 320             around   => \@around,
 321
 322             cache    => \$cache, # cache for around modifiers
 323         };
 324
 325         $self->add_method($name => $modified);
 326     }
 327
 328     if($type eq 'before'){
 329         unshift @{$modifier_table->{before}}, $code;
 330     }
 331     elsif($type eq 'after'){
 332         push @{$modifier_table->{after}}, $code;
 333     }
 334     else{ # around
 335         push @{$modifier_table->{around}}, $code;
 336
 337         my $next = ${ $modifier_table->{cache} };
 338         ${ $modifier_table->{cache} } = sub{ $code->($next, @_) };
 339     }
 340
 341     return;
 342 }
 343
 344 sub _install_modifier {
 345     my ( $self, $type, $name, $code ) = @_;
 346
 347     # load Class::Method::Modifiers first
 348     my $no_cmm_fast = do{
 349         local $@;
 350         eval q{ require Class::Method::Modifiers::Fast };
 351         $@;
 352     };
 353
 354     my $impl;
 355     if($no_cmm_fast){
 356         $impl = \&_install_modifier_pp;
 357     }
 358     else{
 359         my $install_modifier = Class::Method::Modifiers::Fast->can('_install_modifier');
 360         $impl = sub {
 361             my ( $self, $type, $name, $code ) = @_;
 362             my $into = $self->name;
 363             $install_modifier->($into, $type, $name, $code);
 364
 365             $self->add_method($name => do{
 366                 no strict 'refs';
 367                 \&{ $into . '::' . $name };
 368             });
 369             return;
 370         };
 371     }
 372
 373     # replace this method itself :)
 374     {
 375         no warnings 'redefine';
 376         *_install_modifier = $impl;
 377     }
 378
 379     $self->$impl( $type, $name, $code );
 380 }
 381
 382 sub add_before_method_modifier {
 383     my ( $self, $name, $code ) = @_;
 384     $self->_install_modifier( 'before', $name, $code );
 385 }
 386
 387 sub add_around_method_modifier {
 388     my ( $self, $name, $code ) = @_;
 389     $self->_install_modifier( 'around', $name, $code );
 390 }
 391
 392 sub add_after_method_modifier {
 393     my ( $self, $name, $code ) = @_;
 394     $self->_install_modifier( 'after', $name, $code );
 395 }
 396
 397 sub add_override_method_modifier {
 398     my ($self, $name, $code) = @_;
 399
 400     if($self->has_method($name)){
 401         $self->throw_error("Cannot add an override method if a local method is already present");
 402     }
 403
 404     my $package = $self->name;
 405
 406     my $super_body = $package->can($name)
 407         or $self->throw_error("You cannot override '$name' because it has no super method");
 408
 409     $self->add_method($name => sub {
 410         local $Mouse::SUPER_PACKAGE = $package;
 411         local $Mouse::SUPER_BODY    = $super_body;
 412         local @Mouse::SUPER_ARGS    = @_;
 413
 414         $code->(@_);
 415     });
 416     return;
 417 }
 418
 419 sub add_augment_method_modifier {
 420     my ($self, $name, $code) = @_;
 421     if($self->has_method($name)){
 422         $self->throw_error("Cannot add an augment method if a local method is already present");
 423     }
 424
 425     my $super = $self->find_method_by_name($name)
 426         or $self->throw_error("You cannot augment '$name' because it has no super method");
 427
 428     my $super_package = $super->package_name;
 429     my $super_body    = $super->body;
 430
 431     $self->add_method($name => sub{
 432         local $Mouse::INNER_BODY{$super_package} = $code;
 433         local $Mouse::INNER_ARGS{$super_package} = [@_];
 434         $super_body->(@_);
 435     });
 436     return;
 437 }
 438
 439 sub does_role {
 440     my ($self, $role_name) = @_;
 441
 442     (defined $role_name)
 443         || $self->throw_error("You must supply a role name to look for");
 444
 445     for my $class ($self->linearized_isa) {
 446         my $meta = Mouse::Util::get_metaclass_by_name($class)
 447             or next;
 448
 449         for my $role (@{ $meta->roles }) {
 450
 451             return 1 if $role->does_role($role_name);
 452         }
 453     }
 454
 455     return 0;
 456 }
 457
 458 1;
 459 __END__
 460
 461 =head1 NAME
 462
 463 Mouse::Meta::Class - The Mouse class metaclass
 464
 465 =head1 VERSION
 466
 467 This document describes Mouse version 0.45
 468
 469 =head1 METHODS
 470
 471 =head2 C<< initialize(ClassName) -> Mouse::Meta::Class >>
 472
 473 Finds or creates a C<Mouse::Meta::Class> instance for the given ClassName. Only
 474 one instance should exist for a given class.
 475
 476 =head2 C<< name -> ClassName >>
 477
 478 Returns the name of the owner class.
 479
 480 =head2 C<< superclasses -> ClassNames >> C<< superclass(ClassNames) >>
 481
 482 Gets (or sets) the list of superclasses of the owner class.
 483
 484 =head2 C<< add_method(name => CodeRef) >>
 485
 486 Adds a method to the owner class.
 487
 488 =head2 C<< has_method(name) -> Bool >>
 489
 490 Returns whether we have a method with the given name.
 491
 492 =head2 C<< get_method(name) -> Mouse::Meta::Method | undef >>
 493
 494 Returns a L<Mouse::Meta::Method> with the given name.
 495
 496 Note that you can also use C<< $metaclass->name->can($name) >> for a method body.
 497
 498 =head2 C<< get_method_list -> Names >>
 499
 500 Returns a list of method names which are defined in the local class.
 501 If you want a list of all applicable methods for a class, use the
 502 C<get_all_methods> method.
 503
 504 =head2 C<< get_all_methods -> (Mouse::Meta::Method) >>
 505
 506 Return the list of all L<Mouse::Meta::Method> instances associated with
 507 the class and its superclasses.
 508
 509 =head2 C<< add_attribute(name => spec | Mouse::Meta::Attribute) >>
 510
 511 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 512 class.
 513
 514 =head2 C<< has_attribute(Name) -> Bool >>
 515
 516 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 517
 518 =head2 C<< get_attribute Name -> Mouse::Meta::Attribute | undef >>
 519
 520 Returns the L<Mouse::Meta::Attribute> with the given name.
 521
 522 =head2 C<< get_attribute_list -> Names >>
 523
 524 Returns a list of attribute names which are defined in the local
 525 class. If you want a list of all applicable attributes for a class,
 526 use the C<get_all_attributes> method.
 527
 528 =head2 C<< get_all_attributes -> (Mouse::Meta::Attribute) >>
 529
 530 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 531 this class and its superclasses.
 532
 533 =head2 C<< linearized_isa -> [ClassNames] >>
 534
 535 Returns the list of classes in method dispatch order, with duplicates removed.
 536
 537 =head2 C<< new_object(Parameters) -> Instance >>
 538
 539 Creates a new instance.
 540
 541 =head2 C<< clone_object(Instance, Parameters) -> Instance >>
 542
 543 Clones the given instance which must be an instance governed by this
 544 metaclass.
 545
 546 =head2 C<< throw_error(Message, Parameters) >>
 547
 548 Throws an error with the given message.
 549
 550 =head1 SEE ALSO
 551
 552 L<Mouse::Meta::Module>
 553
 554 L<Moose::Meta::Class>
 555
 556 L<Class::MOP::Class>
 557
 558 =cut
 559