lib/MooseX/Getopt/Basic.pm

   1 package MooseX::Getopt::Basic;
   2 # ABSTRACT: MooseX::Getopt::Basic - role to implement the Getopt::Long functionality
   3
   4 use Moose::Role;
   5
   6 use MooseX::Getopt::OptionTypeMap;
   7 use MooseX::Getopt::Meta::Attribute;
   8 use MooseX::Getopt::Meta::Attribute::NoGetopt;
   9 use MooseX::Getopt::ProcessedArgv;
  10 use Carp ();
  11
  12 use Getopt::Long 2.37 ();
  13
  14 has ARGV       => (is => 'rw', isa => 'ArrayRef', traits => ['NoGetopt']);
  15 has extra_argv => (is => 'rw', isa => 'ArrayRef', traits => ['NoGetopt']);
  16
  17 sub process_argv {
  18     my ($class, @params) = @_;
  19
  20     my $constructor_params = ( @params == 1 ? $params[0] : {@params} );
  21
  22     my $config_from_file;
  23     if($class->meta->does_role('MooseX::ConfigFromFile')) {
  24         local @ARGV = @ARGV;
  25
  26         # just get the configfile arg now out of @ARGV; the rest of the args
  27         # will be fetched later
  28         my $configfile;
  29         my $opt_parser = Getopt::Long::Parser->new( config => [ qw( no_auto_help pass_through no_auto_version ) ] );
  30         $opt_parser->getoptions( "configfile=s" => \$configfile );
  31
  32         my $cfmeta = $class->meta->find_attribute_by_name('configfile');
  33
  34         # was it passed to the constructor?
  35         if (!defined $configfile)
  36         {
  37             my $key = $cfmeta->init_arg;
  38             $configfile = $constructor_params->{$key} if $key;
  39         }
  40
  41         if(!defined $configfile) {
  42             $configfile = $cfmeta->default if $cfmeta->has_default;
  43             if (ref $configfile eq 'CODE') {
  44                 # not sure theres a lot you can do with the class and may break some assumptions
  45                 # warn?
  46                 $configfile = &$configfile($class);
  47             }
  48             if (defined $configfile) {
  49                 $config_from_file = eval {
  50                     $class->get_config_from_file($configfile);
  51                 };
  52                 if ($@) {
  53                     die $@ unless $@ =~ /Specified configfile '\Q$configfile\E' does not exist/;
  54                 }
  55             }
  56         }
  57         else {
  58             $config_from_file = $class->get_config_from_file($configfile);
  59         }
  60     }
  61
  62     Carp::croak("Single parameters to new_with_options() must be a HASH ref")
  63         unless ref($constructor_params) eq 'HASH';
  64
  65     my %processed = $class->_parse_argv(
  66         options => [
  67             $class->_attrs_to_options( $config_from_file )
  68         ],
  69         params => $constructor_params,
  70     );
  71
  72     my $params = $config_from_file ? { %$config_from_file, %{$processed{params}} } : $processed{params};
  73
  74     # did the user request usage information?
  75     if ( $processed{usage} and $params->{help_flag} ) {
  76         $class->print_usage_text($processed{usage});
  77     }
  78
  79     return MooseX::Getopt::ProcessedArgv->new(
  80          argv_copy          => $processed{argv_copy},
  81          extra_argv         => $processed{argv},
  82          usage              => $processed{usage},
  83          constructor_params => $constructor_params, # explicit params to ->new
  84          cli_params         => $params, # params from CLI
  85     );
  86 }
  87
  88 sub new_with_options {
  89     my ($class, @params) = @_;
  90
  91     my $pa = $class->process_argv(@params);
  92
  93     $class->new(
  94         ARGV       => $pa->argv_copy,
  95         extra_argv => $pa->extra_argv,
  96         ( $pa->usage ? ( usage => $pa->usage ) : () ),
  97         %{ $pa->constructor_params }, # explicit params to ->new
  98         %{ $pa->cli_params }, # params from CLI
  99     );
 100 }
 101
 102 sub _getopt_spec { shift->_traditional_spec(@_); }
 103
 104 sub _parse_argv {
 105     my ( $class, %params ) = @_;
 106
 107     local @ARGV = @{ $params{params}{argv} || \@ARGV };
 108
 109     my ( $opt_spec, $name_to_init_arg ) = $class->_getopt_spec(%params);
 110
 111     # Get a clean copy of the original @ARGV
 112     my $argv_copy = [ @ARGV ];
 113
 114     my @warnings;
 115     my ( $parsed_options, $usage ) = eval {
 116         local $SIG{__WARN__} = sub { push @warnings, @_ };
 117
 118         return $class->_getopt_get_options(\%params, $opt_spec);
 119     };
 120
 121     $class->_getopt_spec_warnings(@warnings) if @warnings;
 122     $class->_getopt_spec_exception(\@warnings, $@) if $@;
 123
 124     # Get a copy of the Getopt::Long-mangled @ARGV
 125     my $argv_mangled = [ @ARGV ];
 126
 127     my %constructor_args = (
 128         map {
 129             $name_to_init_arg->{$_} => $parsed_options->{$_}
 130         } keys %$parsed_options,
 131     );
 132
 133     return (
 134         params    => \%constructor_args,
 135         argv_copy => $argv_copy,
 136         argv      => $argv_mangled,
 137         ( defined($usage) ? ( usage => $usage ) : () ),
 138     );
 139 }
 140
 141 sub _getopt_get_options {
 142     my ($class, $params, $opt_spec) = @_;
 143     my %options;
 144     Getopt::Long::GetOptions(\%options, @$opt_spec);
 145     return ( \%options, undef );
 146 }
 147
 148 sub _getopt_spec_warnings { }
 149
 150 sub _getopt_spec_exception {
 151     my ($self, $warnings, $exception) = @_;
 152     die @$warnings, $exception;
 153 }
 154
 155 #(this is already documented in MooseX::Getopt. But FIXME later, via RT#82195)
 156 =for Pod::Coverage
 157     print_usage_text
 158 =cut
 159 sub print_usage_text {
 160     my ($self, $usage) = @_;
 161     print $usage->text;
 162     exit 0;
 163 }
 164 # maintained for backwards compatibility only
 165 sub _getopt_full_usage { shift->print_usage_text(@_) }
 166
 167 sub _usage_format {
 168     return "usage: %c %o";
 169 }
 170
 171 sub _traditional_spec {
 172     my ( $class, %params ) = @_;
 173
 174     my ( @options, %name_to_init_arg, %options );
 175
 176     foreach my $opt ( @{ $params{options} } ) {
 177         push @options, $opt->{opt_string};
 178
 179         my $identifier = $opt->{name};
 180         $identifier =~ s/\W/_/g; # Getopt::Long does this to all option names
 181
 182         $name_to_init_arg{$identifier} = $opt->{init_arg};
 183     }
 184
 185     return ( \@options, \%name_to_init_arg );
 186 }
 187
 188 sub _compute_getopt_attrs {
 189     my $class = shift;
 190     sort { $a->insertion_order <=> $b->insertion_order }
 191     grep {
 192         $_->does("MooseX::Getopt::Meta::Attribute::Trait")
 193             or
 194         $_->name !~ /^_/
 195     } grep {
 196         !$_->does('MooseX::Getopt::Meta::Attribute::Trait::NoGetopt')
 197     } $class->meta->get_all_attributes
 198 }
 199
 200 sub _get_cmd_flags_for_attr {
 201     my ( $class, $attr ) = @_;
 202
 203     my $flag = $attr->name;
 204
 205     my @aliases;
 206
 207     if ($attr->does('MooseX::Getopt::Meta::Attribute::Trait')) {
 208         $flag = $attr->cmd_flag if $attr->has_cmd_flag;
 209         @aliases = @{ $attr->cmd_aliases } if $attr->has_cmd_aliases;
 210     }
 211
 212     return ( $flag, @aliases );
 213 }
 214
 215 sub _attrs_to_options {
 216     my $class = shift;
 217     my $config_from_file = shift || {};
 218
 219     my @options;
 220
 221     foreach my $attr ($class->_compute_getopt_attrs) {
 222         my ( $flag, @aliases ) = $class->_get_cmd_flags_for_attr($attr);
 223
 224         my $opt_string = join(q{|}, $flag, @aliases);
 225
 226         if ($attr->name eq 'configfile') {
 227             $opt_string .= '=s';
 228         }
 229         elsif ($attr->has_type_constraint) {
 230             my $type = $attr->type_constraint;
 231             if (MooseX::Getopt::OptionTypeMap->has_option_type($type)) {
 232                 $opt_string .= MooseX::Getopt::OptionTypeMap->get_option_type($type)
 233             }
 234         }
 235
 236         push @options, {
 237             name       => $flag,
 238             init_arg   => $attr->init_arg,
 239             opt_string => $opt_string,
 240             required   => $attr->is_required && !$attr->has_default && !$attr->has_builder && !exists $config_from_file->{$attr->name},
 241             # NOTE:
 242             # this "feature" was breaking because
 243             # Getopt::Long::Descriptive would return
 244             # the default value as if it was a command
 245             # line flag, which would then override the
 246             # one passed into a constructor.
 247             # See 100_gld_default_bug.t for an example
 248             # - SL
 249             #( ( $attr->has_default && ( $attr->is_default_a_coderef xor $attr->is_lazy ) ) ? ( default => $attr->default({}) ) : () ),
 250             ( $attr->has_documentation ? ( doc => $attr->documentation ) : () ),
 251         }
 252     }
 253
 254     return @options;
 255 }
 256
 257 no Moose::Role;
 258 1;
 259
 260 =head1 SYNOPSIS
 261
 262   ## In your class
 263   package My::App;
 264   use Moose;
 265
 266   with 'MooseX::Getopt::Basic';
 267
 268   has 'out' => (is => 'rw', isa => 'Str', required => 1);
 269   has 'in'  => (is => 'rw', isa => 'Str', required => 1);
 270
 271   # ... rest of the class here
 272
 273   ## in your script
 274   #!/usr/bin/perl
 275
 276   use My::App;
 277
 278   my $app = My::App->new_with_options();
 279   # ... rest of the script here
 280
 281   ## on the command line
 282   % perl my_app_script.pl --in file.input --out file.dump
 283
 284 =head1 DESCRIPTION
 285
 286 This is like L<MooseX::Getopt> and can be used instead except that it
 287 doesn't make use of L<Getopt::Long::Descriptive> (or "GLD" for short).
 288
 289 =method new_with_options
 290
 291 See L<MooseX::Getopt/new_with_options>.
 292
 293 =method process_argv
 294
 295 See L<MooseX::Getopt/process_argv>.
 296
 297 =cut