lib/MooseX/Getopt/Basic.pm

   1 package MooseX::Getopt::Basic;
   2 use Moose::Role;
   3
   4 use MooseX::Getopt::OptionTypeMap;
   5 use MooseX::Getopt::Meta::Attribute;
   6 use MooseX::Getopt::Meta::Attribute::NoGetopt;
   7 use Carp ();
   8
   9 use Getopt::Long (); # GLD uses it anyway, doesn't hurt
  10
  11 our $VERSION   = '0.20';
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 has ARGV       => (is => 'rw', isa => 'ArrayRef', metaclass => "NoGetopt");
  15 has extra_argv => (is => 'rw', isa => 'ArrayRef', metaclass => "NoGetopt");
  16
  17 # _getopt_spec() and _getoptions() are overrided by MooseX::Getopt::GLD.
  18
  19 sub _getopt_spec {
  20     my ($class, %params) = @_;
  21     return $class->_traditional_spec(%params)
  22 }
  23
  24 sub _get_options {
  25     my ($class, undef, $opt_spec) = @_;
  26     my %options;
  27     Getopt::Long::GetOptions(\%options, @$opt_spec);
  28     return ( \%options, undef );
  29 }
  30
  31 sub new_with_options {
  32     my ($class, @params) = @_;
  33
  34     my $config_from_file;
  35     if($class->meta->does_role('MooseX::ConfigFromFile')) {
  36         local @ARGV = @ARGV;
  37
  38         my $configfile;
  39         my $opt_parser = Getopt::Long::Parser->new( config => [ qw( pass_through ) ] );
  40         $opt_parser->getoptions( "configfile=s" => \$configfile );
  41
  42         if(!defined $configfile) {
  43             my $cfmeta = $class->meta->find_attribute_by_name('configfile');
  44             $configfile = $cfmeta->default if $cfmeta->has_default;
  45         }
  46
  47         if (defined $configfile) {
  48             $config_from_file = eval {
  49                 $class->get_config_from_file($configfile);
  50             };
  51             if ($@) {
  52                 die $@ unless $@ =~ /Specified configfile '\Q$configfile\E' does not exist/;
  53             }
  54         }
  55     }
  56
  57     my $constructor_params = ( @params == 1 ? $params[0] : {@params} );
  58
  59     Carp::croak("Single parameters to new_with_options() must be a HASH ref")
  60         unless ref($constructor_params) eq 'HASH';
  61
  62     my %processed = $class->_parse_argv(
  63         options => [
  64             $class->_attrs_to_options( $config_from_file )
  65         ],
  66         params => $constructor_params,
  67     );
  68
  69     my $params = $config_from_file ? { %$config_from_file, %{$processed{params}} } : $processed{params};
  70
  71     # did the user request usage information?
  72     if ( $processed{usage} && ($params->{'?'} or $params->{help} or $params->{usage}) )
  73     {
  74         $processed{usage}->die();
  75     }
  76
  77     $class->new(
  78         ARGV       => $processed{argv_copy},
  79         extra_argv => $processed{argv},
  80         %$constructor_params, # explicit params to ->new
  81         %$params, # params from CLI
  82     );
  83 }
  84
  85 sub _parse_argv {
  86     my ( $class, %params ) = @_;
  87
  88     local @ARGV = @{ $params{params}{argv} || \@ARGV };
  89
  90     my ( $opt_spec, $name_to_init_arg ) = $class->_getopt_spec(%params);
  91
  92     # Get a clean copy of the original @ARGV
  93     my $argv_copy = [ @ARGV ];
  94
  95     my @err;
  96
  97     my ( $parsed_options, $usage ) = eval {
  98         local $SIG{__WARN__} = sub { push @err, @_ };
  99
 100         return $class->_get_options(\%params, $opt_spec);
 101     };
 102
 103     die join "", grep { defined } @err, $@ if @err or $@;
 104
 105     # Get a copy of the Getopt::Long-mangled @ARGV
 106     my $argv_mangled = [ @ARGV ];
 107
 108     my %constructor_args = (
 109         map {
 110             $name_to_init_arg->{$_} => $parsed_options->{$_}
 111         } keys %$parsed_options,
 112     );
 113
 114     return (
 115         params    => \%constructor_args,
 116         argv_copy => $argv_copy,
 117         argv      => $argv_mangled,
 118         ( defined($usage) ? ( usage => $usage ) : () ),
 119     );
 120 }
 121
 122 sub _usage_format {
 123     return "usage: %c %o";
 124 }
 125
 126 sub _traditional_spec {
 127     my ( $class, %params ) = @_;
 128
 129     my ( @options, %name_to_init_arg, %options );
 130
 131     foreach my $opt ( @{ $params{options} } ) {
 132         push @options, $opt->{opt_string};
 133
 134         my $identifier = $opt->{name};
 135         $identifier =~ s/\W/_/g; # Getopt::Long does this to all option names
 136
 137         $name_to_init_arg{$identifier} = $opt->{init_arg};
 138     }
 139
 140     return ( \@options, \%name_to_init_arg );
 141 }
 142
 143 sub _compute_getopt_attrs {
 144     my $class = shift;
 145     grep {
 146         $_->does("MooseX::Getopt::Meta::Attribute::Trait")
 147             or
 148         $_->name !~ /^_/
 149     } grep {
 150         !$_->does('MooseX::Getopt::Meta::Attribute::Trait::NoGetopt')
 151     } $class->meta->get_all_attributes
 152 }
 153
 154 sub _get_cmd_flags_for_attr {
 155     my ( $class, $attr ) = @_;
 156
 157     my $flag = $attr->name;
 158
 159     my @aliases;
 160
 161     if ($attr->does('MooseX::Getopt::Meta::Attribute::Trait')) {
 162         $flag = $attr->cmd_flag if $attr->has_cmd_flag;
 163         @aliases = @{ $attr->cmd_aliases } if $attr->has_cmd_aliases;
 164     }
 165
 166     return ( $flag, @aliases );
 167 }
 168
 169 sub _attrs_to_options {
 170     my $class = shift;
 171     my $config_from_file = shift || {};
 172
 173     my @options;
 174
 175     foreach my $attr ($class->_compute_getopt_attrs) {
 176         my ( $flag, @aliases ) = $class->_get_cmd_flags_for_attr($attr);
 177
 178         my $opt_string = join(q{|}, $flag, @aliases);
 179
 180         if ($attr->name eq 'configfile') {
 181             $opt_string .= '=s';
 182         }
 183         elsif ($attr->has_type_constraint) {
 184             my $type = $attr->type_constraint;
 185             if (MooseX::Getopt::OptionTypeMap->has_option_type($type)) {
 186                 $opt_string .= MooseX::Getopt::OptionTypeMap->get_option_type($type)
 187             }
 188         }
 189
 190         push @options, {
 191             name       => $flag,
 192             init_arg   => $attr->init_arg,
 193             opt_string => $opt_string,
 194             required   => $attr->is_required && !$attr->has_default && !$attr->has_builder && !exists $config_from_file->{$attr->name},
 195             # NOTE:
 196             # this "feature" was breaking because
 197             # Getopt::Long::Descriptive would return
 198             # the default value as if it was a command
 199             # line flag, which would then override the
 200             # one passed into a constructor.
 201             # See 100_gld_default_bug.t for an example
 202             # - SL
 203             #( ( $attr->has_default && ( $attr->is_default_a_coderef xor $attr->is_lazy ) ) ? ( default => $attr->default({}) ) : () ),
 204             ( $attr->has_documentation ? ( doc => $attr->documentation ) : () ),
 205         }
 206     }
 207
 208     return @options;
 209 }
 210
 211 no Moose::Role; 1;
 212
 213 1;
 214
 215 =pod
 216
 217 =head1 NAME
 218
 219 MooseX::Getopt::Basic - role to implement the basic functionality of
 220 L<MooseX::Getopt> without GLD.
 221
 222 =head1 SYNOPSIS
 223
 224   ## In your class
 225   package My::App;
 226   use Moose;
 227
 228   with 'MooseX::Getopt::Basic';
 229
 230   has 'out' => (is => 'rw', isa => 'Str', required => 1);
 231   has 'in'  => (is => 'rw', isa => 'Str', required => 1);
 232
 233   # ... rest of the class here
 234
 235   ## in your script
 236   #!/usr/bin/perl
 237
 238   use My::App;
 239
 240   my $app = My::App->new_with_options();
 241   # ... rest of the script here
 242
 243   ## on the command line
 244   % perl my_app_script.pl --in file.input --out file.dump
 245
 246 =head1 DESCRIPTION
 247
 248 This is like L<MooseX::Getopt> and can be used instead except that it
 249 doesn't make use of L<Getopt::Long::Descriptive> (or "GLD" for short).
 250
 251 =head1 METHODS
 252
 253 =over 4
 254
 255 =item B<new_with_options>
 256
 257 See L<MooseX::Getopt> .
 258
 259 =item B<meta>
 260
 261 This returns the role meta object.
 262
 263 =back
 264
 265 =head1 BUGS
 266
 267 All complex software has bugs lurking in it, and this module is no
 268 exception. If you find a bug please either email me, or add the bug
 269 to cpan-RT.
 270
 271 =head1 AUTHOR
 272
 273 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 274
 275 Brandon L. Black, E<lt>blblack@gmail.comE<gt>
 276
 277 Yuval Kogman, E<lt>nothingmuch@woobling.orgE<gt>
 278
 279 =head1 CONTRIBUTORS
 280
 281 Ryan D Johnson, E<lt>ryan@innerfence.comE<gt>
 282
 283 Drew Taylor, E<lt>drew@drewtaylor.comE<gt>
 284
 285 Shlomi Fish E<lt>shlomif@cpan.orgE<gt>
 286
 287 =head1 COPYRIGHT AND LICENSE
 288
 289 Copyright 2007-2008 by Infinity Interactive, Inc.
 290
 291 L<http://www.iinteractive.com>
 292
 293 This library is free software; you can redistribute it and/or modify
 294 it under the same terms as Perl itself.
 295
 296 =cut
 297