* MooseX::Getopt: ARGV and extra_argv are deletaged from MooseX::Getopt::Session.

[gitmo/MooseX-Getopt.git] / t / 004_nogetop.t

#!/usr/bin/perl

use strict;
use warnings;

use Test::More tests => 34;
use Test::Exception;

BEGIN {
    use_ok('MooseX::Getopt');
}

{
    package App;
    use Moose;

    with 'MooseX::Getopt';

    has 'data' => (
        metaclass => 'Getopt',
        is        => 'ro',
        isa       => 'Str',
        default   => 'file.dat',
        cmd_flag  => 'f',
    );

    has 'cow' => (
        metaclass   => 'Getopt',
        is          => 'ro',
        isa         => 'Str',
        default     => 'moo',
        cmd_aliases => [qw/ moocow m c /],
    );

    has 'horse' => (
        metaclass   => 'Getopt',
        is          => 'ro',
        isa         => 'Str',
        default     => 'bray',
        cmd_flag    => 'horsey',
        cmd_aliases => 'x',
    );

    has 'length' => (
        is      => 'ro',
        isa     => 'Int',
        default => 24
    );

    has 'verbose' => (
        is  => 'ro',
        isa => 'Bool',
    );

    has 'libs' => (
        is      => 'ro',
        isa     => 'ArrayRef',
        default => sub { [] },
    );

    has 'details' => (
        is      => 'ro',
        isa     => 'HashRef',
        default => sub { {} },
    );

    has 'private_stuff' => (
        metaclass => 'NoGetopt',
        is       => 'ro',
        isa      => 'Int',
        default  => 713
    );

    has '_private_stuff_cmdline' => (
        metaclass => 'Getopt',
        is        => 'ro',
        isa       => 'Int',
        default   => 832,
        cmd_flag  => 'p',
    );

}

foreach my $parser_name (qw(MooseX::Getopt::Parser::Long MooseX::Getopt::Parser::Descriptive MooseX::Getopt::Parser::Default)) {
    SKIP: {
        if ($parser_name eq 'MooseX::Getopt::Parser::Descriptive') {
            eval { require Getopt::Long::Descriptive };
            skip "Getopt::Long::Descriptive not installed", 11 if $@;
        }

        {
            local @ARGV = ();

            my $parser = $parser_name->new;
            ok(ref($parser) =~ /^MooseX::Getopt::Parser::/, '... parser object is created');

            my $getopt = MooseX::Getopt::Session->new( parser => $parser );
            isa_ok($getopt, 'MooseX::Getopt::Session');

            my $app = App->new_with_options( getopt => $getopt );
            isa_ok( $app, 'App' );

            ok( !$app->verbose, '... verbosity is off as expected' );
            is( $app->length, 24,         '... length is 24 as expected' );
            is( $app->data,   'file.dat', '... data is file.dat as expected' );
            is_deeply( $app->libs, [], '... libs is [] as expected' );
            is_deeply( $app->details, {}, '... details is {} as expected' );
            is($app->private_stuff, 713, '... private stuff is 713 as expected');
        }

        {
            local @ARGV = (qw/--private_stuff 317/);

            throws_ok {
                my $parser = $parser_name->new;
                ok(ref($parser) =~ /^MooseX::Getopt::Parser::/, '... parser object is created');

                my $getopt = MooseX::Getopt::Session->new( parser => $parser );
                isa_ok($getopt, 'MooseX::Getopt::Session');

                App->new_with_options( getopt => $getopt )
            } qr/Unknown option: private_stuff/;
        }

    }
}