lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use Mouse::Util qw/:meta/; # enables strict and warnings
   3
   4 use Scalar::Util qw/blessed weaken/;
   5
   6 use Mouse::Meta::Module;
   7 our @ISA = qw(Mouse::Meta::Module);
   8
   9 our @CARP_NOT = qw(Mouse); # trust Mouse
  10
  11 sub attribute_metaclass;
  12 sub method_metaclass;
  13
  14 sub constructor_class;
  15 sub destructor_class;
  16
  17
  18 sub _construct_meta {
  19     my($class, %args) = @_;
  20
  21     $args{attributes} = {};
  22     $args{methods}    = {};
  23     $args{roles}      = [];
  24
  25     $args{superclasses} = do {
  26         no strict 'refs';
  27         \@{ $args{package} . '::ISA' };
  28     };
  29
  30     my $self = bless \%args, ref($class) || $class;
  31     if(ref($self) ne __PACKAGE__){
  32         $self->meta->_initialize_object($self, \%args);
  33     }
  34     return $self;
  35 }
  36
  37 sub create_anon_class{
  38     my $self = shift;
  39     return $self->create(undef, @_);
  40 }
  41
  42 sub is_anon_class;
  43
  44 sub roles;
  45
  46 sub calculate_all_roles {
  47     my $self = shift;
  48     my %seen;
  49     return grep { !$seen{ $_->name }++ }
  50            map  { $_->calculate_all_roles } @{ $self->roles };
  51 }
  52
  53 sub superclasses {
  54     my $self = shift;
  55
  56     if (@_) {
  57         foreach my $super(@_){
  58             Mouse::Util::load_class($super);
  59
  60             my $meta = Mouse::Util::get_metaclass_by_name($super);
  61             unless(defined $meta) {
  62                 # checks if $super is a foreign class (i.e. non-Mouse class)
  63                 my $mm = $super->can('meta');
  64                 if(!($mm && $mm == \&Mouse::Util::meta)) {
  65                     if($super->can('new') or $super->can('DESTROY')) {
  66                         $self->inherit_from_foreign_class($super);
  67                     }
  68                 }
  69                 next;
  70             }
  71
  72             if(Mouse::Util::is_a_metarole($meta)){
  73                 $self->throw_error("You cannot inherit from a Mouse Role ($super)");
  74             }
  75
  76             # checks and fixes in metaclass compatiility
  77             next if $self->isa(ref $meta); # _superclass_meta_is_compatible
  78             $self->_reconcile_with_superclass_meta($meta);
  79         }
  80         @{ $self->{superclasses} } = @_;
  81     }
  82
  83     return @{ $self->{superclasses} };
  84 }
  85
  86 sub inherit_from_foreign_class {
  87     my($class, $super) = @_;
  88     Carp::carp("You inherit from non-Mouse class ($super),"
  89         . " but it is unlikely to work correctly."
  90         . " Please concider to use MouseX::Foreign");
  91     return;
  92 }
  93
  94 my @MetaClassTypes = (
  95     'attribute',   # Mouse::Meta::Attribute
  96     'method',      # Mouse::Meta::Method
  97     'constructor', # Mouse::Meta::Method::Constructor
  98     'destructor',  # Mouse::Meta::Method::Destructor
  99 );
 100
 101 sub _reconcile_with_superclass_meta {
 102     my($self, $other) = @_;
 103
 104     # find incompatible traits
 105     my %metaroles;
 106     foreach my $metaclass_type(@MetaClassTypes){
 107         my $accessor = $self->can($metaclass_type . '_metaclass')
 108             || $self->can($metaclass_type . '_class');
 109
 110         my $other_c = $other->$accessor();
 111         my $self_c  = $self->$accessor();
 112
 113         if(!$self_c->isa($other_c)){
 114             $metaroles{$metaclass_type}
 115                 = [ $self_c->meta->_collect_roles($other_c->meta) ];
 116         }
 117     }
 118
 119     $metaroles{class} = [$self->meta->_collect_roles($other->meta)];
 120
 121     #use Data::Dumper; print Data::Dumper->new([\%metaroles], ['*metaroles'])->Indent(1)->Dump;
 122
 123     require Mouse::Util::MetaRole;
 124     $_[0] = Mouse::Util::MetaRole::apply_metaroles(
 125         for             => $self,
 126         class_metaroles => \%metaroles,
 127     );
 128     return;
 129 }
 130
 131 sub _collect_roles {
 132     my ($self, $other) = @_;
 133
 134     # find common ancestor
 135     my @self_lin_isa  = $self->linearized_isa;
 136     my @other_lin_isa = $other->linearized_isa;
 137
 138     my(@self_anon_supers, @other_anon_supers);
 139     push @self_anon_supers,  shift @self_lin_isa  while $self_lin_isa[0]->meta->is_anon_class;
 140     push @other_anon_supers, shift @other_lin_isa while $other_lin_isa[0]->meta->is_anon_class;
 141
 142     my $common_ancestor = $self_lin_isa[0] eq $other_lin_isa[0] && $self_lin_isa[0];
 143
 144     if(!$common_ancestor){
 145         $self->throw_error(sprintf '%s cannot have %s as a super class because of their metaclass incompatibility',
 146             $self->name, $other->name);
 147     }
 148
 149     my %seen;
 150     return sort grep { !$seen{$_}++ } ## no critic
 151         (map{ $_->name } map{ $_->meta->calculate_all_roles } @self_anon_supers),
 152         (map{ $_->name } map{ $_->meta->calculate_all_roles } @other_anon_supers),
 153     ;
 154 }
 155
 156
 157 sub find_method_by_name{
 158     my($self, $method_name) = @_;
 159     defined($method_name)
 160         or $self->throw_error('You must define a method name to find');
 161
 162     foreach my $class( $self->linearized_isa ){
 163         my $method = $self->initialize($class)->get_method($method_name);
 164         return $method if defined $method;
 165     }
 166     return undef;
 167 }
 168
 169 sub get_all_methods {
 170     my($self) = @_;
 171     return map{ $self->find_method_by_name($_) } $self->get_all_method_names;
 172 }
 173
 174 sub get_all_method_names {
 175     my $self = shift;
 176     my %uniq;
 177     return grep { $uniq{$_}++ == 0 }
 178             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
 179             $self->linearized_isa;
 180 }
 181
 182 sub find_attribute_by_name {
 183     my($self, $name) = @_;
 184     foreach my $attr($self->get_all_attributes) {
 185         return $attr if $attr->name eq $name;
 186     }
 187     return undef;
 188 }
 189
 190 sub add_attribute {
 191     my $self = shift;
 192
 193     my($attr, $name);
 194
 195     if(blessed $_[0]){
 196         $attr = $_[0];
 197
 198         $attr->isa('Mouse::Meta::Attribute')
 199             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
 200
 201         $name = $attr->name;
 202     }
 203     else{
 204         # _process_attribute
 205         $name = shift;
 206
 207         my %args = (@_ == 1) ? %{$_[0]} : @_;
 208
 209         defined($name)
 210             or $self->throw_error('You must provide a name for the attribute');
 211
 212         if ($name =~ s/^\+//) { # inherited attributes
 213             my $inherited_attr = $self->find_attribute_by_name($name)
 214                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 215
 216             $attr = $inherited_attr->clone_and_inherit_options(%args);
 217         }
 218         else{
 219             my($attribute_class, @traits) = $self->attribute_metaclass->interpolate_class(\%args);
 220             $args{traits} = \@traits if @traits;
 221
 222             $attr = $attribute_class->new($name, %args);
 223         }
 224     }
 225
 226     weaken( $attr->{associated_class} = $self );
 227
 228     # install accessors first
 229     $attr->install_accessors();
 230
 231     # then register the attribute to the metaclass
 232     $attr->{insertion_order}   = keys %{ $self->{attributes} };
 233     $self->{attributes}{$name} = $attr;
 234     delete $self->{_mouse_cache}; # clears internal cache
 235
 236     if(!$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 237         Carp::carp(qq{Attribute ($name) of class }.$self->name
 238             .qq{ has no associated methods (did you mean to provide an "is" argument?)});
 239     }
 240     return $attr;
 241 }
 242
 243 sub _calculate_all_attributes {
 244     my($self) = @_;
 245     my %seen;
 246     my @all_attrs;
 247     foreach my $class($self->linearized_isa) {
 248         my $meta  = Mouse::Util::get_metaclass_by_name($class) or next;
 249         my @attrs = grep { !$seen{$_->name}++ } values %{$meta->{attributes}};
 250         @attrs = sort {
 251                 $b->{insertion_order} <=> $a->{insertion_order}
 252             } @attrs;
 253         push @all_attrs, @attrs;
 254     }
 255     return [reverse @all_attrs];
 256 }
 257
 258 sub linearized_isa;
 259
 260 sub new_object;
 261 sub clone_object;
 262
 263 sub immutable_options {
 264     my ( $self, @args ) = @_;
 265
 266     return (
 267         inline_constructor => 1,
 268         inline_destructor  => 1,
 269         constructor_name   => 'new',
 270         @args,
 271     );
 272 }
 273
 274 sub make_immutable {
 275     my $self = shift;
 276     my %args = $self->immutable_options(@_);
 277
 278     $self->{is_immutable}++;
 279
 280     if ($args{inline_constructor}) {
 281         $self->add_method($args{constructor_name} =>
 282             Mouse::Util::load_class($self->constructor_class)
 283                 ->_generate_constructor($self, \%args));
 284     }
 285
 286     if ($args{inline_destructor}) {
 287         $self->add_method(DESTROY =>
 288             Mouse::Util::load_class($self->destructor_class)
 289                 ->_generate_destructor($self, \%args));
 290     }
 291
 292     # Moose's make_immutable returns true allowing calling code to skip
 293     # setting an explicit true value at the end of a source file.
 294     return 1;
 295 }
 296
 297 sub make_mutable {
 298     my($self) = @_;
 299     $self->{is_immutable} = 0;
 300     return;
 301 }
 302
 303 sub is_immutable;
 304 sub is_mutable   { !$_[0]->is_immutable }
 305
 306 sub _install_modifier {
 307     my( $self, $type, $name, $code ) = @_;
 308     my $into = $self->name;
 309
 310     my $original = $into->can($name)
 311         or $self->throw_error("The method '$name' was not found in the inheritance hierarchy for $into");
 312
 313     my $modifier_table = $self->{modifiers}{$name};
 314
 315     if(!$modifier_table){
 316         my(@before, @after, @around);
 317         my $cache = $original;
 318         my $modified = sub {
 319             if(@before) {
 320                 for my $c (@before) { $c->(@_) }
 321             }
 322             unless(@after) {
 323                 return $cache->(@_);
 324             }
 325
 326             if(wantarray){ # list context
 327                 my @rval = $cache->(@_);
 328
 329                 for my $c(@after){ $c->(@_) }
 330                 return @rval;
 331             }
 332             elsif(defined wantarray){ # scalar context
 333                 my $rval = $cache->(@_);
 334
 335                 for my $c(@after){ $c->(@_) }
 336                 return $rval;
 337             }
 338             else{ # void context
 339                 $cache->(@_);
 340
 341                 for my $c(@after){ $c->(@_) }
 342                 return;
 343             }
 344         };
 345
 346         $self->{modifiers}{$name} = $modifier_table = {
 347             original => $original,
 348
 349             before   => \@before,
 350             after    => \@after,
 351             around   => \@around,
 352
 353             cache    => \$cache, # cache for around modifiers
 354         };
 355
 356         $self->add_method($name => $modified);
 357     }
 358
 359     if($type eq 'before'){
 360         unshift @{$modifier_table->{before}}, $code;
 361     }
 362     elsif($type eq 'after'){
 363         push @{$modifier_table->{after}}, $code;
 364     }
 365     else{ # around
 366         push @{$modifier_table->{around}}, $code;
 367
 368         my $next = ${ $modifier_table->{cache} };
 369         ${ $modifier_table->{cache} } = sub{ $code->($next, @_) };
 370     }
 371
 372     return;
 373 }
 374
 375 sub add_before_method_modifier {
 376     my ( $self, $name, $code ) = @_;
 377     $self->_install_modifier( 'before', $name, $code );
 378 }
 379
 380 sub add_around_method_modifier {
 381     my ( $self, $name, $code ) = @_;
 382     $self->_install_modifier( 'around', $name, $code );
 383 }
 384
 385 sub add_after_method_modifier {
 386     my ( $self, $name, $code ) = @_;
 387     $self->_install_modifier( 'after', $name, $code );
 388 }
 389
 390 sub add_override_method_modifier {
 391     my ($self, $name, $code) = @_;
 392
 393     if($self->has_method($name)){
 394         $self->throw_error("Cannot add an override method if a local method is already present");
 395     }
 396
 397     my $package = $self->name;
 398
 399     my $super_body = $package->can($name)
 400         or $self->throw_error("You cannot override '$name' because it has no super method");
 401
 402     $self->add_method($name => sub {
 403         local $Mouse::SUPER_PACKAGE = $package;
 404         local $Mouse::SUPER_BODY    = $super_body;
 405         local @Mouse::SUPER_ARGS    = @_;
 406
 407         $code->(@_);
 408     });
 409     return;
 410 }
 411
 412 sub add_augment_method_modifier {
 413     my ($self, $name, $code) = @_;
 414     if($self->has_method($name)){
 415         $self->throw_error("Cannot add an augment method if a local method is already present");
 416     }
 417
 418     my $super = $self->find_method_by_name($name)
 419         or $self->throw_error("You cannot augment '$name' because it has no super method");
 420
 421     my $super_package = $super->package_name;
 422     my $super_body    = $super->body;
 423
 424     $self->add_method($name => sub{
 425         local $Mouse::INNER_BODY{$super_package} = $code;
 426         local $Mouse::INNER_ARGS{$super_package} = [@_];
 427         $super_body->(@_);
 428     });
 429     return;
 430 }
 431
 432 sub does_role {
 433     my ($self, $role_name) = @_;
 434
 435     (defined $role_name)
 436         || $self->throw_error("You must supply a role name to look for");
 437
 438     $role_name = $role_name->name if ref $role_name;
 439
 440     for my $class ($self->linearized_isa) {
 441         my $meta = Mouse::Util::get_metaclass_by_name($class)
 442             or next;
 443
 444         for my $role (@{ $meta->roles }) {
 445
 446             return 1 if $role->does_role($role_name);
 447         }
 448     }
 449
 450     return 0;
 451 }
 452
 453 1;
 454 __END__
 455
 456 =head1 NAME
 457
 458 Mouse::Meta::Class - The Mouse class metaclass
 459
 460 =head1 VERSION
 461
 462 This document describes Mouse version 0.73
 463
 464 =head1 DESCRIPTION
 465
 466 This class is a meta object protocol for Mouse classes,
 467 which is a subset of Moose::Meta:::Class.
 468
 469 =head1 METHODS
 470
 471 =head2 C<< initialize(ClassName) -> Mouse::Meta::Class >>
 472
 473 Finds or creates a C<Mouse::Meta::Class> instance for the given ClassName. Only
 474 one instance should exist for a given class.
 475
 476 =head2 C<< name -> ClassName >>
 477
 478 Returns the name of the owner class.
 479
 480 =head2 C<< superclasses -> ClassNames >> C<< superclass(ClassNames) >>
 481
 482 Gets (or sets) the list of superclasses of the owner class.
 483
 484 =head2 C<< add_method(name => CodeRef) >>
 485
 486 Adds a method to the owner class.
 487
 488 =head2 C<< has_method(name) -> Bool >>
 489
 490 Returns whether we have a method with the given name.
 491
 492 =head2 C<< get_method(name) -> Mouse::Meta::Method | undef >>
 493
 494 Returns a L<Mouse::Meta::Method> with the given name.
 495
 496 Note that you can also use C<< $metaclass->name->can($name) >> for a method body.
 497
 498 =head2 C<< get_method_list -> Names >>
 499
 500 Returns a list of method names which are defined in the local class.
 501 If you want a list of all applicable methods for a class, use the
 502 C<get_all_methods> method.
 503
 504 =head2 C<< get_all_methods -> (Mouse::Meta::Method) >>
 505
 506 Return the list of all L<Mouse::Meta::Method> instances associated with
 507 the class and its superclasses.
 508
 509 =head2 C<< add_attribute(name => spec | Mouse::Meta::Attribute) >>
 510
 511 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 512 class.
 513
 514 =head2 C<< has_attribute(Name) -> Bool >>
 515
 516 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 517
 518 =head2 C<< get_attribute Name -> Mouse::Meta::Attribute | undef >>
 519
 520 Returns the L<Mouse::Meta::Attribute> with the given name.
 521
 522 =head2 C<< get_attribute_list -> Names >>
 523
 524 Returns a list of attribute names which are defined in the local
 525 class. If you want a list of all applicable attributes for a class,
 526 use the C<get_all_attributes> method.
 527
 528 =head2 C<< get_all_attributes -> (Mouse::Meta::Attribute) >>
 529
 530 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 531 this class and its superclasses.
 532
 533 =head2 C<< linearized_isa -> [ClassNames] >>
 534
 535 Returns the list of classes in method dispatch order, with duplicates removed.
 536
 537 =head2 C<< new_object(Parameters) -> Instance >>
 538
 539 Creates a new instance.
 540
 541 =head2 C<< clone_object(Instance, Parameters) -> Instance >>
 542
 543 Clones the given instance which must be an instance governed by this
 544 metaclass.
 545
 546 =head2 C<< throw_error(Message, Parameters) >>
 547
 548 Throws an error with the given message.
 549
 550 =head1 SEE ALSO
 551
 552 L<Mouse::Meta::Module>
 553
 554 L<Moose::Meta::Class>
 555
 556 L<Class::MOP::Class>
 557
 558 =cut
 559