lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use Mouse::Util qw/:meta get_linear_isa not_supported/; # enables strict and warnings
   3
   4 use Scalar::Util qw/blessed weaken/;
   5
   6 use Mouse::Meta::Method::Constructor;
   7 use Mouse::Meta::Method::Destructor;
   8 use Mouse::Meta::Module;
   9 our @ISA = qw(Mouse::Meta::Module);
  10
  11 sub method_metaclass()    { 'Mouse::Meta::Method'    }
  12 sub attribute_metaclass() { 'Mouse::Meta::Attribute' }
  13
  14 sub constructor_class(); # XS
  15 sub destructor_class()    { 'Mouse::Meta::Method::Destructor'  }
  16
  17 sub _construct_meta {
  18     my($class, %args) = @_;
  19
  20     $args{attributes} = {};
  21     $args{methods}    = {};
  22     $args{roles}      = [];
  23
  24     $args{superclasses} = do {
  25         no strict 'refs';
  26         \@{ $args{package} . '::ISA' };
  27     };
  28
  29     my $self = bless \%args, ref($class) || $class;
  30     if(ref($self) ne __PACKAGE__){
  31         $self->meta->_initialize_object($self, \%args);
  32     }
  33     return $self;
  34 }
  35
  36 sub create_anon_class{
  37     my $self = shift;
  38     return $self->create(undef, @_);
  39 }
  40
  41 sub is_anon_class;
  42
  43 sub roles;
  44
  45 sub calculate_all_roles {
  46     my $self = shift;
  47     my %seen;
  48     return grep { !$seen{ $_->name }++ }
  49            map  { $_->calculate_all_roles } @{ $self->roles };
  50 }
  51
  52 sub superclasses {
  53     my $self = shift;
  54
  55     if (@_) {
  56         foreach my $super(@_){
  57             Mouse::Util::load_class($super);
  58             my $meta = Mouse::Util::get_metaclass_by_name($super);
  59             if(Mouse::Util::is_a_metarole($meta)){
  60                 $self->throw_error("You cannot inherit from a Mouse Role ($super)");
  61             }
  62         }
  63         @{ $self->{superclasses} } = @_;
  64     }
  65
  66     return @{ $self->{superclasses} };
  67 }
  68
  69 sub find_method_by_name{
  70     my($self, $method_name) = @_;
  71     defined($method_name)
  72         or $self->throw_error('You must define a method name to find');
  73
  74     foreach my $class( $self->linearized_isa ){
  75         my $method = $self->initialize($class)->get_method($method_name);
  76         return $method if defined $method;
  77     }
  78     return undef;
  79 }
  80
  81 sub get_all_methods {
  82     my($self) = @_;
  83     return map{ $self->find_method_by_name($_) } $self->get_all_method_names;
  84 }
  85
  86 sub get_all_method_names {
  87     my $self = shift;
  88     my %uniq;
  89     return grep { $uniq{$_}++ == 0 }
  90             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
  91             $self->linearized_isa;
  92 }
  93
  94 sub find_attribute_by_name{
  95     my($self, $name) = @_;
  96     my $attr;
  97     foreach my $class($self->linearized_isa){
  98         my $meta = Mouse::Util::get_metaclass_by_name($class) or next;
  99         $attr = $meta->get_attribute($name) and last;
 100     }
 101     return $attr;
 102 }
 103
 104 sub add_attribute {
 105     my $self = shift;
 106
 107     my($attr, $name);
 108
 109     if(blessed $_[0]){
 110         $attr = $_[0];
 111
 112         $attr->isa('Mouse::Meta::Attribute')
 113             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
 114
 115         $name = $attr->name;
 116     }
 117     else{
 118         # _process_attribute
 119         $name = shift;
 120
 121         my %args = (@_ == 1) ? %{$_[0]} : @_;
 122
 123         defined($name)
 124             or $self->throw_error('You must provide a name for the attribute');
 125
 126         if ($name =~ s/^\+//) { # inherited attributes
 127             my $inherited_attr = $self->find_attribute_by_name($name)
 128                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 129
 130             $attr = $inherited_attr->clone_and_inherit_options(%args);
 131         }
 132         else{
 133             my($attribute_class, @traits) = $self->attribute_metaclass->interpolate_class(\%args);
 134             $args{traits} = \@traits if @traits;
 135
 136             $attr = $attribute_class->new($name, %args);
 137         }
 138     }
 139
 140     weaken( $attr->{associated_class} = $self );
 141
 142     $self->{attributes}{$attr->name} = $attr;
 143     $attr->install_accessors();
 144
 145     if(_MOUSE_VERBOSE && !$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 146         Carp::cluck(qq{Attribute (}.$attr->name.qq{) of class }.$self->name.qq{ has no associated methods (did you mean to provide an "is" argument?)});
 147     }
 148     return $attr;
 149 }
 150
 151 sub compute_all_applicable_attributes {
 152     Carp::cluck('compute_all_applicable_attributes() has been deprecated')
 153         if _MOUSE_VERBOSE;
 154     return shift->get_all_attributes(@_)
 155 }
 156
 157 sub linearized_isa;
 158
 159 sub new_object {
 160     my $self = shift;
 161     my %args = (@_ == 1 ? %{$_[0]} : @_);
 162
 163     my $object = bless {}, $self->name;
 164
 165     $self->_initialize_object($object, \%args);
 166     return $object;
 167 }
 168
 169 sub clone_object {
 170     my $class  = shift;
 171     my $object = shift;
 172     my %params = (@_ == 1) ? %{$_[0]} : @_;
 173
 174     (blessed($object) && $object->isa($class->name))
 175         || $class->throw_error("You must pass an instance of the metaclass (" . $class->name . "), not ($object)");
 176
 177     my $cloned = bless { %$object }, ref $object;
 178     $class->_initialize_object($cloned, \%params);
 179
 180     return $cloned;
 181 }
 182
 183 sub clone_instance {
 184     my ($class, $instance, %params) = @_;
 185
 186     Carp::cluck('clone_instance has been deprecated. Use clone_object instead')
 187         if _MOUSE_VERBOSE;
 188     return $class->clone_object($instance, %params);
 189 }
 190
 191 sub make_immutable {
 192     my $self = shift;
 193     my %args = (
 194         inline_constructor => 1,
 195         inline_destructor  => 1,
 196         constructor_name   => 'new',
 197         @_,
 198     );
 199
 200     $self->{is_immutable}++;
 201
 202     if ($args{inline_constructor}) {
 203         $self->add_method($args{constructor_name} =>
 204             $self->constructor_class->_generate_constructor($self, \%args));
 205     }
 206
 207     if ($args{inline_destructor}) {
 208         $self->add_method(DESTROY =>
 209             $self->destructor_class->_generate_destructor($self, \%args));
 210     }
 211
 212     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 213     # at the end of a source file.
 214     return 1;
 215 }
 216
 217 sub make_mutable { not_supported }
 218
 219 sub is_immutable {  $_[0]->{is_immutable} }
 220 sub is_mutable   { !$_[0]->{is_immutable} }
 221
 222 sub _install_modifier_pp{
 223     my( $self, $type, $name, $code ) = @_;
 224     my $into = $self->name;
 225
 226     my $original = $into->can($name)
 227         or $self->throw_error("The method '$name' is not found in the inheritance hierarchy for class $into");
 228
 229     my $modifier_table = $self->{modifiers}{$name};
 230
 231     if(!$modifier_table){
 232         my(@before, @after, @around, $cache, $modified);
 233
 234         $cache = $original;
 235
 236         $modified = sub {
 237             for my $c (@before) { $c->(@_) }
 238
 239             if(wantarray){ # list context
 240                 my @rval = $cache->(@_);
 241
 242                 for my $c(@after){ $c->(@_) }
 243                 return @rval;
 244             }
 245             elsif(defined wantarray){ # scalar context
 246                 my $rval = $cache->(@_);
 247
 248                 for my $c(@after){ $c->(@_) }
 249                 return $rval;
 250             }
 251             else{ # void context
 252                 $cache->(@_);
 253
 254                 for my $c(@after){ $c->(@_) }
 255                 return;
 256             }
 257         };
 258
 259         $self->{modifiers}{$name} = $modifier_table = {
 260             original => $original,
 261
 262             before   => \@before,
 263             after    => \@after,
 264             around   => \@around,
 265
 266             cache    => \$cache, # cache for around modifiers
 267         };
 268
 269         $self->add_method($name => $modified);
 270     }
 271
 272     if($type eq 'before'){
 273         unshift @{$modifier_table->{before}}, $code;
 274     }
 275     elsif($type eq 'after'){
 276         push @{$modifier_table->{after}}, $code;
 277     }
 278     else{ # around
 279         push @{$modifier_table->{around}}, $code;
 280
 281         my $next = ${ $modifier_table->{cache} };
 282         ${ $modifier_table->{cache} } = sub{ $code->($next, @_) };
 283     }
 284
 285     return;
 286 }
 287
 288 sub _install_modifier {
 289     my ( $self, $type, $name, $code ) = @_;
 290
 291     # load Class::Method::Modifiers first
 292     my $no_cmm_fast = do{
 293         local $@;
 294         eval q{ require Class::Method::Modifiers::Fast };
 295         $@;
 296     };
 297
 298     my $impl;
 299     if($no_cmm_fast){
 300         $impl = \&_install_modifier_pp;
 301     }
 302     else{
 303         my $install_modifier = Class::Method::Modifiers::Fast->can('_install_modifier');
 304         $impl = sub {
 305             my ( $self, $type, $name, $code ) = @_;
 306             my $into = $self->name;
 307             $install_modifier->($into, $type, $name, $code);
 308
 309             $self->add_method($name => do{
 310                 no strict 'refs';
 311                 \&{ $into . '::' . $name };
 312             });
 313             return;
 314         };
 315     }
 316
 317     # replace this method itself :)
 318     {
 319         no warnings 'redefine';
 320         *_install_modifier = $impl;
 321     }
 322
 323     $self->$impl( $type, $name, $code );
 324 }
 325
 326 sub add_before_method_modifier {
 327     my ( $self, $name, $code ) = @_;
 328     $self->_install_modifier( 'before', $name, $code );
 329 }
 330
 331 sub add_around_method_modifier {
 332     my ( $self, $name, $code ) = @_;
 333     $self->_install_modifier( 'around', $name, $code );
 334 }
 335
 336 sub add_after_method_modifier {
 337     my ( $self, $name, $code ) = @_;
 338     $self->_install_modifier( 'after', $name, $code );
 339 }
 340
 341 sub add_override_method_modifier {
 342     my ($self, $name, $code) = @_;
 343
 344     if($self->has_method($name)){
 345         $self->throw_error("Cannot add an override method if a local method is already present");
 346     }
 347
 348     my $package = $self->name;
 349
 350     my $super_body = $package->can($name)
 351         or $self->throw_error("You cannot override '$name' because it has no super method");
 352
 353     $self->add_method($name => sub {
 354         local $Mouse::SUPER_PACKAGE = $package;
 355         local $Mouse::SUPER_BODY    = $super_body;
 356         local @Mouse::SUPER_ARGS    = @_;
 357
 358         $code->(@_);
 359     });
 360     return;
 361 }
 362
 363 sub add_augment_method_modifier {
 364     my ($self, $name, $code) = @_;
 365     if($self->has_method($name)){
 366         $self->throw_error("Cannot add an augment method if a local method is already present");
 367     }
 368
 369     my $super = $self->find_method_by_name($name)
 370         or $self->throw_error("You cannot augment '$name' because it has no super method");
 371
 372     my $super_package = $super->package_name;
 373     my $super_body    = $super->body;
 374
 375     $self->add_method($name => sub{
 376         local $Mouse::INNER_BODY{$super_package} = $code;
 377         local $Mouse::INNER_ARGS{$super_package} = [@_];
 378         $super_body->(@_);
 379     });
 380     return;
 381 }
 382
 383 sub does_role {
 384     my ($self, $role_name) = @_;
 385
 386     (defined $role_name)
 387         || $self->throw_error("You must supply a role name to look for");
 388
 389     for my $class ($self->linearized_isa) {
 390         my $meta = Mouse::Util::get_metaclass_by_name($class)
 391             or next;
 392
 393         for my $role (@{ $meta->roles }) {
 394
 395             return 1 if $role->does_role($role_name);
 396         }
 397     }
 398
 399     return 0;
 400 }
 401
 402 1;
 403 __END__
 404
 405 =head1 NAME
 406
 407 Mouse::Meta::Class - The Mouse class metaclass
 408
 409 =head1 VERSION
 410
 411 This document describes Mouse version 0.40_05
 412
 413 =head1 METHODS
 414
 415 =head2 C<< initialize(ClassName) -> Mouse::Meta::Class >>
 416
 417 Finds or creates a C<Mouse::Meta::Class> instance for the given ClassName. Only
 418 one instance should exist for a given class.
 419
 420 =head2 C<< name -> ClassName >>
 421
 422 Returns the name of the owner class.
 423
 424 =head2 C<< superclasses -> ClassNames >> C<< superclass(ClassNames) >>
 425
 426 Gets (or sets) the list of superclasses of the owner class.
 427
 428 =head2 C<< add_method(name => CodeRef) >>
 429
 430 Adds a method to the owner class.
 431
 432 =head2 C<< has_method(name) -> Bool >>
 433
 434 Returns whether we have a method with the given name.
 435
 436 =head2 C<< get_method(name) -> Mouse::Meta::Method | undef >>
 437
 438 Returns a L<Mouse::Meta::Method> with the given name.
 439
 440 Note that you can also use C<< $metaclass->name->can($name) >> for a method body.
 441
 442 =head2 C<< get_method_list -> Names >>
 443
 444 Returns a list of method names which are defined in the local class.
 445 If you want a list of all applicable methods for a class, use the
 446 C<get_all_methods> method.
 447
 448 =head2 C<< get_all_methods -> (Mouse::Meta::Method) >>
 449
 450 Return the list of all L<Mouse::Meta::Method> instances associated with
 451 the class and its superclasses.
 452
 453 =head2 C<< add_attribute(name => spec | Mouse::Meta::Attribute) >>
 454
 455 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 456 class.
 457
 458 =head2 C<< has_attribute(Name) -> Bool >>
 459
 460 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 461
 462 =head2 C<< get_attribute Name -> Mouse::Meta::Attribute | undef >>
 463
 464 Returns the L<Mouse::Meta::Attribute> with the given name.
 465
 466 =head2 C<< get_attribute_list -> Names >>
 467
 468 Returns a list of attribute names which are defined in the local
 469 class. If you want a list of all applicable attributes for a class,
 470 use the C<get_all_attributes> method.
 471
 472 =head2 C<< get_all_attributes -> (Mouse::Meta::Attribute) >>
 473
 474 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 475 this class and its superclasses.
 476
 477 =head2 C<< linearized_isa -> [ClassNames] >>
 478
 479 Returns the list of classes in method dispatch order, with duplicates removed.
 480
 481 =head2 C<< new_object(Parameters) -> Instance >>
 482
 483 Creates a new instance.
 484
 485 =head2 C<< clone_object(Instance, Parameters) -> Instance >>
 486
 487 Clones the given instance which must be an instance governed by this
 488 metaclass.
 489
 490 =head2 C<< throw_error(Message, Parameters) >>
 491
 492 Throws an error with the given message.
 493
 494 =head1 SEE ALSO
 495
 496 L<Moose::Meta::Class>
 497
 498 L<Class::MOP::Class>
 499
 500 =cut
 501