lib/MooseX/Getopt.pm

   1
   2 package MooseX::Getopt;
   3 use Moose::Role;
   4
   5 use Moose::Util::TypeConstraints;
   6
   7 use MooseX::Getopt::OptionTypeMap;
   8
   9 use MooseX::Getopt::Session;
  10
  11 use MooseX::Getopt::Meta::Attribute;
  12 use MooseX::Getopt::Meta::Attribute::NoGetopt;
  13
  14
  15 our $VERSION   = '0.15';
  16 our $AUTHORITY = 'cpan:STEVAN';
  17
  18
  19 use constant _default_getopt_session => 'MooseX::Getopt::Session';
  20
  21
  22 has getopt => (
  23     is => 'rw',
  24     isa => 'MooseX::Getopt::Session',
  25     metaclass => 'NoGetopt',
  26     handles => [ 'ARGV', 'extra_argv' ],
  27 );
  28
  29
  30 sub new_with_options {
  31     my $class = shift;
  32
  33     Moose->throw_error("Single parameters to new_with_options() must be a HASH ref")
  34         if ref $_[0] and ref $_ ne 'HASH';
  35
  36     my %params = ( @_ == 1 ? %{ $_[0] } : @_ );
  37
  38     my $getopt = defined $params{getopt}
  39                  ? $params{getopt}
  40                  : $class->_default_getopt_session->new(
  41                        classes_filter => sub { $_ eq $class },
  42                        params => \%params,
  43                    );
  44
  45     $class->new(
  46         getopt     => $getopt,
  47         %{ $getopt->params },                   # params from session object
  48         %params,                                # explicit params to ->new
  49         %{ $getopt->options },                  # params from CLI
  50     );
  51 };
  52
  53
  54 sub _compute_getopt_attrs {
  55     my $class = shift;
  56
  57     return grep {
  58         $_->does('MooseX::Getopt::Meta::Attribute::Trait')
  59             or
  60         $_->name !~ /^_/
  61     } grep {
  62         !$_->does('MooseX::Getopt::Meta::Attribute::Trait::NoGetopt')
  63     } $class->meta->compute_all_applicable_attributes;
  64 };
  65
  66
  67 no Moose::Role; 1;
  68
  69 __END__
  70
  71 =pod
  72
  73 =head1 NAME
  74
  75 MooseX::Getopt - A Moose role for processing command line options
  76
  77 =head1 SYNOPSIS
  78
  79   ## In your class
  80   package My::App;
  81   use Moose;
  82
  83   with 'MooseX::Getopt';
  84
  85   has 'out' => (is => 'rw', isa => 'Str', required => 1);
  86   has 'in'  => (is => 'rw', isa => 'Str', required => 1);
  87
  88   # ... rest of the class here
  89
  90   ## in your script
  91   #!/usr/bin/perl
  92
  93   use My::App;
  94
  95   my $app = My::App->new_with_options();
  96   # ... rest of the script here
  97
  98   ## on the command line
  99   % perl my_app_script.pl -in file.input -out file.dump
 100
 101 =head1 DESCRIPTION
 102
 103 This is a role which provides an alternate constructor for creating
 104 objects using parameters passed in from the command line.
 105
 106 This module attempts to DWIM as much as possible with the command line
 107 params by introspecting your class's attributes. It will use the name
 108 of your attribute as the command line option, and if there is a type
 109 constraint defined, it will configure Getopt::Long to handle the option
 110 accordingly.
 111
 112 You can use the trait L<MooseX::Getopt::Meta::Attribute::Trait> or the
 113 attribute metaclass L<MooseX::Getopt::Meta::Attribute> to get non-default
 114 commandline option names and aliases.
 115
 116 You can use the trait L<MooseX::Getopt::Meta::Attribute::Trait::NoGetopt>
 117 or the attribute metaclass L<MooseX::Getopt::Meta::Attribute::NoGetopt>
 118 to have C<MooseX::Getopt> ignore your attribute in the commandline options.
 119
 120 By default, attributes which start with an underscore are not given
 121 commandline argument support, unless the attribute's metaclass is set
 122 to L<MooseX::Getopt::Meta::Attribute>. If you don't want you accessors
 123 to have the leading underscore in thier name, you can do this:
 124
 125   # for read/write attributes
 126   has '_foo' => (accessor => 'foo', ...);
 127
 128   # or for read-only attributes
 129   has '_bar' => (reader => 'bar', ...);
 130
 131 This will mean that Getopt will not handle a --foo param, but your
 132 code can still call the C<foo> method.
 133
 134 If your class also uses a configfile-loading role based on
 135 L<MooseX::ConfigFromFile>, such as L<MooseX::SimpleConfig>,
 136 L<MooseX::Getopt>'s C<new_with_options> will load the configfile
 137 specified by the C<--configfile> option (or the default you've
 138 given for the configfile attribute) for you.
 139
 140 Options specified in multiple places follow the following
 141 precendence order: commandline overrides configfile, which
 142 overrides explicit new_with_options parameters.
 143
 144 =head2 Supported Type Constraints
 145
 146 =over 4
 147
 148 =item I<Bool>
 149
 150 A I<Bool> type constraint is set up as a boolean option with
 151 Getopt::Long. So that this attribute description:
 152
 153   has 'verbose' => (is => 'rw', isa => 'Bool');
 154
 155 would translate into C<verbose!> as a Getopt::Long option descriptor,
 156 which would enable the following command line options:
 157
 158   % my_script.pl --verbose
 159   % my_script.pl --noverbose
 160
 161 =item I<Int>, I<Float>, I<Str>
 162
 163 These type constraints are set up as properly typed options with
 164 Getopt::Long, using the C<=i>, C<=f> and C<=s> modifiers as appropriate.
 165
 166 =item I<ArrayRef>
 167
 168 An I<ArrayRef> type constraint is set up as a multiple value option
 169 in Getopt::Long. So that this attribute description:
 170
 171   has 'include' => (
 172       is      => 'rw',
 173       isa     => 'ArrayRef',
 174       default => sub { [] }
 175   );
 176
 177 would translate into C<includes=s@> as a Getopt::Long option descriptor,
 178 which would enable the following command line options:
 179
 180   % my_script.pl --include /usr/lib --include /usr/local/lib
 181
 182 =item I<HashRef>
 183
 184 A I<HashRef> type constraint is set up as a hash value option
 185 in Getopt::Long. So that this attribute description:
 186
 187   has 'define' => (
 188       is      => 'rw',
 189       isa     => 'HashRef',
 190       default => sub { {} }
 191   );
 192
 193 would translate into C<define=s%> as a Getopt::Long option descriptor,
 194 which would enable the following command line options:
 195
 196   % my_script.pl --define os=linux --define vendor=debian
 197
 198 =back
 199
 200 =head2 Custom Type Constraints
 201
 202 It is possible to create custom type constraint to option spec
 203 mappings if you need them. The process is fairly simple (but a
 204 little verbose maybe). First you create a custom subtype, like
 205 so:
 206
 207   subtype 'ArrayOfInts'
 208       => as 'ArrayRef'
 209       => where { scalar (grep { looks_like_number($_) } @$_)  };
 210
 211 Then you register the mapping, like so:
 212
 213   MooseX::Getopt::OptionTypeMap->add_option_type_to_map(
 214       'ArrayOfInts' => '=i@'
 215   );
 216
 217 Now any attribute declarations using this type constraint will
 218 get the custom option spec. So that, this:
 219
 220   has 'nums' => (
 221       is      => 'ro',
 222       isa     => 'ArrayOfInts',
 223       default => sub { [0] }
 224   );
 225
 226 Will translate to the following on the command line:
 227
 228   % my_script.pl --nums 5 --nums 88 --nums 199
 229
 230 This example is fairly trivial, but more complex validations are
 231 easily possible with a little creativity. The trick is balancing
 232 the type constraint validations with the Getopt::Long validations.
 233
 234 Better examples are certainly welcome :)
 235
 236 =head2 Inferred Type Constraints
 237
 238 If you define a custom subtype which is a subtype of one of the
 239 standard L</Supported Type Constraints> above, and do not explicitly
 240 provide custom support as in L</Custom Type Constraints> above,
 241 MooseX::Getopt will treat it like the parent type for Getopt
 242 purposes.
 243
 244 For example, if you had the same custom C<ArrayOfInts> subtype
 245 from the examples above, but did not add a new custom option
 246 type for it to the C<OptionTypeMap>, it would be treated just
 247 like a normal C<ArrayRef> type for Getopt purposes (that is,
 248 C<=s@>).
 249
 250 =head2 Session
 251
 252 L<MooseX::Getopt> can handle more than one class which contain
 253 attributes filled from CLI.  In this case, you need to use explicite
 254 L<MooseX::Getopt::Session> object and then the Getopt attributes will be
 255 searched in any class which does L<MooseX::Getopt>.
 256
 257   package My::App;
 258   use Moose;
 259   with 'MooseX::Getopt';
 260   has 'send' => (is => 'rw', predicate => 'has_send');
 261
 262   package My::App::Send;
 263   use Moose;
 264   with 'MooseX::Getopt';
 265   has 'to' => (is => 'rw', isa => 'Str', default => 'localhost');
 266   sub send { my $self = shift; warn "Sending mail to ", $self->to; }
 267
 268   # ... rest of the class here
 269
 270   ## in your script
 271   #!/usr/bin/perl
 272
 273   my $getopt = MooseX::Getopt::Session->new;
 274
 275   my $app = My::App->new_with_options( getopt => $getopt );
 276   if ($app->has_send) {
 277       # Use the same command line
 278       my $sender = My::App::Send->new_with_options( getopt => $getopt );
 279       $sender->send;
 280   }
 281   # ... rest of the script here
 282
 283   ## on the command line
 284   % perl my_app_script.pl --send --to server.example.net
 285
 286 =head1 METHODS
 287
 288 =over 4
 289
 290 =item B<new_with_options (%params)>
 291
 292 This method will take a set of default C<%params> and then collect
 293 params from the command line (possibly overriding those in C<%params>)
 294 and then return a newly constructed object.
 295
 296 If L<Getopt::Long/GetOptions> fails (due to invalid arguments),
 297 C<new_with_options> will throw an exception.
 298
 299 If you have L<Getopt::Long::Descriptive> a the C<usage> param is also passed to
 300 C<new>.
 301
 302 =item B<ARGV>
 303
 304 This accessor contains a reference to a copy of the C<@ARGV> array as it
 305 originally existed at the time of C<new_with_options>.
 306
 307 The C<ARGV> is delegated from L<MooseX::Getopt::Session> object.
 308
 309 =item B<extra_argv>
 310
 311 This accessor contains an arrayref of leftover C<@ARGV> elements that
 312 L<Getopt::Long> did not parse.  Note that the real C<@ARGV> is left
 313 un-mangled.
 314
 315 The C<extra_argv> is delegated from L<MooseX::Getopt::Session> object.
 316
 317 =item B<getopt>
 318
 319 This accessor contains a L<MooseX::Getopt::Session> object.  This object can
 320 be shared between more than one class which does L<MooseX::Getopt>.  The new
 321 object is created by default.
 322
 323 =item B<meta>
 324
 325 This returns the role meta object.
 326
 327 =back
 328
 329 =head1 SEE ALSO
 330
 331 =over 4
 332
 333 =item L<MooseX::Getopt::Strict>
 334
 335 =item L<MooseX::Getopt::Session>
 336
 337 =item L<MooseX::Getopt::Parser>
 338
 339 =back
 340
 341 =head1 BUGS
 342
 343 All complex software has bugs lurking in it, and this module is no
 344 exception. If you find a bug please either email me, or add the bug
 345 to cpan-RT.
 346
 347 =head1 AUTHOR
 348
 349 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 350
 351 Brandon L. Black, E<lt>blblack@gmail.comE<gt>
 352
 353 Yuval Kogman, E<lt>nothingmuch@woobling.orgE<gt>
 354
 355 =head1 CONTRIBUTORS
 356
 357 Ryan D Johnson, E<lt>ryan@innerfence.comE<gt>
 358
 359 Piotr Roszatycki, E<lt>dexter@cpan.orgE<gt>
 360
 361 =head1 COPYRIGHT AND LICENSE
 362
 363 Copyright 2007-2008 by Infinity Interactive, Inc.
 364
 365 L<http://www.iinteractive.com>
 366
 367 This library is free software; you can redistribute it and/or modify
 368 it under the same terms as Perl itself.
 369
 370 =cut