lib/MooseX/Getopt/Basic.pm

   1 package MooseX::Getopt::Basic;
   2 use Moose::Role;
   3
   4 use MooseX::Getopt::OptionTypeMap;
   5 use MooseX::Getopt::Meta::Attribute;
   6 use MooseX::Getopt::Meta::Attribute::NoGetopt;
   7 use Carp ();
   8
   9 use Getopt::Long (); # GLD uses it anyway, doesn't hurt
  10
  11 our $VERSION   = '0.20';
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 has ARGV       => (is => 'rw', isa => 'ArrayRef', metaclass => "NoGetopt");
  15 has extra_argv => (is => 'rw', isa => 'ArrayRef', metaclass => "NoGetopt");
  16
  17 # _getopt_spec() and _getoptions() are overrided by MooseX::Getopt::GLD.
  18
  19 sub _getopt_spec {
  20     my ($class, %params) = @_;
  21     return $class->_traditional_spec(%params)
  22 }
  23
  24 sub _get_options {
  25     my ($class, undef, $opt_spec) = @_;
  26     my %options;
  27     Getopt::Long::GetOptions(\%options, @$opt_spec);
  28     return ( \%options, undef );
  29 }
  30
  31 sub new_with_options {
  32     my ($class, @params) = @_;
  33
  34     my $config_from_file;
  35     if($class->meta->does_role('MooseX::ConfigFromFile')) {
  36         local @ARGV = @ARGV;
  37
  38         my $configfile;
  39         my $opt_parser = Getopt::Long::Parser->new( config => [ qw( pass_through ) ] );
  40         $opt_parser->getoptions( "configfile=s" => \$configfile );
  41
  42         if(!defined $configfile) {
  43             my $cfmeta = $class->meta->find_attribute_by_name('configfile');
  44             $configfile = $cfmeta->default if $cfmeta->has_default;
  45         }
  46
  47         if (defined $configfile) {
  48             $config_from_file = eval {
  49                 $class->get_config_from_file($configfile);
  50             };
  51             if ($@) {
  52                 die $@ unless $@ =~ /Specified configfile '\Q$configfile\E' does not exist/;
  53             }
  54         }
  55     }
  56
  57     my $constructor_params = ( @params == 1 ? $params[0] : {@params} );
  58
  59     Carp::croak("Single parameters to new_with_options() must be a HASH ref")
  60         unless ref($constructor_params) eq 'HASH';
  61
  62     my %processed = $class->_parse_argv(
  63         options => [
  64             $class->_attrs_to_options( $config_from_file )
  65         ],
  66         params => $constructor_params,
  67     );
  68
  69     my $params = $config_from_file ? { %$config_from_file, %{$processed{params}} } : $processed{params};
  70
  71     # did the user request usage information?
  72     if ( $processed{usage} && ($params->{'?'} or $params->{help} or $params->{usage}) )
  73     {
  74         $class->_exit_with_usage($processed{usage});
  75     }
  76
  77     $class->new(
  78         ARGV       => $processed{argv_copy},
  79         extra_argv => $processed{argv},
  80         %$constructor_params, # explicit params to ->new
  81         %$params, # params from CLI
  82     );
  83 }
  84
  85 sub _exit_with_usage {
  86     my ($self, $usage) = @_;
  87     $usage->die();
  88 }
  89
  90 sub _parse_argv {
  91     my ( $class, %params ) = @_;
  92
  93     local @ARGV = @{ $params{params}{argv} || \@ARGV };
  94
  95     my ( $opt_spec, $name_to_init_arg ) = $class->_getopt_spec(%params);
  96
  97     # Get a clean copy of the original @ARGV
  98     my $argv_copy = [ @ARGV ];
  99
 100     my @err;
 101
 102     my ( $parsed_options, $usage ) = eval {
 103         local $SIG{__WARN__} = sub { push @err, @_ };
 104
 105         return $class->_get_options(\%params, $opt_spec);
 106     };
 107
 108     die join "", grep { defined } @err, $@ if @err or $@;
 109
 110     # Get a copy of the Getopt::Long-mangled @ARGV
 111     my $argv_mangled = [ @ARGV ];
 112
 113     my %constructor_args = (
 114         map {
 115             $name_to_init_arg->{$_} => $parsed_options->{$_}
 116         } keys %$parsed_options,
 117     );
 118
 119     return (
 120         params    => \%constructor_args,
 121         argv_copy => $argv_copy,
 122         argv      => $argv_mangled,
 123         ( defined($usage) ? ( usage => $usage ) : () ),
 124     );
 125 }
 126
 127 sub _usage_format {
 128     return "usage: %c %o";
 129 }
 130
 131 sub _traditional_spec {
 132     my ( $class, %params ) = @_;
 133
 134     my ( @options, %name_to_init_arg, %options );
 135
 136     foreach my $opt ( @{ $params{options} } ) {
 137         push @options, $opt->{opt_string};
 138
 139         my $identifier = $opt->{name};
 140         $identifier =~ s/\W/_/g; # Getopt::Long does this to all option names
 141
 142         $name_to_init_arg{$identifier} = $opt->{init_arg};
 143     }
 144
 145     return ( \@options, \%name_to_init_arg );
 146 }
 147
 148 sub _compute_getopt_attrs {
 149     my $class = shift;
 150     grep {
 151         $_->does("MooseX::Getopt::Meta::Attribute::Trait")
 152             or
 153         $_->name !~ /^_/
 154     } grep {
 155         !$_->does('MooseX::Getopt::Meta::Attribute::Trait::NoGetopt')
 156     } $class->meta->get_all_attributes
 157 }
 158
 159 sub _get_cmd_flags_for_attr {
 160     my ( $class, $attr ) = @_;
 161
 162     my $flag = $attr->name;
 163
 164     my @aliases;
 165
 166     if ($attr->does('MooseX::Getopt::Meta::Attribute::Trait')) {
 167         $flag = $attr->cmd_flag if $attr->has_cmd_flag;
 168         @aliases = @{ $attr->cmd_aliases } if $attr->has_cmd_aliases;
 169     }
 170
 171     return ( $flag, @aliases );
 172 }
 173
 174 sub _attrs_to_options {
 175     my $class = shift;
 176     my $config_from_file = shift || {};
 177
 178     my @options;
 179
 180     foreach my $attr ($class->_compute_getopt_attrs) {
 181         my ( $flag, @aliases ) = $class->_get_cmd_flags_for_attr($attr);
 182
 183         my $opt_string = join(q{|}, $flag, @aliases);
 184
 185         if ($attr->name eq 'configfile') {
 186             $opt_string .= '=s';
 187         }
 188         elsif ($attr->has_type_constraint) {
 189             my $type = $attr->type_constraint;
 190             if (MooseX::Getopt::OptionTypeMap->has_option_type($type)) {
 191                 $opt_string .= MooseX::Getopt::OptionTypeMap->get_option_type($type)
 192             }
 193         }
 194
 195         push @options, {
 196             name       => $flag,
 197             init_arg   => $attr->init_arg,
 198             opt_string => $opt_string,
 199             required   => $attr->is_required && !$attr->has_default && !$attr->has_builder && !exists $config_from_file->{$attr->name},
 200             # NOTE:
 201             # this "feature" was breaking because
 202             # Getopt::Long::Descriptive would return
 203             # the default value as if it was a command
 204             # line flag, which would then override the
 205             # one passed into a constructor.
 206             # See 100_gld_default_bug.t for an example
 207             # - SL
 208             #( ( $attr->has_default && ( $attr->is_default_a_coderef xor $attr->is_lazy ) ) ? ( default => $attr->default({}) ) : () ),
 209             ( $attr->has_documentation ? ( doc => $attr->documentation ) : () ),
 210         }
 211     }
 212
 213     return @options;
 214 }
 215
 216 no Moose::Role; 1;
 217
 218 1;
 219
 220 =pod
 221
 222 =head1 NAME
 223
 224 MooseX::Getopt::Basic - role to implement the basic functionality of
 225 L<MooseX::Getopt> without GLD.
 226
 227 =head1 SYNOPSIS
 228
 229   ## In your class
 230   package My::App;
 231   use Moose;
 232
 233   with 'MooseX::Getopt::Basic';
 234
 235   has 'out' => (is => 'rw', isa => 'Str', required => 1);
 236   has 'in'  => (is => 'rw', isa => 'Str', required => 1);
 237
 238   # ... rest of the class here
 239
 240   ## in your script
 241   #!/usr/bin/perl
 242
 243   use My::App;
 244
 245   my $app = My::App->new_with_options();
 246   # ... rest of the script here
 247
 248   ## on the command line
 249   % perl my_app_script.pl --in file.input --out file.dump
 250
 251 =head1 DESCRIPTION
 252
 253 This is like L<MooseX::Getopt> and can be used instead except that it
 254 doesn't make use of L<Getopt::Long::Descriptive> (or "GLD" for short).
 255
 256 =head1 METHODS
 257
 258 =over 4
 259
 260 =item B<new_with_options>
 261
 262 See L<MooseX::Getopt> .
 263
 264 =item B<meta>
 265
 266 This returns the role meta object.
 267
 268 =back
 269
 270 =head1 BUGS
 271
 272 All complex software has bugs lurking in it, and this module is no
 273 exception. If you find a bug please either email me, or add the bug
 274 to cpan-RT.
 275
 276 =head1 AUTHOR
 277
 278 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 279
 280 Brandon L. Black, E<lt>blblack@gmail.comE<gt>
 281
 282 Yuval Kogman, E<lt>nothingmuch@woobling.orgE<gt>
 283
 284 =head1 CONTRIBUTORS
 285
 286 Ryan D Johnson, E<lt>ryan@innerfence.comE<gt>
 287
 288 Drew Taylor, E<lt>drew@drewtaylor.comE<gt>
 289
 290 Shlomi Fish E<lt>shlomif@cpan.orgE<gt>
 291
 292 =head1 COPYRIGHT AND LICENSE
 293
 294 Copyright 2007-2008 by Infinity Interactive, Inc.
 295
 296 L<http://www.iinteractive.com>
 297
 298 This library is free software; you can redistribute it and/or modify
 299 it under the same terms as Perl itself.
 300
 301 =cut
 302