lib/MooseX/Getopt/Basic.pm

   1
   2 package MooseX::Getopt::Basic;
   3 use Moose::Role;
   4
   5 use MooseX::Getopt::OptionTypeMap;
   6 use MooseX::Getopt::Meta::Attribute;
   7 use MooseX::Getopt::Meta::Attribute::NoGetopt;
   8 use Carp ();
   9
  10 use Getopt::Long ();
  11
  12 has ARGV       => (is => 'rw', isa => 'ArrayRef', metaclass => "NoGetopt");
  13 has extra_argv => (is => 'rw', isa => 'ArrayRef', metaclass => "NoGetopt");
  14
  15 sub new_with_options {
  16     my ($class, @params) = @_;
  17
  18     my $config_from_file;
  19     if($class->meta->does_role('MooseX::ConfigFromFile')) {
  20         local @ARGV = @ARGV;
  21
  22         my $configfile;
  23         my $opt_parser = Getopt::Long::Parser->new( config => [ qw( pass_through ) ] );
  24         $opt_parser->getoptions( "configfile=s" => \$configfile );
  25
  26         if(!defined $configfile) {
  27             my $cfmeta = $class->meta->find_attribute_by_name('configfile');
  28             $configfile = $cfmeta->default if $cfmeta->has_default;
  29             if (ref $configfile eq 'CODE') {
  30                 # not sure theres a lot you can do with the class and may break some assumptions
  31                 # warn?
  32                 $configfile = &$configfile($class);
  33             }
  34             if (defined $configfile) {
  35                 $config_from_file = eval {
  36                     $class->get_config_from_file($configfile);
  37                 };
  38                 if ($@) {
  39                     die $@ unless $@ =~ /Specified configfile '\Q$configfile\E' does not exist/;
  40                 }
  41             }
  42         }
  43         else {
  44             $config_from_file = $class->get_config_from_file($configfile);
  45         }
  46     }
  47
  48     my $constructor_params = ( @params == 1 ? $params[0] : {@params} );
  49
  50     Carp::croak("Single parameters to new_with_options() must be a HASH ref")
  51         unless ref($constructor_params) eq 'HASH';
  52
  53     my %processed = $class->_parse_argv(
  54         options => [
  55             $class->_attrs_to_options( $config_from_file )
  56         ],
  57         params => $constructor_params,
  58     );
  59
  60     my $params = $config_from_file ? { %$config_from_file, %{$processed{params}} } : $processed{params};
  61
  62     # did the user request usage information?
  63     if ( $processed{usage} && ($params->{'?'} or $params->{help} or $params->{usage}) )
  64     {
  65         $class->_getopt_full_usage($processed{usage});
  66     }
  67
  68     $class->new(
  69         ARGV       => $processed{argv_copy},
  70         extra_argv => $processed{argv},
  71         %$constructor_params, # explicit params to ->new
  72         %$params, # params from CLI
  73     );
  74 }
  75
  76 sub _getopt_spec { shift->_traditional_spec(@_); }
  77
  78 sub _parse_argv {
  79     my ( $class, %params ) = @_;
  80
  81     local @ARGV = @{ $params{params}{argv} || \@ARGV };
  82
  83     my ( $opt_spec, $name_to_init_arg ) = $class->_getopt_spec(%params);
  84
  85     # Get a clean copy of the original @ARGV
  86     my $argv_copy = [ @ARGV ];
  87
  88     my @warnings;
  89     my ( $parsed_options, $usage ) = eval {
  90         local $SIG{__WARN__} = sub { push @warnings, @_ };
  91
  92         return $class->_getopt_get_options(\%params, $opt_spec);
  93     };
  94
  95     $class->_getopt_spec_warnings(@warnings) if @warnings;
  96     $class->_getopt_spec_exception(\@warnings, $@) if $@;
  97
  98     # Get a copy of the Getopt::Long-mangled @ARGV
  99     my $argv_mangled = [ @ARGV ];
 100
 101     my %constructor_args = (
 102         map {
 103             $name_to_init_arg->{$_} => $parsed_options->{$_}
 104         } keys %$parsed_options,
 105     );
 106
 107     return (
 108         params    => \%constructor_args,
 109         argv_copy => $argv_copy,
 110         argv      => $argv_mangled,
 111         ( defined($usage) ? ( usage => $usage ) : () ),
 112     );
 113 }
 114
 115 sub _getopt_get_options {
 116     my ($class, $params, $opt_spec) = @_;
 117     my %options;
 118     Getopt::Long::GetOptions(\%options, @$opt_spec);
 119     return ( \%options, undef );
 120 }
 121
 122 sub _getopt_spec_warnings { }
 123
 124 sub _getopt_spec_exception {
 125     my ($self, $warnings, $exception) = @_;
 126     die @$warnings, $exception;
 127 }
 128
 129 sub _getopt_full_usage {
 130     my ($self, $usage) = @_;
 131     $usage->die;
 132 }
 133
 134 sub _usage_format {
 135     return "usage: %c %o";
 136 }
 137
 138 sub _traditional_spec {
 139     my ( $class, %params ) = @_;
 140
 141     my ( @options, %name_to_init_arg, %options );
 142
 143     foreach my $opt ( @{ $params{options} } ) {
 144         push @options, $opt->{opt_string};
 145
 146         my $identifier = $opt->{name};
 147         $identifier =~ s/\W/_/g; # Getopt::Long does this to all option names
 148
 149         $name_to_init_arg{$identifier} = $opt->{init_arg};
 150     }
 151
 152     return ( \@options, \%name_to_init_arg );
 153 }
 154
 155 sub _compute_getopt_attrs {
 156     my $class = shift;
 157     grep {
 158         $_->does("MooseX::Getopt::Meta::Attribute::Trait")
 159             or
 160         $_->name !~ /^_/
 161     } grep {
 162         !$_->does('MooseX::Getopt::Meta::Attribute::Trait::NoGetopt')
 163     } $class->meta->get_all_attributes
 164 }
 165
 166 sub _get_cmd_flags_for_attr {
 167     my ( $class, $attr ) = @_;
 168
 169     my $flag = $attr->name;
 170
 171     my @aliases;
 172
 173     if ($attr->does('MooseX::Getopt::Meta::Attribute::Trait')) {
 174         $flag = $attr->cmd_flag if $attr->has_cmd_flag;
 175         @aliases = @{ $attr->cmd_aliases } if $attr->has_cmd_aliases;
 176     }
 177
 178     return ( $flag, @aliases );
 179 }
 180
 181 sub _attrs_to_options {
 182     my $class = shift;
 183     my $config_from_file = shift || {};
 184
 185     my @options;
 186
 187     foreach my $attr ($class->_compute_getopt_attrs) {
 188         my ( $flag, @aliases ) = $class->_get_cmd_flags_for_attr($attr);
 189
 190         my $opt_string = join(q{|}, $flag, @aliases);
 191
 192         if ($attr->name eq 'configfile') {
 193             $opt_string .= '=s';
 194         }
 195         elsif ($attr->has_type_constraint) {
 196             my $type = $attr->type_constraint;
 197             if (MooseX::Getopt::OptionTypeMap->has_option_type($type)) {
 198                 $opt_string .= MooseX::Getopt::OptionTypeMap->get_option_type($type)
 199             }
 200         }
 201
 202         push @options, {
 203             name       => $flag,
 204             init_arg   => $attr->init_arg,
 205             opt_string => $opt_string,
 206             required   => $attr->is_required && !$attr->has_default && !$attr->has_builder && !exists $config_from_file->{$attr->name},
 207             # NOTE:
 208             # this "feature" was breaking because
 209             # Getopt::Long::Descriptive would return
 210             # the default value as if it was a command
 211             # line flag, which would then override the
 212             # one passed into a constructor.
 213             # See 100_gld_default_bug.t for an example
 214             # - SL
 215             #( ( $attr->has_default && ( $attr->is_default_a_coderef xor $attr->is_lazy ) ) ? ( default => $attr->default({}) ) : () ),
 216             ( $attr->has_documentation ? ( doc => $attr->documentation ) : () ),
 217         }
 218     }
 219
 220     return @options;
 221 }
 222
 223 no Moose::Role; 1;
 224
 225 __END__
 226
 227 =pod
 228
 229 =head1 NAME
 230
 231 MooseX::Getopt::Basic - role to implement the Getopt::Long functionality
 232
 233 =head1 SYNOPSIS
 234
 235   ## In your class
 236   package My::App;
 237   use Moose;
 238
 239   with 'MooseX::Getopt::Basic';
 240
 241   has 'out' => (is => 'rw', isa => 'Str', required => 1);
 242   has 'in'  => (is => 'rw', isa => 'Str', required => 1);
 243
 244   # ... rest of the class here
 245
 246   ## in your script
 247   #!/usr/bin/perl
 248
 249   use My::App;
 250
 251   my $app = My::App->new_with_options();
 252   # ... rest of the script here
 253
 254   ## on the command line
 255   % perl my_app_script.pl --in file.input --out file.dump
 256
 257 =head1 DESCRIPTION
 258
 259 This is like L<MooseX::Getopt> and can be used instead except that it
 260 doesn't make use of L<Getopt::Long::Descriptive> (or "GLD" for short).
 261
 262 =head1 METHODS
 263
 264 =head2 new_with_options
 265
 266 See L<MooseX::Getopt/new_with_options>.
 267
 268 =head1 COPYRIGHT AND LICENSE
 269
 270 Copyright 2007-2008 by Infinity Interactive, Inc.
 271
 272 L<http://www.iinteractive.com>
 273
 274 This library is free software; you can redistribute it and/or modify
 275 it under the same terms as Perl itself.
 276
 277 =cut
 278