* MooseX::Getopt: _get_options_from_configfile renamed to get_options_from_configfile.

[gitmo/MooseX-Getopt.git] / lib / MooseX / Getopt.pm

package MooseX::Getopt;
use Moose::Role;

use Moose::Util::TypeConstraints;

use MooseX::Getopt::OptionTypeMap;

use MooseX::Getopt::Session;

use MooseX::Getopt::Meta::Attribute;
use MooseX::Getopt::Meta::Attribute::NoGetopt;


our $VERSION   = '0.15';
our $AUTHORITY = 'cpan:STEVAN';


use constant _default_getopt_session => 'MooseX::Getopt::Session';


has getopt => (
    is => 'rw',
    isa => 'MooseX::Getopt::Session',
    metaclass => 'NoGetopt',
    handles => [ 'ARGV', 'extra_argv' ],
);


sub new_with_options {
    my $class = shift;

    return $class->new( $class->get_options_from_argv(@_) );
};


sub get_options_from_argv {
    my $class = shift;

    Moose->throw_error("Single parameters to get_options_from_argv() must be a HASH ref")
        if ref $_[0] and ref $_ ne 'HASH';

    my $options = { %{ $class->get_options_from_configfile }, @_ == 1 ? %{ $_[0] } : @_ };

    my $getopt = defined $options->{getopt}
                 ? $options->{getopt}
                 : $class->_default_getopt_session->new(
                       classes_filter => sub { $_ eq $class },
                       options => $options,
                   );

    my $new_options = {
        %{ $options },                          # explicit options to ->new
        %{ $getopt->options },                  # options from CLI
        getopt => $getopt,
    };

    return $new_options;
};


sub get_options_from_configfile {
    my $class = shift;

    my $options = {};

    if ($class->meta->does_role('MooseX::ConfigFromFile')) {
        local @ARGV = @ARGV;

        my $configfile;
        my $opt_parser = Getopt::Long::Parser->new( config => [ 'pass_through' ] );
        $opt_parser->getoptions( "configfile=s" => \$configfile );

        if (not defined $configfile) {
            my $cfmeta = $class->meta->find_attribute_by_name('configfile');
            $configfile = $cfmeta->default if $cfmeta->has_default;
        };

        if (defined $configfile) {
            $options = $class->get_config_from_file($configfile);
        };
    };

    return $options;
};


sub _compute_getopt_attrs {
    my $class = shift;

    return grep {
        $_->does('MooseX::Getopt::Meta::Attribute::Trait')
            or
        $_->name !~ /^_/
    } grep {
        !$_->does('MooseX::Getopt::Meta::Attribute::Trait::NoGetopt')
    } $class->meta->compute_all_applicable_attributes;
};


no Moose::Role; 1;

__END__

=pod

=head1 NAME

MooseX::Getopt - A Moose role for processing command line options

=head1 SYNOPSIS

  ## In your class
  package My::App;
  use Moose;

  with 'MooseX::Getopt';

  has 'out' => (is => 'rw', isa => 'Str', required => 1);
  has 'in'  => (is => 'rw', isa => 'Str', required => 1);

  # ... rest of the class here

  ## in your script
  #!/usr/bin/perl

  use My::App;

  my $app = My::App->new_with_options();
  # ... rest of the script here

  ## on the command line
  % perl my_app_script.pl -in file.input -out file.dump

=head1 DESCRIPTION

This is a role which provides an alternate constructor for creating
objects using parameters passed in from the command line.

This module attempts to DWIM as much as possible with the command line
params by introspecting your class's attributes. It will use the name
of your attribute as the command line option, and if there is a type
constraint defined, it will configure Getopt::Long to handle the option
accordingly.

You can use the trait L<MooseX::Getopt::Meta::Attribute::Trait> or the
attribute metaclass L<MooseX::Getopt::Meta::Attribute> to get non-default
commandline option names and aliases.

You can use the trait L<MooseX::Getopt::Meta::Attribute::Trait::NoGetopt>
or the attribute metaclass L<MooseX::Getopt::Meta::Attribute::NoGetopt>
to have C<MooseX::Getopt> ignore your attribute in the commandline options.

By default, attributes which start with an underscore are not given
commandline argument support, unless the attribute's metaclass is set
to L<MooseX::Getopt::Meta::Attribute>. If you don't want you accessors
to have the leading underscore in thier name, you can do this:

  # for read/write attributes
  has '_foo' => (accessor => 'foo', ...);

  # or for read-only attributes
  has '_bar' => (reader => 'bar', ...);

This will mean that Getopt will not handle a --foo param, but your
code can still call the C<foo> method.

If your class also uses a configfile-loading role based on
L<MooseX::ConfigFromFile>, such as L<MooseX::SimpleConfig>,
L<MooseX::Getopt>'s C<new_with_options> will load the configfile
specified by the C<--configfile> option (or the default you've
given for the configfile attribute) for you.

Options specified in multiple places follow the following
precendence order: commandline overrides configfile, which
overrides explicit new_with_options parameters.

=head2 Supported Type Constraints

=over 4

=item I<Bool>

A I<Bool> type constraint is set up as a boolean option with
Getopt::Long. So that this attribute description:

  has 'verbose' => (is => 'rw', isa => 'Bool');

would translate into C<verbose!> as a Getopt::Long option descriptor,
which would enable the following command line options:

  % my_script.pl --verbose
  % my_script.pl --noverbose

=item I<Int>, I<Float>, I<Str>

These type constraints are set up as properly typed options with
Getopt::Long, using the C<=i>, C<=f> and C<=s> modifiers as appropriate.

=item I<ArrayRef>

An I<ArrayRef> type constraint is set up as a multiple value option
in Getopt::Long. So that this attribute description:

  has 'include' => (
      is      => 'rw',
      isa     => 'ArrayRef',
      default => sub { [] }
  );

would translate into C<includes=s@> as a Getopt::Long option descriptor,
which would enable the following command line options:

  % my_script.pl --include /usr/lib --include /usr/local/lib

=item I<HashRef>

A I<HashRef> type constraint is set up as a hash value option
in Getopt::Long. So that this attribute description:

  has 'define' => (
      is      => 'rw',
      isa     => 'HashRef',
      default => sub { {} }
  );

would translate into C<define=s%> as a Getopt::Long option descriptor,
which would enable the following command line options:

  % my_script.pl --define os=linux --define vendor=debian

=back

=head2 Custom Type Constraints

It is possible to create custom type constraint to option spec
mappings if you need them. The process is fairly simple (but a
little verbose maybe). First you create a custom subtype, like
so:

  subtype 'ArrayOfInts'
      => as 'ArrayRef'
      => where { scalar (grep { looks_like_number($_) } @$_)  };

Then you register the mapping, like so:

  MooseX::Getopt::OptionTypeMap->add_option_type_to_map(
      'ArrayOfInts' => '=i@'
  );

Now any attribute declarations using this type constraint will
get the custom option spec. So that, this:

  has 'nums' => (
      is      => 'ro',
      isa     => 'ArrayOfInts',
      default => sub { [0] }
  );

Will translate to the following on the command line:

  % my_script.pl --nums 5 --nums 88 --nums 199

This example is fairly trivial, but more complex validations are
easily possible with a little creativity. The trick is balancing
the type constraint validations with the Getopt::Long validations.

Better examples are certainly welcome :)

=head2 Inferred Type Constraints

If you define a custom subtype which is a subtype of one of the
standard L</Supported Type Constraints> above, and do not explicitly
provide custom support as in L</Custom Type Constraints> above,
MooseX::Getopt will treat it like the parent type for Getopt
purposes.

For example, if you had the same custom C<ArrayOfInts> subtype
from the examples above, but did not add a new custom option
type for it to the C<OptionTypeMap>, it would be treated just
like a normal C<ArrayRef> type for Getopt purposes (that is,
C<=s@>).

=head2 Session

L<MooseX::Getopt> can handle more than one class which contain
attributes filled from CLI.  In this case, you need to use explicite
L<MooseX::Getopt::Session> object and then the Getopt attributes will be
searched in any class which does L<MooseX::Getopt>.

  package My::App;
  use Moose;
  with 'MooseX::Getopt';
  has 'send' => (is => 'rw', predicate => 'has_send');

  package My::App::Send;
  use Moose;
  with 'MooseX::Getopt';
  has 'to' => (is => 'rw', isa => 'Str', default => 'localhost');
  sub send { my $self = shift; warn "Sending mail to ", $self->to; }

  # ... rest of the class here

  ## in your script
  #!/usr/bin/perl

  my $getopt = MooseX::Getopt::Session->new;

  my $app = My::App->new_with_options( getopt => $getopt );
  if ($app->has_send) {
      # Use the same command line
      my $sender = My::App::Send->new_with_options( getopt => $getopt );
      $sender->send;
  }
  # ... rest of the script here

  ## on the command line
  % perl my_app_script.pl --send --to server.example.net

=head1 METHODS

=over 4

=item B<new_with_options (%params)>

This method will take a set of default C<%params> and then collect
params from the command line (possibly overriding those in C<%params>)
and then return a newly constructed object.

If L<Getopt::Long/GetOptions> fails (due to invalid arguments),
C<new_with_options> will throw an exception.

If you have L<Getopt::Long::Descriptive> a the C<usage> param is also passed to
C<new>.

=item B<get_options_from_argv (%params)>

This method returns the list of parameters collected from command line
without creating the new object.

=item B<get_options_from_configfile>

This method returns the list of parameters collected with
L<MooseX::ConfigFromFile> mechanism.

=item B<ARGV>

This accessor contains a reference to a copy of the C<@ARGV> array as it
originally existed at the time of C<new_with_options>.

The C<ARGV> is delegated from L<MooseX::Getopt::Session> object.

=item B<extra_argv>

This accessor contains an arrayref of leftover C<@ARGV> elements that
L<Getopt::Long> did not parse.  Note that the real C<@ARGV> is left
un-mangled.

The C<extra_argv> is delegated from L<MooseX::Getopt::Session> object.

=item B<getopt>

This accessor contains a L<MooseX::Getopt::Session> object.  This object can
be shared between more than one class which does L<MooseX::Getopt>.  The new
object is created by default.

=item B<meta>

This returns the role meta object.

=back

=head1 SEE ALSO

=over 4

=item L<MooseX::Getopt::Strict>

=item L<MooseX::Getopt::Session>

=item L<MooseX::Getopt::Parser>

=back

=head1 BUGS

All complex software has bugs lurking in it, and this module is no
exception. If you find a bug please either email me, or add the bug
to cpan-RT.

=head1 AUTHOR

Stevan Little E<lt>stevan@iinteractive.comE<gt>

Brandon L. Black, E<lt>blblack@gmail.comE<gt>

Yuval Kogman, E<lt>nothingmuch@woobling.orgE<gt>

=head1 CONTRIBUTORS

Ryan D Johnson, E<lt>ryan@innerfence.comE<gt>

Piotr Roszatycki, E<lt>dexter@cpan.orgE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright 2007-2008 by Infinity Interactive, Inc.

L<http://www.iinteractive.com>

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.

=cut