lib/MooseX/Getopt/Basic.pm

   1 package MooseX::Getopt::Basic;
   2 # ABSTRACT: MooseX::Getopt::Basic - role to implement the Getopt::Long functionality
   3
   4 use Moose::Role;
   5
   6 use MooseX::Getopt::OptionTypeMap;
   7 use MooseX::Getopt::Meta::Attribute;
   8 use MooseX::Getopt::Meta::Attribute::NoGetopt;
   9 use MooseX::Getopt::ProcessedArgv;
  10 use Try::Tiny;
  11 use Carp ();
  12
  13 use Getopt::Long 2.37 ();
  14
  15 has ARGV       => (is => 'rw', isa => 'ArrayRef', traits => ['NoGetopt']);
  16 has extra_argv => (is => 'rw', isa => 'ArrayRef', traits => ['NoGetopt']);
  17
  18 sub process_argv {
  19     my ($class, @params) = @_;
  20
  21     my $constructor_params = ( @params == 1 ? $params[0] : {@params} );
  22
  23     my $config_from_file;
  24     if($class->meta->does_role('MooseX::ConfigFromFile')) {
  25         local @ARGV = @ARGV;
  26
  27         # just get the configfile arg now out of @ARGV; the rest of the args
  28         # will be fetched later
  29         my $configfile;
  30         my $opt_parser = Getopt::Long::Parser->new( config => [ qw( no_auto_help pass_through no_auto_version ) ] );
  31         $opt_parser->getoptions( "configfile=s" => \$configfile );
  32
  33         my $cfmeta = $class->meta->find_attribute_by_name('configfile');
  34         my $init_arg = $cfmeta->init_arg;
  35
  36         # was it passed to the constructor?
  37         if (!defined $configfile)
  38         {
  39             $configfile = $constructor_params->{$init_arg} if defined $init_arg;
  40         }
  41
  42         if(!defined $configfile) {
  43             # this is a classic legacy usecase documented in
  44             # MooseX::ConfigFromFile that we should continue to support
  45             $configfile = try { $class->configfile };
  46
  47             $configfile = $cfmeta->default
  48                 if not defined $configfile and $cfmeta->has_default;
  49             if (ref $configfile eq 'CODE') {
  50                 # not sure theres a lot you can do with the class and may break some assumptions
  51                 # warn?
  52                 $configfile = &$configfile($class);
  53             }
  54             if (defined $configfile) {
  55                 $config_from_file = try {
  56                     $class->get_config_from_file($configfile);
  57                 }
  58                 catch {
  59                     die $_ unless /Specified configfile '\Q$configfile\E' does not exist/;
  60                 };
  61             }
  62
  63             $constructor_params->{$init_arg} = $configfile
  64                 if defined $configfile and defined $init_arg;
  65         }
  66         else {
  67             $config_from_file = $class->get_config_from_file($configfile);
  68         }
  69     }
  70
  71     Carp::croak("Single parameters to new_with_options() must be a HASH ref")
  72         unless ref($constructor_params) eq 'HASH';
  73
  74     my %processed = $class->_parse_argv(
  75         options => [
  76             $class->_attrs_to_options( $config_from_file )
  77         ],
  78         params => $constructor_params,
  79     );
  80
  81     my $params = $config_from_file ? { %$config_from_file, %{$processed{params}} } : $processed{params};
  82
  83     # did the user request usage information?
  84     if ( $processed{usage} and $params->{help_flag} ) {
  85         $class->print_usage_text($processed{usage});
  86     }
  87
  88     return MooseX::Getopt::ProcessedArgv->new(
  89          argv_copy          => $processed{argv_copy},
  90          extra_argv         => $processed{argv},
  91          usage              => $processed{usage},
  92          constructor_params => $constructor_params, # explicit params to ->new
  93          cli_params         => $params, # params from CLI
  94     );
  95 }
  96
  97 sub new_with_options {
  98     my ($class, @params) = @_;
  99
 100     my $pa = $class->process_argv(@params);
 101
 102     $class->new(
 103         ARGV       => $pa->argv_copy,
 104         extra_argv => $pa->extra_argv,
 105         ( $pa->usage ? ( usage => $pa->usage ) : () ),
 106         %{ $pa->constructor_params }, # explicit params to ->new
 107         %{ $pa->cli_params }, # params from CLI
 108     );
 109 }
 110
 111 sub _getopt_spec { shift->_traditional_spec(@_); }
 112
 113 sub _parse_argv {
 114     my ( $class, %params ) = @_;
 115
 116     local @ARGV = @{ $params{params}{argv} || \@ARGV };
 117
 118     my ( $opt_spec, $name_to_init_arg ) = $class->_getopt_spec(%params);
 119
 120     # Get a clean copy of the original @ARGV
 121     my $argv_copy = [ @ARGV ];
 122
 123     my @warnings;
 124     my ( $parsed_options, $usage ) = try {
 125         local $SIG{__WARN__} = sub { push @warnings, @_ };
 126
 127         return $class->_getopt_get_options(\%params, $opt_spec);
 128     }
 129     catch {
 130         $class->_getopt_spec_exception(\@warnings, $_);
 131     };
 132
 133     $class->_getopt_spec_warnings(@warnings) if @warnings;
 134
 135     # Get a copy of the Getopt::Long-mangled @ARGV
 136     my $argv_mangled = [ @ARGV ];
 137
 138     my %constructor_args = (
 139         map {
 140             $name_to_init_arg->{$_} => $parsed_options->{$_}
 141         } keys %$parsed_options,
 142     );
 143
 144     return (
 145         params    => \%constructor_args,
 146         argv_copy => $argv_copy,
 147         argv      => $argv_mangled,
 148         ( defined($usage) ? ( usage => $usage ) : () ),
 149     );
 150 }
 151
 152 sub _getopt_get_options {
 153     my ($class, $params, $opt_spec) = @_;
 154     my %options;
 155     Getopt::Long::GetOptions(\%options, @$opt_spec);
 156     return ( \%options, undef );
 157 }
 158
 159 sub _getopt_spec_warnings { }
 160
 161 sub _getopt_spec_exception {
 162     my ($self, $warnings, $exception) = @_;
 163     die @$warnings, $exception;
 164 }
 165
 166 # maintained for backwards compatibility only
 167 sub _getopt_full_usage
 168 {
 169     my ($self, $usage) = @_;
 170     print $usage->text;
 171     exit 0;
 172 }
 173 #(this is already documented in MooseX::Getopt. But FIXME later, via RT#82195)
 174 =for Pod::Coverage
 175     print_usage_text
 176 =cut
 177 sub print_usage_text { shift->_getopt_full_usage(@_) }
 178
 179 sub _usage_format {
 180     return "usage: %c %o";
 181 }
 182
 183 sub _traditional_spec {
 184     my ( $class, %params ) = @_;
 185
 186     my ( @options, %name_to_init_arg, %options );
 187
 188     foreach my $opt ( @{ $params{options} } ) {
 189         push @options, $opt->{opt_string};
 190
 191         my $identifier = $opt->{name};
 192         $identifier =~ s/\W/_/g; # Getopt::Long does this to all option names
 193
 194         $name_to_init_arg{$identifier} = $opt->{init_arg};
 195     }
 196
 197     return ( \@options, \%name_to_init_arg );
 198 }
 199
 200 sub _compute_getopt_attrs {
 201     my $class = shift;
 202     sort { $a->insertion_order <=> $b->insertion_order }
 203     grep {
 204         $_->does("MooseX::Getopt::Meta::Attribute::Trait")
 205             or
 206         $_->name !~ /^_/
 207     } grep {
 208         !$_->does('MooseX::Getopt::Meta::Attribute::Trait::NoGetopt')
 209     } $class->meta->get_all_attributes
 210 }
 211
 212 sub _get_cmd_flags_for_attr {
 213     my ( $class, $attr ) = @_;
 214
 215     my $flag = $attr->name;
 216
 217     my @aliases;
 218
 219     if ($attr->does('MooseX::Getopt::Meta::Attribute::Trait')) {
 220         $flag = $attr->cmd_flag if $attr->has_cmd_flag;
 221         @aliases = @{ $attr->cmd_aliases } if $attr->has_cmd_aliases;
 222     }
 223
 224     return ( $flag, @aliases );
 225 }
 226
 227 sub _attrs_to_options {
 228     my $class = shift;
 229     my $config_from_file = shift || {};
 230
 231     my @options;
 232
 233     foreach my $attr ($class->_compute_getopt_attrs) {
 234         my ( $flag, @aliases ) = $class->_get_cmd_flags_for_attr($attr);
 235
 236         my $opt_string = join(q{|}, $flag, @aliases);
 237
 238         if ($attr->name eq 'configfile') {
 239             $opt_string .= '=s';
 240         }
 241         elsif ($attr->has_type_constraint) {
 242             my $type = $attr->type_constraint;
 243             if (MooseX::Getopt::OptionTypeMap->has_option_type($type)) {
 244                 $opt_string .= MooseX::Getopt::OptionTypeMap->get_option_type($type)
 245             }
 246         }
 247
 248         push @options, {
 249             name       => $flag,
 250             init_arg   => $attr->init_arg,
 251             opt_string => $opt_string,
 252             required   => $attr->is_required && !$attr->has_default && !$attr->has_builder && !exists $config_from_file->{$attr->name},
 253             # NOTE:
 254             # this "feature" was breaking because
 255             # Getopt::Long::Descriptive would return
 256             # the default value as if it was a command
 257             # line flag, which would then override the
 258             # one passed into a constructor.
 259             # See 100_gld_default_bug.t for an example
 260             # - SL
 261             #( ( $attr->has_default && ( $attr->is_default_a_coderef xor $attr->is_lazy ) ) ? ( default => $attr->default({}) ) : () ),
 262             ( $attr->has_documentation ? ( doc => $attr->documentation ) : () ),
 263         }
 264     }
 265
 266     return @options;
 267 }
 268
 269 no Moose::Role;
 270 1;
 271
 272 =head1 SYNOPSIS
 273
 274   ## In your class
 275   package My::App;
 276   use Moose;
 277
 278   with 'MooseX::Getopt::Basic';
 279
 280   has 'out' => (is => 'rw', isa => 'Str', required => 1);
 281   has 'in'  => (is => 'rw', isa => 'Str', required => 1);
 282
 283   # ... rest of the class here
 284
 285   ## in your script
 286   #!/usr/bin/perl
 287
 288   use My::App;
 289
 290   my $app = My::App->new_with_options();
 291   # ... rest of the script here
 292
 293   ## on the command line
 294   % perl my_app_script.pl --in file.input --out file.dump
 295
 296 =head1 DESCRIPTION
 297
 298 This is like L<MooseX::Getopt> and can be used instead except that it
 299 doesn't make use of L<Getopt::Long::Descriptive> (or "GLD" for short).
 300
 301 =method new_with_options
 302
 303 See L<MooseX::Getopt/new_with_options>.
 304
 305 =method process_argv
 306
 307 See L<MooseX::Getopt/process_argv>.
 308
 309 =cut