[gitmo/Mouse.git] / lib / Mouse / PurePerl.pm

package Mouse::PurePerl;

require Mouse::Util;

package Mouse::Util;

use strict;
use warnings;

use warnings FATAL => 'redefine'; # to avoid to load Mouse::PurePerl

use B ();


# taken from Class/MOP.pm
sub is_valid_class_name {
    my $class = shift;

    return 0 if ref($class);
    return 0 unless defined($class);

    return 1 if $class =~ /\A \w+ (?: :: \w+ )* \z/xms;

    return 0;
}

sub is_class_loaded {
    my $class = shift;

    return 0 if ref($class) || !defined($class) || !length($class);

    # walk the symbol table tree to avoid autovififying
    # \*{${main::}{"Foo::"}{"Bar::"}} == \*main::Foo::Bar::

    my $pack = \%::;
    foreach my $part (split('::', $class)) {
        $part .= '::';
        return 0 if !exists $pack->{$part};

        my $entry = \$pack->{$part};
        return 0 if ref($entry) ne 'GLOB';
        $pack = *{$entry}{HASH};
    }

    return 0 if !%{$pack};

    # check for $VERSION or @ISA
    return 1 if exists $pack->{VERSION}
             && defined *{$pack->{VERSION}}{SCALAR} && defined ${ $pack->{VERSION} };
    return 1 if exists $pack->{ISA}
             && defined *{$pack->{ISA}}{ARRAY} && @{ $pack->{ISA} } != 0;

    # check for any method
    foreach my $name( keys %{$pack} ) {
        my $entry = \$pack->{$name};
        return 1 if ref($entry) ne 'GLOB' || defined *{$entry}{CODE};
    }

    # fail
    return 0;
}


# taken from Sub::Identify
sub get_code_info {
    my ($coderef) = @_;
    ref($coderef) or return;

    my $cv = B::svref_2object($coderef);
    $cv->isa('B::CV') or return;

    my $gv = $cv->GV;
    $gv->isa('B::GV') or return;

    return ($gv->STASH->NAME, $gv->NAME);
}

sub get_code_package{
    my($coderef) = @_;

    my $cv = B::svref_2object($coderef);
    $cv->isa('B::CV') or return '';

    my $gv = $cv->GV;
    $gv->isa('B::GV') or return '';

    return $gv->STASH->NAME;
}

sub get_code_ref{
    my($package, $name) = @_;
    no strict 'refs';
    no warnings 'once';
    use warnings FATAL => 'uninitialized';
    return *{$package . '::' . $name}{CODE};
}

sub generate_isa_predicate_for {
    my($for_class, $name) = @_;

    my $predicate = sub{ Scalar::Util::blessed($_[0]) && $_[0]->isa($for_class) };

    if(defined $name){
        Mouse::Util::install_subroutines(scalar caller, $name => $predicate);
        return;
    }

    return $predicate;
}

sub generate_can_predicate_for {
    my($methods_ref, $name) = @_;

    my @methods = @{$methods_ref};

    my $predicate = sub{
        my($instance) = @_;
        if(Scalar::Util::blessed($instance)){
            foreach my $method(@methods){
                if(!$instance->can($method)){
                    return 0;
                }
            }
            return 1;
        }
        return 0;
    };

    if(defined $name){
        Mouse::Util::install_subroutines(scalar caller, $name => $predicate);
        return;
    }

    return $predicate;
}

package Mouse::Util::TypeConstraints;

use Scalar::Util qw(blessed looks_like_number openhandle);

sub Any        { 1 }
sub Item       { 1 }

sub Bool       { $_[0] ? $_[0] eq '1' : 1 }
sub Undef      { !defined($_[0]) }
sub Defined    {  defined($_[0])  }
sub Value      {  defined($_[0]) && !ref($_[0]) }
sub Num        {  looks_like_number($_[0]) }
sub Int        {
    my($value) = @_;
    looks_like_number($value) && $value =~ /\A [+-]? [0-9]+  \z/xms;
}
sub Str        {
    my($value) = @_;
    return defined($value) && ref(\$value) eq 'SCALAR';
}

sub Ref        { ref($_[0]) }
sub ScalarRef  {
    my($value) = @_;
    return ref($value) eq 'SCALAR'
}
sub ArrayRef   { ref($_[0]) eq 'ARRAY'  }
sub HashRef    { ref($_[0]) eq 'HASH'   }
sub CodeRef    { ref($_[0]) eq 'CODE'   }
sub RegexpRef  { ref($_[0]) eq 'Regexp' }
sub GlobRef    { ref($_[0]) eq 'GLOB'   }

sub FileHandle {
    return openhandle($_[0])  || (blessed($_[0]) && $_[0]->isa("IO::Handle"))
}

sub Object     { blessed($_[0]) && blessed($_[0]) ne 'Regexp' }

sub ClassName  { Mouse::Util::is_class_loaded($_[0]) }
sub RoleName   { (Mouse::Util::class_of($_[0]) || return 0)->isa('Mouse::Meta::Role') }

sub _parameterize_ArrayRef_for {
    my($type_parameter) = @_;
    my $check = $type_parameter->_compiled_type_constraint;

    return sub {
        foreach my $value (@{$_}) {
            return undef unless $check->($value);
        }
        return 1;
    }
}

sub _parameterize_HashRef_for {
    my($type_parameter) = @_;
    my $check = $type_parameter->_compiled_type_constraint;

    return sub {
        foreach my $value(values %{$_}){
            return undef unless $check->($value);
        }
        return 1;
    };
}

# 'Maybe' type accepts 'Any', so it requires parameters
sub _parameterize_Maybe_for {
    my($type_parameter) = @_;
    my $check = $type_parameter->_compiled_type_constraint;

    return sub{
        return !defined($_) || $check->($_);
    };
}

package Mouse::Meta::Module;

sub name          { $_[0]->{package} }

sub _method_map   { $_[0]->{methods} }
sub _attribute_map{ $_[0]->{attributes} }

sub namespace{
    my $name = $_[0]->{package};
    no strict 'refs';
    return \%{ $name . '::' };
}

sub add_method {
    my($self, $name, $code) = @_;

    if(!defined $name){
        $self->throw_error('You must pass a defined name');
    }
    if(!defined $code){
        $self->throw_error('You must pass a defined code');
    }

    if(ref($code) ne 'CODE'){
        $code = \&{$code}; # coerce
    }

    $self->{methods}->{$name} = $code; # Moose stores meta object here.

    Mouse::Util::install_subroutines($self->name,
        $name => $code,
    );
    return;
}

package Mouse::Meta::Class;

use Mouse::Meta::Method::Constructor;
use Mouse::Meta::Method::Destructor;

sub method_metaclass    { $_[0]->{method_metaclass}    || 'Mouse::Meta::Method'    }
sub attribute_metaclass { $_[0]->{attribute_metaclass} || 'Mouse::Meta::Attribute' }

sub constructor_class { $_[0]->{constructor_class} || 'Mouse::Meta::Method::Constructor' }
sub destructor_class  { $_[0]->{destructor_class}  || 'Mouse::Meta::Method::Destructor'  }

sub is_anon_class{
    return exists $_[0]->{anon_serial_id};
}

sub roles { $_[0]->{roles} }

sub linearized_isa { @{ get_linear_isa($_[0]->{package}) } }

sub get_all_attributes {
    my($self) = @_;
    my %attrs = map { %{ $self->initialize($_)->{attributes} } } reverse $self->linearized_isa;
    return values %attrs;
}

sub new_object {
    my $meta = shift;
    my %args = (@_ == 1 ? %{$_[0]} : @_);

    my $object = bless {}, $meta->name;

    $meta->_initialize_object($object, \%args);
    # BUILDALL
    if( $object->can('BUILD') ) {
        for my $class (reverse $meta->linearized_isa) {
            my $build = Mouse::Util::get_code_ref($class, 'BUILD')
                || next;

            $object->$build(\%args);
        }
    }
    return $object;
}

sub clone_object {
    my $class  = shift;
    my $object = shift;
    my $args   = $object->Mouse::Object::BUILDARGS(@_);

    (blessed($object) && $object->isa($class->name))
        || $class->throw_error("You must pass an instance of the metaclass (" . $class->name . "), not ($object)");

    my $cloned = bless { %$object }, ref $object;
    $class->_initialize_object($cloned, $args, 1);

    return $cloned;
}

sub _initialize_object{
    my($self, $object, $args, $is_cloning) = @_;

    my @triggers_queue;

    foreach my $attribute ($self->get_all_attributes) {
        my $init_arg = $attribute->init_arg;
        my $slot     = $attribute->name;

        if (defined($init_arg) && exists($args->{$init_arg})) {
            $object->{$slot} = $attribute->_coerce_and_verify($args->{$init_arg}, $object);

            weaken($object->{$slot})
                if ref($object->{$slot}) && $attribute->is_weak_ref;

            if ($attribute->has_trigger) {
                push @triggers_queue, [ $attribute->trigger, $object->{$slot} ];
            }
        }
        else { # no init arg
            if ($attribute->has_default || $attribute->has_builder) {
                if (!$attribute->is_lazy && !exists $object->{$slot}) {
                    my $default = $attribute->default;
                    my $builder = $attribute->builder;
                    my $value =   $builder                ? $object->$builder()
                                : ref($default) eq 'CODE' ? $object->$default()
                                :                           $default;

                    $object->{$slot} = $attribute->_coerce_and_verify($value, $object);

                    weaken($object->{$slot})
                        if ref($object->{$slot}) && $attribute->is_weak_ref;
                }
            }
            elsif(!$is_cloning && $attribute->is_required) {
                $self->throw_error("Attribute (".$attribute->name.") is required");
            }
        }
    }

    if(@triggers_queue){
        foreach my $trigger_and_value(@triggers_queue){
            my($trigger, $value) = @{$trigger_and_value};
            $trigger->($object, $value);
        }
    }

    if($self->is_anon_class){
        $object->{__METACLASS__} = $self;
    }

    return;
}

sub is_immutable {  $_[0]->{is_immutable} }

sub __strict_constructor{ $_[0]->{strict_constructor} }

package Mouse::Meta::Role;

sub method_metaclass{ $_[0]->{method_metaclass} || 'Mouse::Meta::Role::Method' }

sub is_anon_role{
    return exists $_[0]->{anon_serial_id};
}

sub get_roles { $_[0]->{roles} }

sub add_before_method_modifier {
    my ($self, $method_name, $method) = @_;

    push @{ $self->{before_method_modifiers}{$method_name} ||= [] }, $method;
    return;
}
sub add_around_method_modifier {
    my ($self, $method_name, $method) = @_;

    push @{ $self->{around_method_modifiers}{$method_name} ||= [] }, $method;
    return;
}
sub add_after_method_modifier {
    my ($self, $method_name, $method) = @_;

    push @{ $self->{after_method_modifiers}{$method_name} ||= [] }, $method;
    return;
}

sub get_before_method_modifiers {
    my ($self, $method_name) = @_;
    return @{ $self->{before_method_modifiers}{$method_name} ||= [] }
}
sub get_around_method_modifiers {
    my ($self, $method_name) = @_;
    return @{ $self->{around_method_modifiers}{$method_name} ||= [] }
}
sub get_after_method_modifiers {
    my ($self, $method_name) = @_;
    return @{ $self->{after_method_modifiers}{$method_name} ||= [] }
}

package Mouse::Meta::Attribute;

require Mouse::Meta::Method::Accessor;

sub accessor_metaclass{ $_[0]->{accessor_metaclass} || 'Mouse::Meta::Method::Accessor' }

# readers

sub name                 { $_[0]->{name}                   }
sub associated_class     { $_[0]->{associated_class}       }

sub accessor             { $_[0]->{accessor}               }
sub reader               { $_[0]->{reader}                 }
sub writer               { $_[0]->{writer}                 }
sub predicate            { $_[0]->{predicate}              }
sub clearer              { $_[0]->{clearer}                }
sub handles              { $_[0]->{handles}                }

sub _is_metadata         { $_[0]->{is}                     }
sub is_required          { $_[0]->{required}               }
sub default              { $_[0]->{default}                }
sub is_lazy              { $_[0]->{lazy}                   }
sub is_lazy_build        { $_[0]->{lazy_build}             }
sub is_weak_ref          { $_[0]->{weak_ref}               }
sub init_arg             { $_[0]->{init_arg}               }
sub type_constraint      { $_[0]->{type_constraint}        }

sub trigger              { $_[0]->{trigger}                }
sub builder              { $_[0]->{builder}                }
sub should_auto_deref    { $_[0]->{auto_deref}             }
sub should_coerce        { $_[0]->{coerce}                 }

sub documentation        { $_[0]->{documentation}          }

# predicates

sub has_accessor         { exists $_[0]->{accessor}        }
sub has_reader           { exists $_[0]->{reader}          }
sub has_writer           { exists $_[0]->{writer}          }
sub has_predicate        { exists $_[0]->{predicate}       }
sub has_clearer          { exists $_[0]->{clearer}         }
sub has_handles          { exists $_[0]->{handles}         }

sub has_default          { exists $_[0]->{default}         }
sub has_type_constraint  { exists $_[0]->{type_constraint} }
sub has_trigger          { exists $_[0]->{trigger}         }
sub has_builder          { exists $_[0]->{builder}         }

sub has_documentation    { exists $_[0]->{documentation}   }

sub _process_options{
    my($class, $name, $args) = @_;

    # taken from Class::MOP::Attribute::new

    defined($name)
        or $class->throw_error('You must provide a name for the attribute');

    if(!exists $args->{init_arg}){
        $args->{init_arg} = $name;
    }

    # 'required' requires eigher 'init_arg', 'builder', or 'default'
    my $can_be_required = defined( $args->{init_arg} );

    if(exists $args->{builder}){
        # XXX:
        # Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
        # This feature will be changed in a future. (gfx)
        $class->throw_error('builder must be a defined scalar value which is a method name')
            #if ref $args->{builder} || !defined $args->{builder};
            if !defined $args->{builder};

        $can_be_required++;
    }
    elsif(exists $args->{default}){
        if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
            $class->throw_error("References are not allowed as default values, you must "
                              . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
        }
        $can_be_required++;
    }

    if( $args->{required} && !$can_be_required ) {
        $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
    }

    # taken from Mouse::Meta::Attribute->new and ->_process_args

    if(exists $args->{is}){
        my $is = $args->{is};

        if($is eq 'ro'){
            $args->{reader} ||= $name;
        }
        elsif($is eq 'rw'){
            if(exists $args->{writer}){
                $args->{reader} ||= $name;
             }
             else{
                $args->{accessor} ||= $name;
             }
        }
        elsif($is eq 'bare'){
            # do nothing, but don't complain (later) about missing methods
        }
        else{
            $is = 'undef' if !defined $is;
            $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
        }
    }

    my $tc;
    if(exists $args->{isa}){
        $tc = $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
    }

    if(exists $args->{does}){
        if(defined $tc){ # both isa and does supplied
            my $does_ok = do{
                local $@;
                eval{ "$tc"->does($args) };
            };
            if(!$does_ok){
                $class->throw_error("Cannot have both an isa option and a does option because '$tc' does not do '$args->{does}' on attribute ($name)");
            }
        }
        else {
            $tc = $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
        }
    }

    if($args->{coerce}){
        defined($tc)
            || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");

        $args->{weak_ref}
            && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
    }

    if ($args->{lazy_build}) {
        exists($args->{default})
            && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");

        $args->{lazy}      = 1;
        $args->{builder} ||= "_build_${name}";
        if ($name =~ /^_/) {
            $args->{clearer}   ||= "_clear${name}";
            $args->{predicate} ||= "_has${name}";
        }
        else {
            $args->{clearer}   ||= "clear_${name}";
            $args->{predicate} ||= "has_${name}";
        }
    }

    if ($args->{auto_deref}) {
        defined($tc)
            || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");

        ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
            || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
    }

    if (exists $args->{trigger}) {
        ('CODE' eq ref $args->{trigger})
            || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
    }

    if ($args->{lazy}) {
        (exists $args->{default} || defined $args->{builder})
            || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
    }

    return;
}


package Mouse::Meta::TypeConstraint;

sub name    { $_[0]->{name}    }
sub parent  { $_[0]->{parent}  }
sub message { $_[0]->{message} }

sub type_parameter           { $_[0]->{type_parameter} }
sub _compiled_type_constraint{ $_[0]->{compiled_type_constraint} }
sub _compiled_type_coercion  { $_[0]->{_compiled_type_coercion}  }

sub __is_parameterized { exists $_[0]->{type_parameter} }
sub has_coercion {       exists $_[0]->{_compiled_type_coercion} }


sub compile_type_constraint{
    my($self) = @_;

    # add parents first
    my @checks;
    for(my $parent = $self->{parent}; defined $parent; $parent = $parent->{parent}){
         if($parent->{hand_optimized_type_constraint}){
            unshift @checks, $parent->{hand_optimized_type_constraint};
            last; # a hand optimized constraint must include all the parents
        }
        elsif($parent->{constraint}){
            unshift @checks, $parent->{constraint};
        }
    }

    # then add child
    if($self->{constraint}){
        push @checks, $self->{constraint};
    }

    if($self->{type_constraints}){ # Union
        my @types = map{ $_->{compiled_type_constraint} } @{ $self->{type_constraints} };
        push @checks, sub{
            foreach my $c(@types){
                return 1 if $c->($_[0]);
            }
            return 0;
        };
    }

    if(@checks == 0){
        $self->{compiled_type_constraint} = \&Mouse::Util::TypeConstraints::Any;
    }
    else{
        $self->{compiled_type_constraint} =  sub{
            my(@args) = @_;
            local $_ = $args[0];
            foreach my $c(@checks){
                return undef if !$c->(@args);
            }
            return 1;
        };
    }
    return;
}

sub check {
    my $self = shift;
    return $self->_compiled_type_constraint->(@_);
}


package Mouse::Object;

sub BUILDARGS {
    my $class = shift;

    if (scalar @_ == 1) {
        (ref($_[0]) eq 'HASH')
            || $class->meta->throw_error("Single parameters to new() must be a HASH ref");

        return {%{$_[0]}};
    }
    else {
        return {@_};
    }
}

sub new {
    my $class = shift;

    $class->meta->throw_error('Cannot call new() on an instance') if ref $class;

    my $args = $class->BUILDARGS(@_);

    my $meta = Mouse::Meta::Class->initialize($class);
    return $meta->new_object($args);
}

sub DESTROY {
    my $self = shift;

    return unless $self->can('DEMOLISH'); # short circuit

    local $?;

    my $e = do{
        local $@;
        eval{
            # DEMOLISHALL

            # We cannot count on being able to retrieve a previously made
            # metaclass, _or_ being able to make a new one during global
            # destruction. However, we should still be able to use mro at
            # that time (at least tests suggest so ;)

            foreach my $class (@{ Mouse::Util::get_linear_isa(ref $self) }) {
                my $demolish = Mouse::Util::get_code_ref($class, 'DEMOLISH')
                    || next;

                $self->$demolish($Mouse::Util::in_global_destruction);
            }
        };
        $@;
    };

    no warnings 'misc';
    die $e if $e; # rethrow
}

sub BUILDALL {
    my $self = shift;

    # short circuit
    return unless $self->can('BUILD');

    for my $class (reverse $self->meta->linearized_isa) {
        my $build = Mouse::Util::get_code_ref($class, 'BUILD')
            || next;

        $self->$build(@_);
    }
    return;
}

sub DEMOLISHALL;
*DEMOLISHALL = \&DESTROY;

1;
__END__

=head1 NAME

Mouse::PurePerl - A Mouse guts in pure Perl

=head1 VERSION

This document describes Mouse version 0.61

=head1 SEE ALSO

L<Mouse::XS>

=cut
Commit	Line	Data
ccb38d0b	1	package Mouse::PurePerl;
ccb38d0b	2
a52cca04	3	require Mouse::Util;
a52cca04	4
6fffa617	5	package Mouse::Util;
df6dd016	6
	7	use strict;
	8	use warnings;
	9
	10	use warnings FATAL => 'redefine'; # to avoid to load Mouse::PurePerl
	11
	12	use B ();
	13
0ffc4183	14
	15	# taken from Class/MOP.pm
	16	sub is_valid_class_name {
	17	my $class = shift;
	18
	19	return 0 if ref($class);
	20	return 0 unless defined($class);
	21
	22	return 1 if $class =~ /\A \w+ (?: :: \w+ )* \z/xms;
	23
	24	return 0;
	25	}
	26
df6dd016	27	sub is_class_loaded {
	28	my $class = shift;
	29
	30	return 0 if ref($class) \|\| !defined($class) \|\| !length($class);
	31
	32	# walk the symbol table tree to avoid autovififying
3bb9e54e	33	# \{${main::}{"Foo::"}{"Bar::"}} == \main::Foo::Bar::
df6dd016	34
	35	my $pack = \%::;
	36	foreach my $part (split('::', $class)) {
3bb9e54e	37	$part .= '::';
	38	return 0 if !exists $pack->{$part};
	39
	40	my $entry = \$pack->{$part};
df6dd016	41	return 0 if ref($entry) ne 'GLOB';
3bb9e54e	42	$pack = *{$entry}{HASH};
df6dd016	43	}
df6dd016	44
3bb9e54e	45	return 0 if !%{$pack};
3bb9e54e	46
df6dd016	47	# check for $VERSION or @ISA
	48	return 1 if exists $pack->{VERSION}
	49	&& defined *{$pack->{VERSION}}{SCALAR} && defined ${ $pack->{VERSION} };
	50	return 1 if exists $pack->{ISA}
	51	&& defined *{$pack->{ISA}}{ARRAY} && @{ $pack->{ISA} } != 0;
	52
	53	# check for any method
	54	foreach my $name( keys %{$pack} ) {
	55	my $entry = \$pack->{$name};
	56	return 1 if ref($entry) ne 'GLOB' \|\| defined *{$entry}{CODE};
	57	}
	58
	59	# fail
	60	return 0;
	61	}
	62
	63
	64	# taken from Sub::Identify
	65	sub get_code_info {
	66	my ($coderef) = @_;
	67	ref($coderef) or return;
	68
	69	my $cv = B::svref_2object($coderef);
	70	$cv->isa('B::CV') or return;
	71
	72	my $gv = $cv->GV;
	73	$gv->isa('B::GV') or return;
	74
	75	return ($gv->STASH->NAME, $gv->NAME);
	76	}
	77
	78	sub get_code_package{
	79	my($coderef) = @_;
	80
	81	my $cv = B::svref_2object($coderef);
	82	$cv->isa('B::CV') or return '';
	83
	84	my $gv = $cv->GV;
	85	$gv->isa('B::GV') or return '';
	86
	87	return $gv->STASH->NAME;
	88	}
	89
7d96ae4d	90	sub get_code_ref{
	91	my($package, $name) = @_;
	92	no strict 'refs';
	93	no warnings 'once';
	94	use warnings FATAL => 'uninitialized';
	95	return *{$package . '::' . $name}{CODE};
	96	}
	97
e3540312	98	sub generate_isa_predicate_for {
1d5ecd5f	99	my($for_class, $name) = @_;
1d5ecd5f	100
f48920c1	101	my $predicate = sub{ Scalar::Util::blessed($_[0]) && $_[0]->isa($for_class) };
1d5ecd5f	102
1d5ecd5f	103	if(defined $name){
1194aede	104	Mouse::Util::install_subroutines(scalar caller, $name => $predicate);
1d5ecd5f	105	return;
	106	}
	107
	108	return $predicate;
	109	}
	110
ebe91068	111	sub generate_can_predicate_for {
	112	my($methods_ref, $name) = @_;
	113
	114	my @methods = @{$methods_ref};
	115
	116	my $predicate = sub{
	117	my($instance) = @_;
	118	if(Scalar::Util::blessed($instance)){
	119	foreach my $method(@methods){
	120	if(!$instance->can($method)){
	121	return 0;
	122	}
	123	}
	124	return 1;
	125	}
	126	return 0;
	127	};
	128
	129	if(defined $name){
1194aede	130	Mouse::Util::install_subroutines(scalar caller, $name => $predicate);
ebe91068	131	return;
	132	}
	133
	134	return $predicate;
	135	}
1d5ecd5f	136
6fffa617	137	package Mouse::Util::TypeConstraints;
f48920c1	138
	139	use Scalar::Util qw(blessed looks_like_number openhandle);
	140
7d96ae4d	141	sub Any { 1 }
7d96ae4d	142	sub Item { 1 }
7d96ae4d	143
	144	sub Bool { $_[0] ? $_[0] eq '1' : 1 }
	145	sub Undef { !defined($_[0]) }
	146	sub Defined { defined($_[0]) }
	147	sub Value { defined($_[0]) && !ref($_[0]) }
1adf864e	148	sub Num { looks_like_number($_[0]) }
	149	sub Int {
	150	my($value) = @_;
0cfe08a4	151	looks_like_number($value) && $value =~ /\A [+-]? [0-9]+ \z/xms;
1adf864e	152	}
9848d3e1	153	sub Str {
	154	my($value) = @_;
	155	return defined($value) && ref(\$value) eq 'SCALAR';
	156	}
7d96ae4d	157
7d96ae4d	158	sub Ref { ref($_[0]) }
9848d3e1	159	sub ScalarRef {
	160	my($value) = @_;
	161	return ref($value) eq 'SCALAR'
	162	}
7d96ae4d	163	sub ArrayRef { ref($_[0]) eq 'ARRAY' }
	164	sub HashRef { ref($_[0]) eq 'HASH' }
	165	sub CodeRef { ref($_[0]) eq 'CODE' }
	166	sub RegexpRef { ref($_[0]) eq 'Regexp' }
	167	sub GlobRef { ref($_[0]) eq 'GLOB' }
	168
	169	sub FileHandle {
9848d3e1	170	return openhandle($_[0]) \|\| (blessed($_[0]) && $_[0]->isa("IO::Handle"))
7d96ae4d	171	}
	172
	173	sub Object { blessed($_[0]) && blessed($_[0]) ne 'Regexp' }
	174
	175	sub ClassName { Mouse::Util::is_class_loaded($_[0]) }
	176	sub RoleName { (Mouse::Util::class_of($_[0]) \|\| return 0)->isa('Mouse::Meta::Role') }
	177
619338ac	178	sub _parameterize_ArrayRef_for {
	179	my($type_parameter) = @_;
	180	my $check = $type_parameter->_compiled_type_constraint;
	181
	182	return sub {
	183	foreach my $value (@{$_}) {
	184	return undef unless $check->($value);
	185	}
	186	return 1;
	187	}
	188	}
	189
	190	sub _parameterize_HashRef_for {
	191	my($type_parameter) = @_;
	192	my $check = $type_parameter->_compiled_type_constraint;
	193
	194	return sub {
	195	foreach my $value(values %{$_}){
	196	return undef unless $check->($value);
	197	}
	198	return 1;
	199	};
	200	}
	201
	202	# 'Maybe' type accepts 'Any', so it requires parameters
	203	sub _parameterize_Maybe_for {
	204	my($type_parameter) = @_;
	205	my $check = $type_parameter->_compiled_type_constraint;
	206
	207	return sub{
	208	return !defined($_) \|\| $check->($_);
	209	};
9b923ac8	210	}
7d96ae4d	211
6fffa617	212	package Mouse::Meta::Module;
43165725	213
926404f2	214	sub name { $_[0]->{package} }
	215
	216	sub _method_map { $_[0]->{methods} }
c5f6ad05	217	sub _attribute_map{ $_[0]->{attributes} }
43165725	218
2591e962	219	sub namespace{
	220	my $name = $_[0]->{package};
	221	no strict 'refs';
	222	return \%{ $name . '::' };
	223	}
	224
3e44140b	225	sub add_method {
	226	my($self, $name, $code) = @_;
	227
	228	if(!defined $name){
	229	$self->throw_error('You must pass a defined name');
	230	}
	231	if(!defined $code){
	232	$self->throw_error('You must pass a defined code');
	233	}
	234
	235	if(ref($code) ne 'CODE'){
	236	$code = \&{$code}; # coerce
	237	}
	238
	239	$self->{methods}->{$name} = $code; # Moose stores meta object here.
	240
1194aede	241	Mouse::Util::install_subroutines($self->name,
	242	$name => $code,
	243	);
3e44140b	244	return;
	245	}
	246
6fffa617	247	package Mouse::Meta::Class;
43165725	248
e088c5fc	249	use Mouse::Meta::Method::Constructor;
	250	use Mouse::Meta::Method::Destructor;
	251
e058b279	252	sub method_metaclass { $_[0]->{method_metaclass} \|\| 'Mouse::Meta::Method' }
	253	sub attribute_metaclass { $_[0]->{attribute_metaclass} \|\| 'Mouse::Meta::Attribute' }
	254
	255	sub constructor_class { $_[0]->{constructor_class} \|\| 'Mouse::Meta::Method::Constructor' }
	256	sub destructor_class { $_[0]->{destructor_class} \|\| 'Mouse::Meta::Method::Destructor' }
4e7e3250	257
43165725	258	sub is_anon_class{
	259	return exists $_[0]->{anon_serial_id};
	260	}
	261
	262	sub roles { $_[0]->{roles} }
	263
cccb83de	264	sub linearized_isa { @{ get_linear_isa($_[0]->{package}) } }
cccb83de	265
da4432f3	266	sub get_all_attributes {
da4432f3	267	my($self) = @_;
047d7af0	268	my %attrs = map { %{ $self->initialize($_)->{attributes} } } reverse $self->linearized_isa;
da4432f3	269	return values %attrs;
	270	}
	271
ba153b33	272	sub new_object {
b5956f03	273	my $meta = shift;
ba153b33	274	my %args = (@_ == 1 ? %{$_[0]} : @_);
ba153b33	275
b5956f03	276	my $object = bless {}, $meta->name;
ba153b33	277
b5956f03	278	$meta->_initialize_object($object, \%args);
	279	# BUILDALL
	280	if( $object->can('BUILD') ) {
	281	for my $class (reverse $meta->linearized_isa) {
	282	my $build = Mouse::Util::get_code_ref($class, 'BUILD')
	283	\|\| next;
	284
	285	$object->$build(\%args);
	286	}
	287	}
ba153b33	288	return $object;
	289	}
	290
13b99908	291	sub clone_object {
	292	my $class = shift;
	293	my $object = shift;
	294	my $args = $object->Mouse::Object::BUILDARGS(@_);
	295
	296	(blessed($object) && $object->isa($class->name))
	297	\|\| $class->throw_error("You must pass an instance of the metaclass (" . $class->name . "), not ($object)");
	298
	299	my $cloned = bless { %$object }, ref $object;
	300	$class->_initialize_object($cloned, $args, 1);
	301
	302	return $cloned;
	303	}
	304
4e7e3250	305	sub _initialize_object{
cb6a9721	306	my($self, $object, $args, $is_cloning) = @_;
4e7e3250	307
	308	my @triggers_queue;
	309
	310	foreach my $attribute ($self->get_all_attributes) {
	311	my $init_arg = $attribute->init_arg;
	312	my $slot = $attribute->name;
	313
	314	if (defined($init_arg) && exists($args->{$init_arg})) {
	315	$object->{$slot} = $attribute->_coerce_and_verify($args->{$init_arg}, $object);
	316
	317	weaken($object->{$slot})
	318	if ref($object->{$slot}) && $attribute->is_weak_ref;
	319
	320	if ($attribute->has_trigger) {
	321	push @triggers_queue, [ $attribute->trigger, $object->{$slot} ];
	322	}
	323	}
6c7491f2	324	else { # no init arg
4e7e3250	325	if ($attribute->has_default \|\| $attribute->has_builder) {
6c7491f2	326	if (!$attribute->is_lazy && !exists $object->{$slot}) {
4e7e3250	327	my $default = $attribute->default;
	328	my $builder = $attribute->builder;
	329	my $value = $builder ? $object->$builder()
	330	: ref($default) eq 'CODE' ? $object->$default()
	331	: $default;
	332
	333	$object->{$slot} = $attribute->_coerce_and_verify($value, $object);
	334
	335	weaken($object->{$slot})
	336	if ref($object->{$slot}) && $attribute->is_weak_ref;
	337	}
	338	}
6c7491f2	339	elsif(!$is_cloning && $attribute->is_required) {
4e7e3250	340	$self->throw_error("Attribute (".$attribute->name.") is required");
	341	}
	342	}
	343	}
	344
cb6a9721	345	if(@triggers_queue){
4e7e3250	346	foreach my $trigger_and_value(@triggers_queue){
	347	my($trigger, $value) = @{$trigger_and_value};
	348	$trigger->($object, $value);
	349	}
	350	}
	351
	352	if($self->is_anon_class){
	353	$object->{__METACLASS__} = $self;
	354	}
	355
	356	return;
	357	}
	358
80efe911	359	sub is_immutable { $_[0]->{is_immutable} }
4e7e3250	360
e128626c	361	sub __strict_constructor{ $_[0]->{strict_constructor} }
e128626c	362
6fffa617	363	package Mouse::Meta::Role;
43165725	364
e058b279	365	sub method_metaclass{ $_[0]->{method_metaclass} \|\| 'Mouse::Meta::Role::Method' }
e058b279	366
43165725	367	sub is_anon_role{
	368	return exists $_[0]->{anon_serial_id};
	369	}
	370
	371	sub get_roles { $_[0]->{roles} }
	372
cb60d0b5	373	sub add_before_method_modifier {
	374	my ($self, $method_name, $method) = @_;
	375
	376	push @{ $self->{before_method_modifiers}{$method_name} \|\|= [] }, $method;
	377	return;
	378	}
	379	sub add_around_method_modifier {
	380	my ($self, $method_name, $method) = @_;
	381
	382	push @{ $self->{around_method_modifiers}{$method_name} \|\|= [] }, $method;
	383	return;
	384	}
	385	sub add_after_method_modifier {
	386	my ($self, $method_name, $method) = @_;
	387
	388	push @{ $self->{after_method_modifiers}{$method_name} \|\|= [] }, $method;
	389	return;
	390	}
	391
	392	sub get_before_method_modifiers {
	393	my ($self, $method_name) = @_;
	394	return @{ $self->{before_method_modifiers}{$method_name} \|\|= [] }
	395	}
	396	sub get_around_method_modifiers {
	397	my ($self, $method_name) = @_;
	398	return @{ $self->{around_method_modifiers}{$method_name} \|\|= [] }
	399	}
	400	sub get_after_method_modifiers {
	401	my ($self, $method_name) = @_;
	402	return @{ $self->{after_method_modifiers}{$method_name} \|\|= [] }
	403	}
	404
6fffa617	405	package Mouse::Meta::Attribute;
43165725	406
e058b279	407	require Mouse::Meta::Method::Accessor;
	408
	409	sub accessor_metaclass{ $_[0]->{accessor_metaclass} \|\| 'Mouse::Meta::Method::Accessor' }
43165725	410
	411	# readers
	412
	413	sub name { $_[0]->{name} }
	414	sub associated_class { $_[0]->{associated_class} }
	415
	416	sub accessor { $_[0]->{accessor} }
	417	sub reader { $_[0]->{reader} }
	418	sub writer { $_[0]->{writer} }
	419	sub predicate { $_[0]->{predicate} }
	420	sub clearer { $_[0]->{clearer} }
	421	sub handles { $_[0]->{handles} }
	422
	423	sub _is_metadata { $_[0]->{is} }
	424	sub is_required { $_[0]->{required} }
	425	sub default { $_[0]->{default} }
	426	sub is_lazy { $_[0]->{lazy} }
	427	sub is_lazy_build { $_[0]->{lazy_build} }
	428	sub is_weak_ref { $_[0]->{weak_ref} }
	429	sub init_arg { $_[0]->{init_arg} }
	430	sub type_constraint { $_[0]->{type_constraint} }
	431
	432	sub trigger { $_[0]->{trigger} }
	433	sub builder { $_[0]->{builder} }
	434	sub should_auto_deref { $_[0]->{auto_deref} }
	435	sub should_coerce { $_[0]->{coerce} }
	436
d899d3e7	437	sub documentation { $_[0]->{documentation} }
d899d3e7	438
43165725	439	# predicates
	440
	441	sub has_accessor { exists $_[0]->{accessor} }
	442	sub has_reader { exists $_[0]->{reader} }
	443	sub has_writer { exists $_[0]->{writer} }
	444	sub has_predicate { exists $_[0]->{predicate} }
	445	sub has_clearer { exists $_[0]->{clearer} }
	446	sub has_handles { exists $_[0]->{handles} }
	447
	448	sub has_default { exists $_[0]->{default} }
	449	sub has_type_constraint { exists $_[0]->{type_constraint} }
	450	sub has_trigger { exists $_[0]->{trigger} }
	451	sub has_builder { exists $_[0]->{builder} }
	452
d899d3e7	453	sub has_documentation { exists $_[0]->{documentation} }
d899d3e7	454
ba1f50a2	455	sub _process_options{
	456	my($class, $name, $args) = @_;
	457
	458	# taken from Class::MOP::Attribute::new
	459
	460	defined($name)
	461	or $class->throw_error('You must provide a name for the attribute');
	462
	463	if(!exists $args->{init_arg}){
	464	$args->{init_arg} = $name;
	465	}
	466
	467	# 'required' requires eigher 'init_arg', 'builder', or 'default'
	468	my $can_be_required = defined( $args->{init_arg} );
	469
	470	if(exists $args->{builder}){
	471	# XXX:
	472	# Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
	473	# This feature will be changed in a future. (gfx)
	474	$class->throw_error('builder must be a defined scalar value which is a method name')
	475	#if ref $args->{builder} \|\| !defined $args->{builder};
	476	if !defined $args->{builder};
	477
	478	$can_be_required++;
	479	}
	480	elsif(exists $args->{default}){
	481	if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
	482	$class->throw_error("References are not allowed as default values, you must "
	483	. "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
	484	}
	485	$can_be_required++;
	486	}
	487
	488	if( $args->{required} && !$can_be_required ) {
	489	$class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
	490	}
	491
	492	# taken from Mouse::Meta::Attribute->new and ->_process_args
	493
	494	if(exists $args->{is}){
	495	my $is = $args->{is};
	496
	497	if($is eq 'ro'){
	498	$args->{reader} \|\|= $name;
	499	}
	500	elsif($is eq 'rw'){
	501	if(exists $args->{writer}){
	502	$args->{reader} \|\|= $name;
	503	}
	504	else{
	505	$args->{accessor} \|\|= $name;
	506	}
	507	}
	508	elsif($is eq 'bare'){
	509	# do nothing, but don't complain (later) about missing methods
	510	}
	511	else{
	512	$is = 'undef' if !defined $is;
	513	$class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
	514	}
	515	}
	516
	517	my $tc;
	518	if(exists $args->{isa}){
d503a4f3	519	$tc = $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
ba1f50a2	520	}
d503a4f3	521
	522	if(exists $args->{does}){
	523	if(defined $tc){ # both isa and does supplied
	524	my $does_ok = do{
	525	local $@;
	526	eval{ "$tc"->does($args) };
	527	};
	528	if(!$does_ok){
	529	$class->throw_error("Cannot have both an isa option and a does option because '$tc' does not do '$args->{does}' on attribute ($name)");
	530	}
	531	}
	532	else {
	533	$tc = $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
	534	}
ba1f50a2	535	}
ba1f50a2	536
	537	if($args->{coerce}){
	538	defined($tc)
	539	\|\| $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
	540
	541	$args->{weak_ref}
	542	&& $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
	543	}
	544
	545	if ($args->{lazy_build}) {
	546	exists($args->{default})
	547	&& $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
	548
	549	$args->{lazy} = 1;
	550	$args->{builder} \|\|= "_build_${name}";
	551	if ($name =~ /^_/) {
	552	$args->{clearer} \|\|= "_clear${name}";
	553	$args->{predicate} \|\|= "_has${name}";
	554	}
	555	else {
	556	$args->{clearer} \|\|= "clear_${name}";
	557	$args->{predicate} \|\|= "has_${name}";
	558	}
	559	}
	560
	561	if ($args->{auto_deref}) {
	562	defined($tc)
	563	\|\| $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
	564
	565	( $tc->is_a_type_of('ArrayRef') \|\| $tc->is_a_type_of('HashRef') )
	566	\|\| $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
	567	}
	568
	569	if (exists $args->{trigger}) {
	570	('CODE' eq ref $args->{trigger})
	571	\|\| $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
	572	}
	573
	574	if ($args->{lazy}) {
	575	(exists $args->{default} \|\| defined $args->{builder})
	576	\|\| $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
	577	}
	578
	579	return;
	580	}
	581
	582
6fffa617	583	package Mouse::Meta::TypeConstraint;
43165725	584
	585	sub name { $_[0]->{name} }
	586	sub parent { $_[0]->{parent} }
	587	sub message { $_[0]->{message} }
	588
72dc2c9d	589	sub type_parameter { $_[0]->{type_parameter} }
43165725	590	sub _compiled_type_constraint{ $_[0]->{compiled_type_constraint} }
93540011	591	sub _compiled_type_coercion { $_[0]->{_compiled_type_coercion} }
df6dd016	592
72dc2c9d	593	sub __is_parameterized { exists $_[0]->{type_parameter} }
72dc2c9d	594	sub has_coercion { exists $_[0]->{_compiled_type_coercion} }
df6dd016	595
f790c46b	596
	597	sub compile_type_constraint{
	598	my($self) = @_;
	599
	600	# add parents first
	601	my @checks;
	602	for(my $parent = $self->{parent}; defined $parent; $parent = $parent->{parent}){
	603	if($parent->{hand_optimized_type_constraint}){
	604	unshift @checks, $parent->{hand_optimized_type_constraint};
	605	last; # a hand optimized constraint must include all the parents
	606	}
	607	elsif($parent->{constraint}){
	608	unshift @checks, $parent->{constraint};
	609	}
	610	}
	611
	612	# then add child
	613	if($self->{constraint}){
	614	push @checks, $self->{constraint};
	615	}
	616
	617	if($self->{type_constraints}){ # Union
	618	my @types = map{ $_->{compiled_type_constraint} } @{ $self->{type_constraints} };
	619	push @checks, sub{
	620	foreach my $c(@types){
	621	return 1 if $c->($_[0]);
	622	}
	623	return 0;
	624	};
	625	}
	626
	627	if(@checks == 0){
	628	$self->{compiled_type_constraint} = \&Mouse::Util::TypeConstraints::Any;
	629	}
	630	else{
	631	$self->{compiled_type_constraint} = sub{
	632	my(@args) = @_;
	633	local $_ = $args[0];
	634	foreach my $c(@checks){
	635	return undef if !$c->(@args);
	636	}
	637	return 1;
	638	};
	639	}
	640	return;
	641	}
	642
c7576321	643	sub check {
	644	my $self = shift;
	645	return $self->_compiled_type_constraint->(@_);
	646	}
	647
	648
6fffa617	649	package Mouse::Object;
aa2d2e2c	650
aa2d2e2c	651	sub BUILDARGS {
aa2d2e2c	652	my $class = shift;
f790c46b	653
aa2d2e2c	654	if (scalar @_ == 1) {
	655	(ref($_[0]) eq 'HASH')
	656	\|\| $class->meta->throw_error("Single parameters to new() must be a HASH ref");
	657
	658	return {%{$_[0]}};
	659	}
	660	else {
	661	return {@_};
	662	}
	663	}
f790c46b	664
af04626d	665	sub new {
	666	my $class = shift;
	667
	668	$class->meta->throw_error('Cannot call new() on an instance') if ref $class;
	669
	670	my $args = $class->BUILDARGS(@_);
	671
	672	my $meta = Mouse::Meta::Class->initialize($class);
b5956f03	673	return $meta->new_object($args);
af04626d	674	}
af04626d	675
a5c683f6	676	sub DESTROY {
	677	my $self = shift;
	678
	679	return unless $self->can('DEMOLISH'); # short circuit
	680
	681	local $?;
	682
	683	my $e = do{
	684	local $@;
	685	eval{
a5c683f6	686	# DEMOLISHALL
	687
	688	# We cannot count on being able to retrieve a previously made
	689	# metaclass, _or_ being able to make a new one during global
	690	# destruction. However, we should still be able to use mro at
	691	# that time (at least tests suggest so ;)
	692
	693	foreach my $class (@{ Mouse::Util::get_linear_isa(ref $self) }) {
	694	my $demolish = Mouse::Util::get_code_ref($class, 'DEMOLISH')
	695	\|\| next;
	696
6514735e	697	$self->$demolish($Mouse::Util::in_global_destruction);
a5c683f6	698	}
	699	};
	700	$@;
	701	};
	702
	703	no warnings 'misc';
	704	die $e if $e; # rethrow
	705	}
	706
adb5eb76	707	sub BUILDALL {
	708	my $self = shift;
	709
	710	# short circuit
	711	return unless $self->can('BUILD');
	712
	713	for my $class (reverse $self->meta->linearized_isa) {
	714	my $build = Mouse::Util::get_code_ref($class, 'BUILD')
	715	\|\| next;
	716
	717	$self->$build(@_);
	718	}
	719	return;
	720	}
	721
	722	sub DEMOLISHALL;
	723	*DEMOLISHALL = \&DESTROY;
	724
df6dd016	725	1;
df6dd016	726	__END__
ccb38d0b	727
	728	=head1 NAME
	729
	730	Mouse::PurePerl - A Mouse guts in pure Perl
	731
	732	=head1 VERSION
	733
913b5964	734	This document describes Mouse version 0.61
ccb38d0b	735
	736	=head1 SEE ALSO
	737
	738	L<Mouse::XS>
	739
	740	=cut