lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use Mouse::Util qw/:meta get_linear_isa not_supported/; # enables strict and warnings
   3
   4 use Scalar::Util qw/blessed weaken/;
   5
   6 use Mouse::Meta::Method::Constructor;
   7 use Mouse::Meta::Method::Destructor;
   8 use Mouse::Meta::Module;
   9 our @ISA = qw(Mouse::Meta::Module);
  10
  11 sub method_metaclass()    { 'Mouse::Meta::Method'    }
  12 sub attribute_metaclass() { 'Mouse::Meta::Attribute' }
  13
  14 sub _construct_meta {
  15     my($class, %args) = @_;
  16
  17     $args{attributes} ||= {};
  18     $args{methods}    ||= {};
  19     $args{roles}      ||= [];
  20
  21     $args{superclasses} = do {
  22         no strict 'refs';
  23         \@{ $args{package} . '::ISA' };
  24     };
  25
  26     my $self = bless \%args, ref($class) || $class;
  27     if(ref($self) ne __PACKAGE__){
  28         $self->meta->_initialize_object($self, \%args);
  29     }
  30     return $self;
  31 }
  32
  33 sub create_anon_class{
  34     my $self = shift;
  35     return $self->create(undef, @_);
  36 }
  37
  38 sub is_anon_class{
  39     return exists $_[0]->{anon_serial_id};
  40 }
  41
  42 sub roles { $_[0]->{roles} }
  43
  44 sub superclasses {
  45     my $self = shift;
  46
  47     if (@_) {
  48         Mouse::load_class($_) for @_;
  49         @{ $self->{superclasses} } = @_;
  50     }
  51
  52     return @{ $self->{superclasses} };
  53 }
  54
  55 sub find_method_by_name{
  56     my($self, $method_name) = @_;
  57     defined($method_name)
  58         or $self->throw_error('You must define a method name to find');
  59     foreach my $class( $self->linearized_isa ){
  60         my $method = $self->initialize($class)->get_method($method_name);
  61         return $method if defined $method;
  62     }
  63     return undef;
  64 }
  65
  66 sub get_all_methods {
  67     my($self) = @_;
  68     return map{ $self->find_method_by_name($_) } $self->get_all_method_names;
  69 }
  70
  71 sub get_all_method_names {
  72     my $self = shift;
  73     my %uniq;
  74     return grep { $uniq{$_}++ == 0 }
  75             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
  76             $self->linearized_isa;
  77 }
  78
  79 sub find_attribute_by_name{
  80     my($self, $name) = @_;
  81     my $attr;
  82     foreach my $class($self->linearized_isa){
  83         my $meta = Mouse::Util::get_metaclass_by_name($class) or next;
  84         $attr = $meta->get_attribute($name) and last;
  85     }
  86     return $attr;
  87 }
  88
  89 sub add_attribute {
  90     my $self = shift;
  91
  92     my($attr, $name);
  93
  94     if(blessed $_[0]){
  95         $attr = $_[0];
  96
  97         $attr->isa('Mouse::Meta::Attribute')
  98             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
  99
 100         $name = $attr->name;
 101     }
 102     else{
 103         # _process_attribute
 104         $name = shift;
 105
 106         my %args = (@_ == 1) ? %{$_[0]} : @_;
 107
 108         defined($name)
 109             or $self->throw_error('You must provide a name for the attribute');
 110
 111         if ($name =~ s/^\+//) { # inherited attributes
 112             my $inherited_attr = $self->find_attribute_by_name($name)
 113                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 114
 115             $attr = $inherited_attr->clone_and_inherit_options(%args);
 116         }
 117         else{
 118             my($attribute_class, @traits) = $self->attribute_metaclass->interpolate_class(\%args);
 119             $args{traits} = \@traits if @traits;
 120
 121             $attr = $attribute_class->new($name, %args);
 122         }
 123     }
 124
 125     weaken( $attr->{associated_class} = $self );
 126
 127     $self->{attributes}{$attr->name} = $attr;
 128     $attr->install_accessors();
 129
 130     if(_MOUSE_VERBOSE && !$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 131         Carp::cluck(qq{Attribute (}.$attr->name.qq{) of class }.$self->name.qq{ has no associated methods (did you mean to provide an "is" argument?)});
 132     }
 133     return $attr;
 134 }
 135
 136 sub compute_all_applicable_attributes {
 137     Carp::cluck('compute_all_applicable_attributes() has been deprecated');
 138     return shift->get_all_attributes(@_)
 139 }
 140
 141 sub get_all_attributes {
 142     my $self = shift;
 143     my (@attr, %seen);
 144
 145     for my $class ($self->linearized_isa) {
 146         my $meta = Mouse::Util::get_metaclass_by_name($class)
 147             or next;
 148
 149         for my $name ($meta->get_attribute_list) {
 150             next if $seen{$name}++;
 151             push @attr, $meta->get_attribute($name);
 152         }
 153     }
 154
 155     return @attr;
 156 }
 157
 158 sub linearized_isa { @{ get_linear_isa($_[0]->name) } }
 159
 160 sub new_object {
 161     my $self = shift;
 162     my %args = (@_ == 1 ? %{$_[0]} : @_);
 163
 164     my $object = bless {}, $self->name;
 165
 166     $self->_initialize_object($object, \%args);
 167     return $object;
 168 }
 169
 170 sub _initialize_object{
 171     my($self, $object, $args) = @_;
 172
 173     my @triggers_queue;
 174
 175     foreach my $attribute ($self->get_all_attributes) {
 176         my $from = $attribute->init_arg;
 177         my $key  = $attribute->name;
 178
 179         if (defined($from) && exists($args->{$from})) {
 180             $object->{$key} = $attribute->_coerce_and_verify($args->{$from});
 181
 182             weaken($object->{$key})
 183                 if ref($object->{$key}) && $attribute->is_weak_ref;
 184
 185             if ($attribute->has_trigger) {
 186                 push @triggers_queue, [ $attribute->trigger, $object->{$key} ];
 187             }
 188         }
 189         else {
 190             if ($attribute->has_default || $attribute->has_builder) {
 191                 unless ($attribute->is_lazy) {
 192                     my $default = $attribute->default;
 193                     my $builder = $attribute->builder;
 194                     my $value =   $builder                ? $object->$builder()
 195                                 : ref($default) eq 'CODE' ? $object->$default()
 196                                 :                           $default;
 197
 198                     # XXX: we cannot use $attribute->set_value() because it invokes triggers.
 199                     $object->{$key} = $attribute->_coerce_and_verify($value, $object);;
 200
 201                     weaken($object->{$key})
 202                         if ref($object->{$key}) && $attribute->is_weak_ref;
 203                 }
 204             }
 205             else {
 206                 if ($attribute->is_required) {
 207                     $self->throw_error("Attribute (".$attribute->name.") is required");
 208                 }
 209             }
 210         }
 211     }
 212
 213     foreach my $trigger_and_value(@triggers_queue){
 214         my($trigger, $value) = @{$trigger_and_value};
 215         $trigger->($object, $value);
 216     }
 217
 218     if($self->is_anon_class){
 219         $object->{__METACLASS__} = $self;
 220     }
 221
 222     return $object;
 223 }
 224
 225 sub clone_object {
 226     my $class  = shift;
 227     my $object = shift;
 228     my %params = (@_ == 1) ? %{$_[0]} : @_;
 229
 230     (blessed($object) && $object->isa($class->name))
 231         || $class->throw_error("You must pass an instance of the metaclass (" . $class->name . "), not ($object)");
 232
 233     my $cloned = bless { %$object }, ref $object;
 234     $class->_initialize_object($cloned, \%params);
 235
 236     return $cloned;
 237 }
 238
 239 sub clone_instance {
 240     my ($class, $instance, %params) = @_;
 241
 242     Carp::cluck('clone_instance has been deprecated. Use clone_object instead')
 243         if _MOUSE_VERBOSE;
 244     return $class->clone_object($instance, %params);
 245 }
 246
 247 sub make_immutable {
 248     my $self = shift;
 249     my %args = (
 250         inline_constructor => 1,
 251         inline_destructor  => 1,
 252         constructor_name   => 'new',
 253         @_,
 254     );
 255
 256     $self->{is_immutable}++;
 257
 258     if ($args{inline_constructor}) {
 259         # generate and install
 260         Mouse::Meta::Method::Constructor->_generate_constructor_method($self, \%args);
 261     }
 262
 263     if ($args{inline_destructor}) {
 264         # generate and install
 265         Mouse::Meta::Method::Destructor->_generate_destructor_method($self, \%args);
 266     }
 267
 268     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 269     # at the end of a source file.
 270     return 1;
 271 }
 272
 273 sub make_mutable { not_supported }
 274
 275 sub is_immutable {  $_[0]->{is_immutable} }
 276 sub is_mutable   { !$_[0]->{is_immutable} }
 277
 278 sub _install_modifier_pp{
 279     my( $self, $into, $type, $name, $code ) = @_;
 280
 281     my $original = $into->can($name)
 282         or $self->throw_error("The method '$name' is not found in the inheritance hierarchy for class $into");
 283
 284     my $modifier_table = $self->{modifiers}{$name};
 285
 286     if(!$modifier_table){
 287         my(@before, @after, @around, $cache, $modified);
 288
 289         $cache = $original;
 290
 291         $modified = sub {
 292             for my $c (@before) { $c->(@_) }
 293
 294             if(wantarray){ # list context
 295                 my @rval = $cache->(@_);
 296
 297                 for my $c(@after){ $c->(@_) }
 298                 return @rval;
 299             }
 300             elsif(defined wantarray){ # scalar context
 301                 my $rval = $cache->(@_);
 302
 303                 for my $c(@after){ $c->(@_) }
 304                 return $rval;
 305             }
 306             else{ # void context
 307                 $cache->(@_);
 308
 309                 for my $c(@after){ $c->(@_) }
 310                 return;
 311             }
 312         };
 313
 314         $self->{modifiers}{$name} = $modifier_table = {
 315             original => $original,
 316
 317             before   => \@before,
 318             after    => \@after,
 319             around   => \@around,
 320
 321             cache    => \$cache, # cache for around modifiers
 322         };
 323
 324         $self->add_method($name => $modified);
 325     }
 326
 327     if($type eq 'before'){
 328         unshift @{$modifier_table->{before}}, $code;
 329     }
 330     elsif($type eq 'after'){
 331         push @{$modifier_table->{after}}, $code;
 332     }
 333     else{ # around
 334         push @{$modifier_table->{around}}, $code;
 335
 336         my $next = ${ $modifier_table->{cache} };
 337         ${ $modifier_table->{cache} } = sub{ $code->($next, @_) };
 338     }
 339
 340     return;
 341 }
 342
 343 sub _install_modifier {
 344     my ( $self, $into, $type, $name, $code ) = @_;
 345
 346     # load Class::Method::Modifiers first
 347     my $no_cmm_fast = do{
 348         local $@;
 349         eval q{ require Class::Method::Modifiers::Fast };
 350         $@;
 351     };
 352
 353     my $impl;
 354     if($no_cmm_fast){
 355         $impl = \&_install_modifier_pp;
 356     }
 357     else{
 358         my $install_modifier = Class::Method::Modifiers::Fast->can('_install_modifier');
 359         $impl = sub {
 360             my ( $self, $into, $type, $name, $code ) = @_;
 361             $install_modifier->(
 362                 $into,
 363                 $type,
 364                 $name,
 365                 $code
 366             );
 367             $self->{methods}{$name}++; # register it to the method map
 368             return;
 369         };
 370     }
 371
 372     # replace this method itself :)
 373     {
 374         no warnings 'redefine';
 375         *_install_modifier = $impl;
 376     }
 377
 378     $self->$impl( $into, $type, $name, $code );
 379 }
 380
 381 sub add_before_method_modifier {
 382     my ( $self, $name, $code ) = @_;
 383     $self->_install_modifier( $self->name, 'before', $name, $code );
 384 }
 385
 386 sub add_around_method_modifier {
 387     my ( $self, $name, $code ) = @_;
 388     $self->_install_modifier( $self->name, 'around', $name, $code );
 389 }
 390
 391 sub add_after_method_modifier {
 392     my ( $self, $name, $code ) = @_;
 393     $self->_install_modifier( $self->name, 'after', $name, $code );
 394 }
 395
 396 sub add_override_method_modifier {
 397     my ($self, $name, $code) = @_;
 398
 399     if($self->has_method($name)){
 400         $self->throw_error("Cannot add an override method if a local method is already present");
 401     }
 402
 403     my $package = $self->name;
 404
 405     my $super_body = $package->can($name)
 406         or $self->throw_error("You cannot override '$name' because it has no super method");
 407
 408     $self->add_method($name => sub {
 409         local $Mouse::SUPER_PACKAGE = $package;
 410         local $Mouse::SUPER_BODY    = $super_body;
 411         local @Mouse::SUPER_ARGS    = @_;
 412
 413         $code->(@_);
 414     });
 415     return;
 416 }
 417
 418 sub add_augment_method_modifier {
 419     my ($self, $name, $code) = @_;
 420     if($self->has_method($name)){
 421         $self->throw_error("Cannot add an augment method if a local method is already present");
 422     }
 423
 424     my $super = $self->find_method_by_name($name)
 425         or $self->throw_error("You cannot augment '$name' because it has no super method");
 426
 427     my $super_package = $super->package_name;
 428     my $super_body    = $super->body;
 429
 430     $self->add_method($name => sub{
 431         local $Mouse::INNER_BODY{$super_package} = $code;
 432         local $Mouse::INNER_ARGS{$super_package} = [@_];
 433         $super_body->(@_);
 434     });
 435     return;
 436 }
 437
 438 sub does_role {
 439     my ($self, $role_name) = @_;
 440
 441     (defined $role_name)
 442         || $self->throw_error("You must supply a role name to look for");
 443
 444     for my $class ($self->linearized_isa) {
 445         my $meta = Mouse::Util::get_metaclass_by_name($class);
 446         next unless $meta && $meta->can('roles');
 447
 448         for my $role (@{ $meta->roles }) {
 449
 450             return 1 if $role->does_role($role_name);
 451         }
 452     }
 453
 454     return 0;
 455 }
 456
 457 1;
 458
 459 __END__
 460
 461 =head1 NAME
 462
 463 Mouse::Meta::Class - The Mouse class metaclass
 464
 465 =head1 METHODS
 466
 467 =head2 C<< initialize(ClassName) -> Mouse::Meta::Class >>
 468
 469 Finds or creates a C<Mouse::Meta::Class> instance for the given ClassName. Only
 470 one instance should exist for a given class.
 471
 472 =head2 C<< name -> ClassName >>
 473
 474 Returns the name of the owner class.
 475
 476 =head2 C<< superclasses -> ClassNames >> C<< superclass(ClassNames) >>
 477
 478 Gets (or sets) the list of superclasses of the owner class.
 479
 480 =head2 C<< add_method(name => CodeRef) >>
 481
 482 Adds a method to the owner class.
 483
 484 =head2 C<< has_method(name) -> Bool >>
 485
 486 Returns whether we have a method with the given name.
 487
 488 =head2 C<< get_method(name) -> Mouse::Meta::Method | undef >>
 489
 490 Returns a L<Mouse::Meta::Method> with the given name.
 491
 492 Note that you can also use C<< $metaclass->name->can($name) >> for a method body.
 493
 494 =head2 C<< get_method_list -> Names >>
 495
 496 Returns a list of method names which are defined in the local class.
 497 If you want a list of all applicable methods for a class, use the
 498 C<get_all_methods> method.
 499
 500 =head2 C<< get_all_methods -> (Mouse::Meta::Method) >>
 501
 502 Return the list of all L<Mouse::Meta::Method> instances associated with
 503 the class and its superclasses.
 504
 505 =head2 C<< add_attribute(name => spec | Mouse::Meta::Attribute) >>
 506
 507 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 508 class.
 509
 510 =head2 C<< has_attribute(Name) -> Bool >>
 511
 512 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 513
 514 =head2 C<< get_attribute Name -> Mouse::Meta::Attribute | undef >>
 515
 516 Returns the L<Mouse::Meta::Attribute> with the given name.
 517
 518 =head2 C<< get_attribute_list -> Names >>
 519
 520 Returns a list of attribute names which are defined in the local
 521 class. If you want a list of all applicable attributes for a class,
 522 use the C<get_all_attributes> method.
 523
 524 =head2 C<< get_all_attributes -> (Mouse::Meta::Attribute) >>
 525
 526 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 527 this class and its superclasses.
 528
 529 =head2 C<< linearized_isa -> [ClassNames] >>
 530
 531 Returns the list of classes in method dispatch order, with duplicates removed.
 532
 533 =head2 C<< new_object(Parameters) -> Instance >>
 534
 535 Creates a new instance.
 536
 537 =head2 C<< clone_object(Instance, Parameters) -> Instance >>
 538
 539 Clones the given instance which must be an instance governed by this
 540 metaclass.
 541
 542 =head2 C<< throw_error(Message, Parameters) >>
 543
 544 Throws an error with the given message.
 545
 546 =head1 SEE ALSO
 547
 548 L<Moose::Meta::Class>
 549
 550 L<Class::MOP::Class>
 551
 552 =cut
 553