[gitmo/Mouse.git] / lib / Mouse / PurePerl.pm

package Mouse::PurePerl;
# The pure Perl backend for Mouse
package Mouse::Util;
use strict;
use warnings;
use warnings FATAL => 'redefine'; # to avoid to load Mouse::PurePerl twice

use B ();

require Mouse::Util;


# taken from Class/MOP.pm
sub is_valid_class_name {
    my $class = shift;

    return 0 if ref($class);
    return 0 unless defined($class);

    return 1 if $class =~ /\A \w+ (?: :: \w+ )* \z/xms;

    return 0;
}

sub is_class_loaded {
    my $class = shift;

    return 0 if ref($class) || !defined($class) || !length($class);

    # walk the symbol table tree to avoid autovififying
    # \*{${main::}{"Foo::"}{"Bar::"}} == \*main::Foo::Bar::

    my $pack = \%::;
    foreach my $part (split('::', $class)) {
        $part .= '::';
        return 0 if !exists $pack->{$part};

        my $entry = \$pack->{$part};
        return 0 if ref($entry) ne 'GLOB';
        $pack = *{$entry}{HASH};
    }

    return 0 if !%{$pack};

    # check for $VERSION or @ISA
    return 1 if exists $pack->{VERSION}
             && defined *{$pack->{VERSION}}{SCALAR} && defined ${ $pack->{VERSION} };
    return 1 if exists $pack->{ISA}
             && defined *{$pack->{ISA}}{ARRAY} && @{ $pack->{ISA} } != 0;

    # check for any method
    foreach my $name( keys %{$pack} ) {
        my $entry = \$pack->{$name};
        return 1 if ref($entry) ne 'GLOB' || defined *{$entry}{CODE};
    }

    # fail
    return 0;
}


# taken from Sub::Identify
sub get_code_info {
    my ($coderef) = @_;
    ref($coderef) or return;

    my $cv = B::svref_2object($coderef);
    $cv->isa('B::CV') or return;

    my $gv = $cv->GV;
    $gv->isa('B::GV') or return;

    return ($gv->STASH->NAME, $gv->NAME);
}

sub get_code_package{
    my($coderef) = @_;

    my $cv = B::svref_2object($coderef);
    $cv->isa('B::CV') or return '';

    my $gv = $cv->GV;
    $gv->isa('B::GV') or return '';

    return $gv->STASH->NAME;
}

sub get_code_ref{
    my($package, $name) = @_;
    no strict 'refs';
    no warnings 'once';
    use warnings FATAL => 'uninitialized';
    return *{$package . '::' . $name}{CODE};
}

sub generate_isa_predicate_for {
    my($for_class, $name) = @_;

    my $predicate = sub{ Scalar::Util::blessed($_[0]) && $_[0]->isa($for_class) };

    if(defined $name){
        Mouse::Util::install_subroutines(scalar caller, $name => $predicate);
        return;
    }

    return $predicate;
}

sub generate_can_predicate_for {
    my($methods_ref, $name) = @_;

    my @methods = @{$methods_ref};

    my $predicate = sub{
        my($instance) = @_;
        if(Scalar::Util::blessed($instance)){
            foreach my $method(@methods){
                if(!$instance->can($method)){
                    return 0;
                }
            }
            return 1;
        }
        return 0;
    };

    if(defined $name){
        Mouse::Util::install_subroutines(scalar caller, $name => $predicate);
        return;
    }

    return $predicate;
}

package Mouse::Util::TypeConstraints;

use Scalar::Util qw(blessed looks_like_number openhandle);

sub Any        { 1 }
sub Item       { 1 }

sub Bool       { $_[0] ? $_[0] eq '1' : 1 }
sub Undef      { !defined($_[0]) }
sub Defined    {  defined($_[0])  }
sub Value      {  defined($_[0]) && !ref($_[0]) }
sub Num        {  looks_like_number($_[0]) }
sub Int        {
    my($value) = @_;
    looks_like_number($value) && $value =~ /\A [+-]? [0-9]+  \z/xms;
}
sub Str        {
    my($value) = @_;
    return defined($value) && ref(\$value) eq 'SCALAR';
}

sub Ref        { ref($_[0]) }
sub ScalarRef  {
    my($value) = @_;
    return ref($value) eq 'SCALAR' || ref($value) eq 'REF';
}
sub ArrayRef   { ref($_[0]) eq 'ARRAY'  }
sub HashRef    { ref($_[0]) eq 'HASH'   }
sub CodeRef    { ref($_[0]) eq 'CODE'   }
sub RegexpRef  { ref($_[0]) eq 'Regexp' }
sub GlobRef    { ref($_[0]) eq 'GLOB'   }

sub FileHandle {
    return openhandle($_[0])  || (blessed($_[0]) && $_[0]->isa("IO::Handle"))
}

sub Object     { blessed($_[0]) && blessed($_[0]) ne 'Regexp' }

sub ClassName  { Mouse::Util::is_class_loaded($_[0]) }
sub RoleName   { (Mouse::Util::class_of($_[0]) || return 0)->isa('Mouse::Meta::Role') }

sub _parameterize_ArrayRef_for {
    my($type_parameter) = @_;
    my $check = $type_parameter->_compiled_type_constraint;

    return sub {
        foreach my $value (@{$_}) {
            return undef unless $check->($value);
        }
        return 1;
    }
}

sub _parameterize_HashRef_for {
    my($type_parameter) = @_;
    my $check = $type_parameter->_compiled_type_constraint;

    return sub {
        foreach my $value(values %{$_}){
            return undef unless $check->($value);
        }
        return 1;
    };
}

# 'Maybe' type accepts 'Any', so it requires parameters
sub _parameterize_Maybe_for {
    my($type_parameter) = @_;
    my $check = $type_parameter->_compiled_type_constraint;

    return sub{
        return !defined($_) || $check->($_);
    };
}

package Mouse::Meta::Module;

sub name          { $_[0]->{package} }

sub _method_map   { $_[0]->{methods} }
sub _attribute_map{ $_[0]->{attributes} }

sub namespace{
    my $name = $_[0]->{package};
    no strict 'refs';
    return \%{ $name . '::' };
}

sub add_method {
    my($self, $name, $code) = @_;

    if(!defined $name){
        $self->throw_error('You must pass a defined name');
    }
    if(!defined $code){
        $self->throw_error('You must pass a defined code');
    }

    if(ref($code) ne 'CODE'){
        $code = \&{$code}; # coerce
    }

    $self->{methods}->{$name} = $code; # Moose stores meta object here.

    Mouse::Util::install_subroutines($self->name,
        $name => $code,
    );
    return;
}

my $generate_class_accessor = sub {
    my($name) = @_;
    return sub {
        my $self = shift;
        if(@_) {
            return $self->{$name} = shift;
        }

        foreach my $class($self->linearized_isa) {
            my $meta = Mouse::Util::get_metaclass_by_name($class)
                or next;

            if(exists $meta->{$name}) {
                return $meta->{$name};
            }
        }
        return undef;
    };
};


package Mouse::Meta::Class;

use Mouse::Meta::Method::Constructor;
use Mouse::Meta::Method::Destructor;

sub method_metaclass    { $_[0]->{method_metaclass}    || 'Mouse::Meta::Method'    }
sub attribute_metaclass { $_[0]->{attribute_metaclass} || 'Mouse::Meta::Attribute' }

sub constructor_class { $_[0]->{constructor_class} || 'Mouse::Meta::Method::Constructor' }
sub destructor_class  { $_[0]->{destructor_class}  || 'Mouse::Meta::Method::Destructor'  }

sub is_anon_class{
    return exists $_[0]->{anon_serial_id};
}

sub roles { $_[0]->{roles} }

sub linearized_isa { @{ Mouse::Util::get_linear_isa($_[0]->{package}) } }

sub get_all_attributes {
    my($self) = @_;
    my %attrs = map { %{ $self->initialize($_)->{attributes} } } reverse $self->linearized_isa;
    return values %attrs;
}

sub new_object {
    my $meta = shift;
    my %args = (@_ == 1 ? %{$_[0]} : @_);

    my $object = bless {}, $meta->name;

    $meta->_initialize_object($object, \%args, 0);
    # BUILDALL
    if( $object->can('BUILD') ) {
        for my $class (reverse $meta->linearized_isa) {
            my $build = Mouse::Util::get_code_ref($class, 'BUILD')
                || next;

            $object->$build(\%args);
        }
    }
    return $object;
}

sub clone_object {
    my $class  = shift;
    my $object = shift;
    my $args   = $object->Mouse::Object::BUILDARGS(@_);

    (blessed($object) && $object->isa($class->name))
        || $class->throw_error("You must pass an instance of the metaclass (" . $class->name . "), not ($object)");

    my $cloned = bless { %$object }, ref $object;
    $class->_initialize_object($cloned, $args, 1);
    return $cloned;
}

sub _initialize_object{
    my($self, $object, $args, $is_cloning) = @_;
    # The initializer, which is used everywhere, must be clear
    # when an attribute is added. See Mouse::Meta::Class::add_attribute.
    my $initializer = $self->{_initialize_object} ||= do {
        Mouse::Util::load_class($self->constructor_class)
            ->_generate_initialize_object($self);
    };
    goto &{$initializer};
}

sub is_immutable {  $_[0]->{is_immutable} }

sub strict_constructor;
*strict_constructor = $generate_class_accessor->('strict_constructor');

sub _report_unknown_args {
    my($metaclass, $attrs, $args) = @_;

    my @unknowns;
    my %init_args;
    foreach my $attr(@{$attrs}){
        my $init_arg = $attr->init_arg;
        if(defined $init_arg){
            $init_args{$init_arg}++;
        }
    }

    while(my $key = each %{$args}){
        if(!exists $init_args{$key}){
            push @unknowns, $key;
        }
    }

    $metaclass->throw_error( sprintf
        "Unknown attribute passed to the constructor of %s: %s",
        $metaclass->name, Mouse::Util::english_list(@unknowns),
    );
}

package Mouse::Meta::Role;

sub method_metaclass{ $_[0]->{method_metaclass} || 'Mouse::Meta::Role::Method' }

sub is_anon_role{
    return exists $_[0]->{anon_serial_id};
}

sub get_roles { $_[0]->{roles} }

sub add_before_method_modifier {
    my ($self, $method_name, $method) = @_;

    push @{ $self->{before_method_modifiers}{$method_name} ||= [] }, $method;
    return;
}
sub add_around_method_modifier {
    my ($self, $method_name, $method) = @_;

    push @{ $self->{around_method_modifiers}{$method_name} ||= [] }, $method;
    return;
}
sub add_after_method_modifier {
    my ($self, $method_name, $method) = @_;

    push @{ $self->{after_method_modifiers}{$method_name} ||= [] }, $method;
    return;
}

sub get_before_method_modifiers {
    my ($self, $method_name) = @_;
    return @{ $self->{before_method_modifiers}{$method_name} ||= [] }
}
sub get_around_method_modifiers {
    my ($self, $method_name) = @_;
    return @{ $self->{around_method_modifiers}{$method_name} ||= [] }
}
sub get_after_method_modifiers {
    my ($self, $method_name) = @_;
    return @{ $self->{after_method_modifiers}{$method_name} ||= [] }
}

sub add_metaclass_accessor { # for meta roles (a.k.a. traits)
    my($meta, $name) = @_;
    $meta->add_method($name => $generate_class_accessor->($name));
    return;
}

package Mouse::Meta::Attribute;

require Mouse::Meta::Method::Accessor;

sub accessor_metaclass{ $_[0]->{accessor_metaclass} || 'Mouse::Meta::Method::Accessor' }

# readers

sub name                 { $_[0]->{name}                   }
sub associated_class     { $_[0]->{associated_class}       }

sub accessor             { $_[0]->{accessor}               }
sub reader               { $_[0]->{reader}                 }
sub writer               { $_[0]->{writer}                 }
sub predicate            { $_[0]->{predicate}              }
sub clearer              { $_[0]->{clearer}                }
sub handles              { $_[0]->{handles}                }

sub _is_metadata         { $_[0]->{is}                     }
sub is_required          { $_[0]->{required}               }
sub default              { $_[0]->{default}                }
sub is_lazy              { $_[0]->{lazy}                   }
sub is_lazy_build        { $_[0]->{lazy_build}             }
sub is_weak_ref          { $_[0]->{weak_ref}               }
sub init_arg             { $_[0]->{init_arg}               }
sub type_constraint      { $_[0]->{type_constraint}        }

sub trigger              { $_[0]->{trigger}                }
sub builder              { $_[0]->{builder}                }
sub should_auto_deref    { $_[0]->{auto_deref}             }
sub should_coerce        { $_[0]->{coerce}                 }

sub documentation        { $_[0]->{documentation}          }
sub insertion_order      { $_[0]->{insertion_order}        }

# predicates

sub has_accessor         { exists $_[0]->{accessor}        }
sub has_reader           { exists $_[0]->{reader}          }
sub has_writer           { exists $_[0]->{writer}          }
sub has_predicate        { exists $_[0]->{predicate}       }
sub has_clearer          { exists $_[0]->{clearer}         }
sub has_handles          { exists $_[0]->{handles}         }

sub has_default          { exists $_[0]->{default}         }
sub has_type_constraint  { exists $_[0]->{type_constraint} }
sub has_trigger          { exists $_[0]->{trigger}         }
sub has_builder          { exists $_[0]->{builder}         }

sub has_documentation    { exists $_[0]->{documentation}   }

sub _process_options{
    my($class, $name, $args) = @_;

    # taken from Class::MOP::Attribute::new

    defined($name)
        or $class->throw_error('You must provide a name for the attribute');

    if(!exists $args->{init_arg}){
        $args->{init_arg} = $name;
    }

    # 'required' requires eigher 'init_arg', 'builder', or 'default'
    my $can_be_required = defined( $args->{init_arg} );

    if(exists $args->{builder}){
        # XXX:
        # Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
        # This feature will be changed in a future. (gfx)
        $class->throw_error('builder must be a defined scalar value which is a method name')
            #if ref $args->{builder} || !defined $args->{builder};
            if !defined $args->{builder};

        $can_be_required++;
    }
    elsif(exists $args->{default}){
        if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
            $class->throw_error("References are not allowed as default values, you must "
                              . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
        }
        $can_be_required++;
    }

    if( $args->{required} && !$can_be_required ) {
        $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
    }

    # taken from Mouse::Meta::Attribute->new and ->_process_args

    if(exists $args->{is}){
        my $is = $args->{is};

        if($is eq 'ro'){
            $args->{reader} ||= $name;
        }
        elsif($is eq 'rw'){
            if(exists $args->{writer}){
                $args->{reader} ||= $name;
             }
             else{
                $args->{accessor} ||= $name;
             }
        }
        elsif($is eq 'bare'){
            # do nothing, but don't complain (later) about missing methods
        }
        else{
            $is = 'undef' if !defined $is;
            $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
        }
    }

    my $tc;
    if(exists $args->{isa}){
        $tc = $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
    }

    if(exists $args->{does}){
        if(defined $tc){ # both isa and does supplied
            my $does_ok = do{
                local $@;
                eval{ "$tc"->does($args) };
            };
            if(!$does_ok){
                $class->throw_error("Cannot have both an isa option and a does option because '$tc' does not do '$args->{does}' on attribute ($name)");
            }
        }
        else {
            $tc = $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
        }
    }

    if($args->{coerce}){
        defined($tc)
            || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");

        $args->{weak_ref}
            && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
    }

    if ($args->{lazy_build}) {
        exists($args->{default})
            && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");

        $args->{lazy}      = 1;
        $args->{builder} ||= "_build_${name}";
        if ($name =~ /^_/) {
            $args->{clearer}   ||= "_clear${name}";
            $args->{predicate} ||= "_has${name}";
        }
        else {
            $args->{clearer}   ||= "clear_${name}";
            $args->{predicate} ||= "has_${name}";
        }
    }

    if ($args->{auto_deref}) {
        defined($tc)
            || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");

        ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
            || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
    }

    if (exists $args->{trigger}) {
        ('CODE' eq ref $args->{trigger})
            || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
    }

    if ($args->{lazy}) {
        (exists $args->{default} || defined $args->{builder})
            || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
    }

    return;
}


package Mouse::Meta::TypeConstraint;

use overload
    '""' => '_as_string',
    '0+' => '_identity',
    '|'  => '_unite',

    fallback => 1;

sub name    { $_[0]->{name}    }
sub parent  { $_[0]->{parent}  }
sub message { $_[0]->{message} }

sub _identity  { Scalar::Util::refaddr($_[0]) } # overload 0+

sub type_parameter           { $_[0]->{type_parameter} }
sub _compiled_type_constraint{ $_[0]->{compiled_type_constraint} }
sub _compiled_type_coercion  { $_[0]->{_compiled_type_coercion}  }

sub __is_parameterized { exists $_[0]->{type_parameter} }
sub has_coercion {       exists $_[0]->{_compiled_type_coercion} }


sub compile_type_constraint{
    my($self) = @_;

    # add parents first
    my @checks;
    for(my $parent = $self->{parent}; defined $parent; $parent = $parent->{parent}){
         if($parent->{hand_optimized_type_constraint}){
            unshift @checks, $parent->{hand_optimized_type_constraint};
            last; # a hand optimized constraint must include all the parents
        }
        elsif($parent->{constraint}){
            unshift @checks, $parent->{constraint};
        }
    }

    # then add child
    if($self->{constraint}){
        push @checks, $self->{constraint};
    }

    if($self->{type_constraints}){ # Union
        my @types = map{ $_->{compiled_type_constraint} } @{ $self->{type_constraints} };
        push @checks, sub{
            foreach my $c(@types){
                return 1 if $c->($_[0]);
            }
            return 0;
        };
    }

    if(@checks == 0){
        $self->{compiled_type_constraint} = \&Mouse::Util::TypeConstraints::Any;
    }
    else{
        $self->{compiled_type_constraint} =  sub{
            my(@args) = @_;
            local $_ = $args[0];
            foreach my $c(@checks){
                return undef if !$c->(@args);
            }
            return 1;
        };
    }
    return;
}

sub check {
    my $self = shift;
    return $self->_compiled_type_constraint->(@_);
}


package Mouse::Object;

sub BUILDARGS {
    my $class = shift;

    if (scalar @_ == 1) {
        (ref($_[0]) eq 'HASH')
            || $class->meta->throw_error("Single parameters to new() must be a HASH ref");

        return {%{$_[0]}};
    }
    else {
        return {@_};
    }
}

sub new {
    my $class = shift;
    my $args  = $class->BUILDARGS(@_);
    return $class->meta->new_object($args);
}

sub DESTROY {
    my $self = shift;

    return unless $self->can('DEMOLISH'); # short circuit

    my $e = do{
        local $?;
        local $@;
        eval{
            # DEMOLISHALL

            # We cannot count on being able to retrieve a previously made
            # metaclass, _or_ being able to make a new one during global
            # destruction. However, we should still be able to use mro at
            # that time (at least tests suggest so ;)

            foreach my $class (@{ Mouse::Util::get_linear_isa(ref $self) }) {
                my $demolish = Mouse::Util::get_code_ref($class, 'DEMOLISH')
                    || next;

                $self->$demolish($Mouse::Util::in_global_destruction);
            }
        };
        $@;
    };

    no warnings 'misc';
    die $e if $e; # rethrow
}

sub BUILDALL {
    my $self = shift;

    # short circuit
    return unless $self->can('BUILD');

    for my $class (reverse $self->meta->linearized_isa) {
        my $build = Mouse::Util::get_code_ref($class, 'BUILD')
            || next;

        $self->$build(@_);
    }
    return;
}

sub DEMOLISHALL;
*DEMOLISHALL = \&DESTROY;

1;
__END__

=head1 NAME

Mouse::PurePerl - A Mouse guts in pure Perl

=head1 VERSION

This document describes Mouse version 0.73

=head1 SEE ALSO

L<Mouse::XS>

=cut
Commit	Line	Data
ccb38d0b	1	package Mouse::PurePerl;
4bef84ef	2	# The pure Perl backend for Mouse
6fffa617	3	package Mouse::Util;
df6dd016	4	use strict;
df6dd016	5	use warnings;
4bef84ef	6	use warnings FATAL => 'redefine'; # to avoid to load Mouse::PurePerl twice
df6dd016	7
	8	use B ();
	9
4bef84ef	10	require Mouse::Util;
4bef84ef	11
0ffc4183	12
	13	# taken from Class/MOP.pm
	14	sub is_valid_class_name {
	15	my $class = shift;
	16
	17	return 0 if ref($class);
	18	return 0 unless defined($class);
	19
	20	return 1 if $class =~ /\A \w+ (?: :: \w+ )* \z/xms;
	21
	22	return 0;
	23	}
	24
df6dd016	25	sub is_class_loaded {
	26	my $class = shift;
	27
	28	return 0 if ref($class) \|\| !defined($class) \|\| !length($class);
	29
	30	# walk the symbol table tree to avoid autovififying
3bb9e54e	31	# \{${main::}{"Foo::"}{"Bar::"}} == \main::Foo::Bar::
df6dd016	32
	33	my $pack = \%::;
	34	foreach my $part (split('::', $class)) {
3bb9e54e	35	$part .= '::';
	36	return 0 if !exists $pack->{$part};
	37
	38	my $entry = \$pack->{$part};
df6dd016	39	return 0 if ref($entry) ne 'GLOB';
3bb9e54e	40	$pack = *{$entry}{HASH};
df6dd016	41	}
df6dd016	42
3bb9e54e	43	return 0 if !%{$pack};
3bb9e54e	44
df6dd016	45	# check for $VERSION or @ISA
	46	return 1 if exists $pack->{VERSION}
	47	&& defined *{$pack->{VERSION}}{SCALAR} && defined ${ $pack->{VERSION} };
	48	return 1 if exists $pack->{ISA}
	49	&& defined *{$pack->{ISA}}{ARRAY} && @{ $pack->{ISA} } != 0;
	50
	51	# check for any method
	52	foreach my $name( keys %{$pack} ) {
	53	my $entry = \$pack->{$name};
	54	return 1 if ref($entry) ne 'GLOB' \|\| defined *{$entry}{CODE};
	55	}
	56
	57	# fail
	58	return 0;
	59	}
	60
	61
	62	# taken from Sub::Identify
	63	sub get_code_info {
	64	my ($coderef) = @_;
	65	ref($coderef) or return;
	66
	67	my $cv = B::svref_2object($coderef);
	68	$cv->isa('B::CV') or return;
	69
	70	my $gv = $cv->GV;
	71	$gv->isa('B::GV') or return;
	72
	73	return ($gv->STASH->NAME, $gv->NAME);
	74	}
	75
	76	sub get_code_package{
	77	my($coderef) = @_;
	78
	79	my $cv = B::svref_2object($coderef);
	80	$cv->isa('B::CV') or return '';
	81
	82	my $gv = $cv->GV;
	83	$gv->isa('B::GV') or return '';
	84
	85	return $gv->STASH->NAME;
	86	}
	87
7d96ae4d	88	sub get_code_ref{
	89	my($package, $name) = @_;
	90	no strict 'refs';
	91	no warnings 'once';
	92	use warnings FATAL => 'uninitialized';
	93	return *{$package . '::' . $name}{CODE};
	94	}
	95
e3540312	96	sub generate_isa_predicate_for {
1d5ecd5f	97	my($for_class, $name) = @_;
1d5ecd5f	98
f48920c1	99	my $predicate = sub{ Scalar::Util::blessed($_[0]) && $_[0]->isa($for_class) };
1d5ecd5f	100
1d5ecd5f	101	if(defined $name){
1194aede	102	Mouse::Util::install_subroutines(scalar caller, $name => $predicate);
1d5ecd5f	103	return;
	104	}
	105
	106	return $predicate;
	107	}
	108
ebe91068	109	sub generate_can_predicate_for {
	110	my($methods_ref, $name) = @_;
	111
	112	my @methods = @{$methods_ref};
	113
	114	my $predicate = sub{
	115	my($instance) = @_;
	116	if(Scalar::Util::blessed($instance)){
	117	foreach my $method(@methods){
	118	if(!$instance->can($method)){
	119	return 0;
	120	}
	121	}
	122	return 1;
	123	}
	124	return 0;
	125	};
	126
	127	if(defined $name){
1194aede	128	Mouse::Util::install_subroutines(scalar caller, $name => $predicate);
ebe91068	129	return;
	130	}
	131
	132	return $predicate;
	133	}
1d5ecd5f	134
6fffa617	135	package Mouse::Util::TypeConstraints;
f48920c1	136
	137	use Scalar::Util qw(blessed looks_like_number openhandle);
	138
7d96ae4d	139	sub Any { 1 }
7d96ae4d	140	sub Item { 1 }
7d96ae4d	141
	142	sub Bool { $_[0] ? $_[0] eq '1' : 1 }
	143	sub Undef { !defined($_[0]) }
	144	sub Defined { defined($_[0]) }
	145	sub Value { defined($_[0]) && !ref($_[0]) }
1adf864e	146	sub Num { looks_like_number($_[0]) }
	147	sub Int {
	148	my($value) = @_;
0cfe08a4	149	looks_like_number($value) && $value =~ /\A [+-]? [0-9]+ \z/xms;
1adf864e	150	}
9848d3e1	151	sub Str {
	152	my($value) = @_;
	153	return defined($value) && ref(\$value) eq 'SCALAR';
	154	}
7d96ae4d	155
7d96ae4d	156	sub Ref { ref($_[0]) }
9848d3e1	157	sub ScalarRef {
9848d3e1	158	my($value) = @_;
4068a8f6	159	return ref($value) eq 'SCALAR' \|\| ref($value) eq 'REF';
9848d3e1	160	}
7d96ae4d	161	sub ArrayRef { ref($_[0]) eq 'ARRAY' }
	162	sub HashRef { ref($_[0]) eq 'HASH' }
	163	sub CodeRef { ref($_[0]) eq 'CODE' }
	164	sub RegexpRef { ref($_[0]) eq 'Regexp' }
	165	sub GlobRef { ref($_[0]) eq 'GLOB' }
	166
	167	sub FileHandle {
9848d3e1	168	return openhandle($_[0]) \|\| (blessed($_[0]) && $_[0]->isa("IO::Handle"))
7d96ae4d	169	}
	170
	171	sub Object { blessed($_[0]) && blessed($_[0]) ne 'Regexp' }
	172
	173	sub ClassName { Mouse::Util::is_class_loaded($_[0]) }
	174	sub RoleName { (Mouse::Util::class_of($_[0]) \|\| return 0)->isa('Mouse::Meta::Role') }
	175
619338ac	176	sub _parameterize_ArrayRef_for {
	177	my($type_parameter) = @_;
	178	my $check = $type_parameter->_compiled_type_constraint;
	179
	180	return sub {
	181	foreach my $value (@{$_}) {
	182	return undef unless $check->($value);
	183	}
	184	return 1;
	185	}
	186	}
	187
	188	sub _parameterize_HashRef_for {
	189	my($type_parameter) = @_;
	190	my $check = $type_parameter->_compiled_type_constraint;
	191
	192	return sub {
	193	foreach my $value(values %{$_}){
	194	return undef unless $check->($value);
	195	}
	196	return 1;
	197	};
	198	}
	199
	200	# 'Maybe' type accepts 'Any', so it requires parameters
	201	sub _parameterize_Maybe_for {
	202	my($type_parameter) = @_;
	203	my $check = $type_parameter->_compiled_type_constraint;
	204
	205	return sub{
	206	return !defined($_) \|\| $check->($_);
	207	};
9b923ac8	208	}
7d96ae4d	209
6fffa617	210	package Mouse::Meta::Module;
43165725	211
926404f2	212	sub name { $_[0]->{package} }
	213
	214	sub _method_map { $_[0]->{methods} }
c5f6ad05	215	sub _attribute_map{ $_[0]->{attributes} }
43165725	216
2591e962	217	sub namespace{
	218	my $name = $_[0]->{package};
	219	no strict 'refs';
	220	return \%{ $name . '::' };
	221	}
	222
3e44140b	223	sub add_method {
	224	my($self, $name, $code) = @_;
	225
	226	if(!defined $name){
	227	$self->throw_error('You must pass a defined name');
	228	}
	229	if(!defined $code){
	230	$self->throw_error('You must pass a defined code');
	231	}
	232
	233	if(ref($code) ne 'CODE'){
	234	$code = \&{$code}; # coerce
	235	}
	236
	237	$self->{methods}->{$name} = $code; # Moose stores meta object here.
	238
1194aede	239	Mouse::Util::install_subroutines($self->name,
	240	$name => $code,
	241	);
3e44140b	242	return;
	243	}
	244
b4dc9315	245	my $generate_class_accessor = sub {
	246	my($name) = @_;
	247	return sub {
	248	my $self = shift;
	249	if(@_) {
	250	return $self->{$name} = shift;
	251	}
	252
	253	foreach my $class($self->linearized_isa) {
	254	my $meta = Mouse::Util::get_metaclass_by_name($class)
	255	or next;
	256
	257	if(exists $meta->{$name}) {
	258	return $meta->{$name};
	259	}
	260	}
	261	return undef;
	262	};
	263	};
	264
	265
6fffa617	266	package Mouse::Meta::Class;
43165725	267
e088c5fc	268	use Mouse::Meta::Method::Constructor;
	269	use Mouse::Meta::Method::Destructor;
	270
e058b279	271	sub method_metaclass { $_[0]->{method_metaclass} \|\| 'Mouse::Meta::Method' }
	272	sub attribute_metaclass { $_[0]->{attribute_metaclass} \|\| 'Mouse::Meta::Attribute' }
	273
	274	sub constructor_class { $_[0]->{constructor_class} \|\| 'Mouse::Meta::Method::Constructor' }
	275	sub destructor_class { $_[0]->{destructor_class} \|\| 'Mouse::Meta::Method::Destructor' }
4e7e3250	276
43165725	277	sub is_anon_class{
	278	return exists $_[0]->{anon_serial_id};
	279	}
	280
	281	sub roles { $_[0]->{roles} }
	282
bc76ed1c	283	sub linearized_isa { @{ Mouse::Util::get_linear_isa($_[0]->{package}) } }
cccb83de	284
da4432f3	285	sub get_all_attributes {
da4432f3	286	my($self) = @_;
047d7af0	287	my %attrs = map { %{ $self->initialize($_)->{attributes} } } reverse $self->linearized_isa;
da4432f3	288	return values %attrs;
	289	}
	290
ba153b33	291	sub new_object {
b5956f03	292	my $meta = shift;
ba153b33	293	my %args = (@_ == 1 ? %{$_[0]} : @_);
ba153b33	294
b5956f03	295	my $object = bless {}, $meta->name;
ba153b33	296
a3a09e38	297	$meta->_initialize_object($object, \%args, 0);
b5956f03	298	# BUILDALL
	299	if( $object->can('BUILD') ) {
	300	for my $class (reverse $meta->linearized_isa) {
	301	my $build = Mouse::Util::get_code_ref($class, 'BUILD')
	302	\|\| next;
	303
	304	$object->$build(\%args);
	305	}
	306	}
ba153b33	307	return $object;
	308	}
	309
13b99908	310	sub clone_object {
	311	my $class = shift;
	312	my $object = shift;
	313	my $args = $object->Mouse::Object::BUILDARGS(@_);
	314
	315	(blessed($object) && $object->isa($class->name))
	316	\|\| $class->throw_error("You must pass an instance of the metaclass (" . $class->name . "), not ($object)");
	317
	318	my $cloned = bless { %$object }, ref $object;
	319	$class->_initialize_object($cloned, $args, 1);
13b99908	320	return $cloned;
	321	}
	322
4e7e3250	323	sub _initialize_object{
cb6a9721	324	my($self, $object, $args, $is_cloning) = @_;
74de0f8b	325	# The initializer, which is used everywhere, must be clear
74de0f8b	326	# when an attribute is added. See Mouse::Meta::Class::add_attribute.
a3a09e38	327	my $initializer = $self->{_initialize_object} \|\|= do {
	328	Mouse::Util::load_class($self->constructor_class)
	329	->_generate_initialize_object($self);
	330	};
	331	goto &{$initializer};
4e7e3250	332	}
4e7e3250	333
80efe911	334	sub is_immutable { $_[0]->{is_immutable} }
4e7e3250	335
823419c5	336	sub strict_constructor;
823419c5	337	*strict_constructor = $generate_class_accessor->('strict_constructor');
fb4ddd88	338
	339	sub _report_unknown_args {
	340	my($metaclass, $attrs, $args) = @_;
	341
	342	my @unknowns;
	343	my %init_args;
	344	foreach my $attr(@{$attrs}){
	345	my $init_arg = $attr->init_arg;
	346	if(defined $init_arg){
	347	$init_args{$init_arg}++;
	348	}
	349	}
	350
	351	while(my $key = each %{$args}){
	352	if(!exists $init_args{$key}){
	353	push @unknowns, $key;
	354	}
	355	}
	356
	357	$metaclass->throw_error( sprintf
	358	"Unknown attribute passed to the constructor of %s: %s",
	359	$metaclass->name, Mouse::Util::english_list(@unknowns),
	360	);
	361	}
e128626c	362
6fffa617	363	package Mouse::Meta::Role;
43165725	364
e058b279	365	sub method_metaclass{ $_[0]->{method_metaclass} \|\| 'Mouse::Meta::Role::Method' }
e058b279	366
43165725	367	sub is_anon_role{
	368	return exists $_[0]->{anon_serial_id};
	369	}
	370
	371	sub get_roles { $_[0]->{roles} }
	372
cb60d0b5	373	sub add_before_method_modifier {
	374	my ($self, $method_name, $method) = @_;
	375
	376	push @{ $self->{before_method_modifiers}{$method_name} \|\|= [] }, $method;
	377	return;
	378	}
	379	sub add_around_method_modifier {
	380	my ($self, $method_name, $method) = @_;
	381
	382	push @{ $self->{around_method_modifiers}{$method_name} \|\|= [] }, $method;
	383	return;
	384	}
	385	sub add_after_method_modifier {
	386	my ($self, $method_name, $method) = @_;
	387
	388	push @{ $self->{after_method_modifiers}{$method_name} \|\|= [] }, $method;
	389	return;
	390	}
	391
	392	sub get_before_method_modifiers {
	393	my ($self, $method_name) = @_;
	394	return @{ $self->{before_method_modifiers}{$method_name} \|\|= [] }
	395	}
	396	sub get_around_method_modifiers {
	397	my ($self, $method_name) = @_;
	398	return @{ $self->{around_method_modifiers}{$method_name} \|\|= [] }
	399	}
	400	sub get_after_method_modifiers {
	401	my ($self, $method_name) = @_;
	402	return @{ $self->{after_method_modifiers}{$method_name} \|\|= [] }
	403	}
	404
b4dc9315	405	sub add_metaclass_accessor { # for meta roles (a.k.a. traits)
	406	my($meta, $name) = @_;
	407	$meta->add_method($name => $generate_class_accessor->($name));
	408	return;
	409	}
	410
6fffa617	411	package Mouse::Meta::Attribute;
43165725	412
e058b279	413	require Mouse::Meta::Method::Accessor;
	414
	415	sub accessor_metaclass{ $_[0]->{accessor_metaclass} \|\| 'Mouse::Meta::Method::Accessor' }
43165725	416
	417	# readers
	418
	419	sub name { $_[0]->{name} }
	420	sub associated_class { $_[0]->{associated_class} }
	421
	422	sub accessor { $_[0]->{accessor} }
	423	sub reader { $_[0]->{reader} }
	424	sub writer { $_[0]->{writer} }
	425	sub predicate { $_[0]->{predicate} }
	426	sub clearer { $_[0]->{clearer} }
	427	sub handles { $_[0]->{handles} }
	428
	429	sub _is_metadata { $_[0]->{is} }
	430	sub is_required { $_[0]->{required} }
	431	sub default { $_[0]->{default} }
	432	sub is_lazy { $_[0]->{lazy} }
	433	sub is_lazy_build { $_[0]->{lazy_build} }
	434	sub is_weak_ref { $_[0]->{weak_ref} }
	435	sub init_arg { $_[0]->{init_arg} }
	436	sub type_constraint { $_[0]->{type_constraint} }
	437
	438	sub trigger { $_[0]->{trigger} }
	439	sub builder { $_[0]->{builder} }
	440	sub should_auto_deref { $_[0]->{auto_deref} }
	441	sub should_coerce { $_[0]->{coerce} }
	442
d899d3e7	443	sub documentation { $_[0]->{documentation} }
beb51b30	444	sub insertion_order { $_[0]->{insertion_order} }
d899d3e7	445
43165725	446	# predicates
	447
	448	sub has_accessor { exists $_[0]->{accessor} }
	449	sub has_reader { exists $_[0]->{reader} }
	450	sub has_writer { exists $_[0]->{writer} }
	451	sub has_predicate { exists $_[0]->{predicate} }
	452	sub has_clearer { exists $_[0]->{clearer} }
	453	sub has_handles { exists $_[0]->{handles} }
	454
	455	sub has_default { exists $_[0]->{default} }
	456	sub has_type_constraint { exists $_[0]->{type_constraint} }
	457	sub has_trigger { exists $_[0]->{trigger} }
	458	sub has_builder { exists $_[0]->{builder} }
	459
d899d3e7	460	sub has_documentation { exists $_[0]->{documentation} }
d899d3e7	461
ba1f50a2	462	sub _process_options{
	463	my($class, $name, $args) = @_;
	464
	465	# taken from Class::MOP::Attribute::new
	466
	467	defined($name)
	468	or $class->throw_error('You must provide a name for the attribute');
	469
	470	if(!exists $args->{init_arg}){
	471	$args->{init_arg} = $name;
	472	}
	473
	474	# 'required' requires eigher 'init_arg', 'builder', or 'default'
	475	my $can_be_required = defined( $args->{init_arg} );
	476
	477	if(exists $args->{builder}){
	478	# XXX:
	479	# Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
	480	# This feature will be changed in a future. (gfx)
	481	$class->throw_error('builder must be a defined scalar value which is a method name')
	482	#if ref $args->{builder} \|\| !defined $args->{builder};
	483	if !defined $args->{builder};
	484
	485	$can_be_required++;
	486	}
	487	elsif(exists $args->{default}){
	488	if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
	489	$class->throw_error("References are not allowed as default values, you must "
	490	. "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
	491	}
	492	$can_be_required++;
	493	}
	494
	495	if( $args->{required} && !$can_be_required ) {
	496	$class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
	497	}
	498
	499	# taken from Mouse::Meta::Attribute->new and ->_process_args
	500
	501	if(exists $args->{is}){
	502	my $is = $args->{is};
	503
	504	if($is eq 'ro'){
	505	$args->{reader} \|\|= $name;
	506	}
	507	elsif($is eq 'rw'){
	508	if(exists $args->{writer}){
	509	$args->{reader} \|\|= $name;
	510	}
	511	else{
	512	$args->{accessor} \|\|= $name;
	513	}
	514	}
	515	elsif($is eq 'bare'){
	516	# do nothing, but don't complain (later) about missing methods
	517	}
	518	else{
	519	$is = 'undef' if !defined $is;
	520	$class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
	521	}
	522	}
	523
	524	my $tc;
	525	if(exists $args->{isa}){
d503a4f3	526	$tc = $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
ba1f50a2	527	}
d503a4f3	528
	529	if(exists $args->{does}){
	530	if(defined $tc){ # both isa and does supplied
	531	my $does_ok = do{
	532	local $@;
	533	eval{ "$tc"->does($args) };
	534	};
	535	if(!$does_ok){
	536	$class->throw_error("Cannot have both an isa option and a does option because '$tc' does not do '$args->{does}' on attribute ($name)");
	537	}
	538	}
	539	else {
	540	$tc = $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
	541	}
ba1f50a2	542	}
ba1f50a2	543
	544	if($args->{coerce}){
	545	defined($tc)
	546	\|\| $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
	547
	548	$args->{weak_ref}
	549	&& $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
	550	}
	551
	552	if ($args->{lazy_build}) {
	553	exists($args->{default})
	554	&& $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
	555
	556	$args->{lazy} = 1;
	557	$args->{builder} \|\|= "_build_${name}";
	558	if ($name =~ /^_/) {
	559	$args->{clearer} \|\|= "_clear${name}";
	560	$args->{predicate} \|\|= "_has${name}";
	561	}
	562	else {
	563	$args->{clearer} \|\|= "clear_${name}";
	564	$args->{predicate} \|\|= "has_${name}";
	565	}
	566	}
	567
	568	if ($args->{auto_deref}) {
	569	defined($tc)
	570	\|\| $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
	571
	572	( $tc->is_a_type_of('ArrayRef') \|\| $tc->is_a_type_of('HashRef') )
	573	\|\| $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
	574	}
	575
	576	if (exists $args->{trigger}) {
	577	('CODE' eq ref $args->{trigger})
	578	\|\| $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
	579	}
	580
	581	if ($args->{lazy}) {
	582	(exists $args->{default} \|\| defined $args->{builder})
	583	\|\| $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
	584	}
	585
	586	return;
	587	}
	588
	589
6fffa617	590	package Mouse::Meta::TypeConstraint;
43165725	591
6e647cac	592	use overload
6e647cac	593	'""' => '_as_string',
b4dc9315	594	'0+' => '_identity',
6e647cac	595	'\|' => '_unite',
	596
	597	fallback => 1;
	598
43165725	599	sub name { $_[0]->{name} }
	600	sub parent { $_[0]->{parent} }
	601	sub message { $_[0]->{message} }
	602
f6c81f00	603	sub _identity { Scalar::Util::refaddr($_[0]) } # overload 0+
f6c81f00	604
72dc2c9d	605	sub type_parameter { $_[0]->{type_parameter} }
43165725	606	sub _compiled_type_constraint{ $_[0]->{compiled_type_constraint} }
93540011	607	sub _compiled_type_coercion { $_[0]->{_compiled_type_coercion} }
df6dd016	608
72dc2c9d	609	sub __is_parameterized { exists $_[0]->{type_parameter} }
72dc2c9d	610	sub has_coercion { exists $_[0]->{_compiled_type_coercion} }
df6dd016	611
f790c46b	612
	613	sub compile_type_constraint{
	614	my($self) = @_;
	615
	616	# add parents first
	617	my @checks;
	618	for(my $parent = $self->{parent}; defined $parent; $parent = $parent->{parent}){
	619	if($parent->{hand_optimized_type_constraint}){
	620	unshift @checks, $parent->{hand_optimized_type_constraint};
	621	last; # a hand optimized constraint must include all the parents
	622	}
	623	elsif($parent->{constraint}){
	624	unshift @checks, $parent->{constraint};
	625	}
	626	}
	627
	628	# then add child
	629	if($self->{constraint}){
	630	push @checks, $self->{constraint};
	631	}
	632
	633	if($self->{type_constraints}){ # Union
	634	my @types = map{ $_->{compiled_type_constraint} } @{ $self->{type_constraints} };
	635	push @checks, sub{
	636	foreach my $c(@types){
	637	return 1 if $c->($_[0]);
	638	}
	639	return 0;
	640	};
	641	}
	642
	643	if(@checks == 0){
	644	$self->{compiled_type_constraint} = \&Mouse::Util::TypeConstraints::Any;
	645	}
	646	else{
	647	$self->{compiled_type_constraint} = sub{
	648	my(@args) = @_;
	649	local $_ = $args[0];
	650	foreach my $c(@checks){
	651	return undef if !$c->(@args);
	652	}
	653	return 1;
	654	};
	655	}
	656	return;
	657	}
	658
c7576321	659	sub check {
	660	my $self = shift;
	661	return $self->_compiled_type_constraint->(@_);
	662	}
	663
	664
6fffa617	665	package Mouse::Object;
aa2d2e2c	666
aa2d2e2c	667	sub BUILDARGS {
aa2d2e2c	668	my $class = shift;
f790c46b	669
aa2d2e2c	670	if (scalar @_ == 1) {
	671	(ref($_[0]) eq 'HASH')
	672	\|\| $class->meta->throw_error("Single parameters to new() must be a HASH ref");
	673
	674	return {%{$_[0]}};
	675	}
	676	else {
	677	return {@_};
	678	}
	679	}
f790c46b	680
af04626d	681	sub new {
af04626d	682	my $class = shift;
c83feefa	683	my $args = $class->BUILDARGS(@_);
c83feefa	684	return $class->meta->new_object($args);
af04626d	685	}
af04626d	686
a5c683f6	687	sub DESTROY {
	688	my $self = shift;
	689
	690	return unless $self->can('DEMOLISH'); # short circuit
	691
a5c683f6	692	my $e = do{
a3a09e38	693	local $?;
a5c683f6	694	local $@;
a5c683f6	695	eval{
a5c683f6	696	# DEMOLISHALL
	697
	698	# We cannot count on being able to retrieve a previously made
	699	# metaclass, _or_ being able to make a new one during global
	700	# destruction. However, we should still be able to use mro at
	701	# that time (at least tests suggest so ;)
	702
	703	foreach my $class (@{ Mouse::Util::get_linear_isa(ref $self) }) {
	704	my $demolish = Mouse::Util::get_code_ref($class, 'DEMOLISH')
	705	\|\| next;
	706
6514735e	707	$self->$demolish($Mouse::Util::in_global_destruction);
a5c683f6	708	}
	709	};
	710	$@;
	711	};
	712
	713	no warnings 'misc';
	714	die $e if $e; # rethrow
	715	}
	716
adb5eb76	717	sub BUILDALL {
	718	my $self = shift;
	719
	720	# short circuit
	721	return unless $self->can('BUILD');
	722
	723	for my $class (reverse $self->meta->linearized_isa) {
	724	my $build = Mouse::Util::get_code_ref($class, 'BUILD')
	725	\|\| next;
	726
	727	$self->$build(@_);
	728	}
	729	return;
	730	}
	731
	732	sub DEMOLISHALL;
	733	*DEMOLISHALL = \&DESTROY;
	734
df6dd016	735	1;
df6dd016	736	__END__
ccb38d0b	737
	738	=head1 NAME
	739
	740	Mouse::PurePerl - A Mouse guts in pure Perl
	741
	742	=head1 VERSION
	743
b0d52f03	744	This document describes Mouse version 0.73
ccb38d0b	745
	746	=head1 SEE ALSO
	747
	748	L<Mouse::XS>
	749
	750	=cut