lib/MooseX/ClassAttribute.pm

   1 package MooseX::ClassAttribute;
   2
   3 use strict;
   4 use warnings;
   5
   6 our $VERSION = '0.05';
   7 our $AUTHORITY = 'cpan:DROLSKY';
   8
   9 use Moose ();
  10 use Moose::Exporter;
  11 use MooseX::ClassAttribute::Role::Meta::Class;
  12 use MooseX::ClassAttribute::Role::Meta::Attribute;
  13
  14 Moose::Exporter->setup_import_methods
  15     ( with_caller => [ 'class_has' ] );
  16
  17
  18 sub init_meta
  19 {
  20     shift;
  21     my %p = @_;
  22
  23     Moose->init_meta(%p);
  24
  25     return
  26         Moose::Util::MetaRole::apply_metaclass_roles
  27             ( for_class       => $p{for_class},
  28               metaclass_roles => [ 'MooseX::ClassAttribute::Role::Meta::Class' ],
  29             );
  30 }
  31
  32 sub class_has
  33 {
  34     my $caller  = shift;
  35     my $name    = shift;
  36     my %options = @_;
  37
  38     my $attrs = ref $name eq 'ARRAY' ? $name : [$name];
  39
  40     Class::MOP::Class
  41             ->initialize($caller)
  42             ->add_class_attribute( $_, %options )
  43                 for @{ $attrs };
  44 }
  45
  46 1;
  47
  48 __END__
  49
  50 =pod
  51
  52 =head1 NAME
  53
  54 MooseX::ClassAttribute - Declare class attributes Moose-style
  55
  56 =head1 SYNOPSIS
  57
  58     package My::Class;
  59
  60     use Moose;
  61     use MooseX::ClassAttribute;
  62
  63     class_has 'Cache' =>
  64         ( is      => 'rw',
  65           isa     => 'HashRef',
  66           default => sub { {} },
  67         );
  68
  69     __PACKAGE__->meta()->make_immutable();
  70
  71     no Moose;
  72     no MooseX::ClassAttribute;
  73
  74     # then later ...
  75
  76     My::Class->Cache()->{thing} = ...;
  77
  78
  79 =head1 DESCRIPTION
  80
  81 This module allows you to declare class attributes in exactly the same
  82 way as object attributes, using C<class_has()> instead of C<has()>.
  83
  84 You can use any feature of Moose's attribute declarations, including
  85 overriding a parent's attributes, delegation (C<handles>), and
  86 attribute metaclasses, and it should just work. The one exception is
  87 the "required" flag, which is not allowed for class attributes.
  88
  89 The accessor methods for class attribute may be called on the class
  90 directly, or on objects of that class. Passing a class attribute to
  91 the constructor will not set it.
  92
  93 =head1 FUNCTIONS
  94
  95 This class exports one function when you use it, C<class_has()>. This
  96 works exactly like Moose's C<has()>, but it declares class attributes.
  97
  98 One little nit is that if you include C<no Moose> in your class, you
  99 won't remove the C<class_has()> function. To do that you must include
 100 C<no MooseX::ClassAttribute> as well.
 101
 102 =head2 Implementation and Immutability
 103
 104 This module will add a role to your class's metaclass, See
 105 L<MooseX::ClassAttribute::Role::Meta::Class> for details. This role
 106 provides introspection methods for class attributes.
 107
 108 Class attributes themselves do the
 109 L<MooseX::ClassAttribute::Role::Meta::Attribute> role.
 110
 111 There is also a L<MooseX::ClassAttribute::Meta::Method::Accessor>
 112 which provides part of the inlining implementation for class
 113 attributes.
 114
 115 =head2 Cooperation with Metaclasses and Traits
 116
 117 This module should work with most attribute metaclasses and traits,
 118 but it's possible that conflicts could occur. This module has been
 119 tested to work with C<MooseX::AttributeHelpers>.
 120
 121 =head1 AUTHOR
 122
 123 Dave Rolsky, C<< <autarch@urth.org> >>
 124
 125 =head1 BUGS
 126
 127 Please report any bugs or feature requests to
 128 C<bug-moosex-classattribute@rt.cpan.org>, or through the web interface
 129 at L<http://rt.cpan.org>.  I will be notified, and then you'll
 130 automatically be notified of progress on your bug as I make changes.
 131
 132 =head1 COPYRIGHT & LICENSE
 133
 134 Copyright 2007-2008 Dave Rolsky, All Rights Reserved.
 135
 136 This program is free software; you can redistribute it and/or modify
 137 it under the same terms as Perl itself.
 138
 139 =cut