lib/MooseX/ClassAttribute.pm

   1 package MooseX::ClassAttribute;
   2
   3 use strict;
   4 use warnings;
   5
   6 our $VERSION = '0.07';
   7 our $AUTHORITY = 'cpan:DROLSKY';
   8
   9 use Moose ();
  10 use Moose::Exporter;
  11 use MooseX::ClassAttribute::Role::Meta::Class;
  12
  13 Moose::Exporter->setup_import_methods
  14     ( with_caller => [ 'class_has' ] );
  15
  16
  17 sub init_meta
  18 {
  19     shift;
  20     my %p = @_;
  21
  22     Moose->init_meta(%p);
  23
  24     return
  25         Moose::Util::MetaRole::apply_metaclass_roles
  26             ( for_class       => $p{for_class},
  27               metaclass_roles => [ 'MooseX::ClassAttribute::Role::Meta::Class' ],
  28             );
  29 }
  30
  31 sub class_has
  32 {
  33     my $caller  = shift;
  34     my $name    = shift;
  35     my %options = @_;
  36
  37     my $attrs = ref $name eq 'ARRAY' ? $name : [$name];
  38
  39     Class::MOP::Class
  40         ->initialize($caller)
  41         ->add_class_attribute( $_, %options )
  42             for @{ $attrs };
  43 }
  44
  45 1;
  46
  47 __END__
  48
  49 =pod
  50
  51 =head1 NAME
  52
  53 MooseX::ClassAttribute - Declare class attributes Moose-style
  54
  55 =head1 SYNOPSIS
  56
  57     package My::Class;
  58
  59     use Moose;
  60     use MooseX::ClassAttribute;
  61
  62     class_has 'Cache' =>
  63         ( is      => 'rw',
  64           isa     => 'HashRef',
  65           default => sub { {} },
  66         );
  67
  68     __PACKAGE__->meta()->make_immutable();
  69
  70     no Moose;
  71     no MooseX::ClassAttribute;
  72
  73     # then later ...
  74
  75     My::Class->Cache()->{thing} = ...;
  76
  77
  78 =head1 DESCRIPTION
  79
  80 This module allows you to declare class attributes in exactly the same
  81 way as object attributes, using C<class_has()> instead of C<has()>.
  82
  83 You can use any feature of Moose's attribute declarations, including
  84 overriding a parent's attributes, delegation (C<handles>), and
  85 attribute metaclasses, and it should just work. The one exception is
  86 the "required" flag, which is not allowed for class attributes.
  87
  88 The accessor methods for class attribute may be called on the class
  89 directly, or on objects of that class. Passing a class attribute to
  90 the constructor will not set it.
  91
  92 =head1 FUNCTIONS
  93
  94 This class exports one function when you use it, C<class_has()>. This
  95 works exactly like Moose's C<has()>, but it declares class attributes.
  96
  97 One little nit is that if you include C<no Moose> in your class, you
  98 won't remove the C<class_has()> function. To do that you must include
  99 C<no MooseX::ClassAttribute> as well.
 100
 101 =head2 Implementation and Immutability
 102
 103 This module will add a role to your class's metaclass, See
 104 L<MooseX::ClassAttribute::Role::Meta::Class> for details. This role
 105 provides introspection methods for class attributes.
 106
 107 Class attributes themselves do the
 108 L<MooseX::ClassAttribute::Role::Meta::Attribute> role.
 109
 110 There is also a L<MooseX::ClassAttribute::Meta::Method::Accessor>
 111 which provides part of the inlining implementation for class
 112 attributes.
 113
 114 =head2 Cooperation with Metaclasses and Traits
 115
 116 This module should work with most attribute metaclasses and traits,
 117 but it's possible that conflicts could occur. This module has been
 118 tested to work with C<MooseX::AttributeHelpers>.
 119
 120 =head1 DONATIONS
 121
 122 If you'd like to thank me for the work I've done on this module,
 123 please consider making a "donation" to me via PayPal. I spend a lot of
 124 free time creating free software, and would appreciate any support
 125 you'd care to offer.
 126
 127 Please note that B<I am not suggesting that you must do this> in order
 128 for me to continue working on this particular software. I will
 129 continue to do so, inasmuch as I have in the past, for as long as it
 130 interests me.
 131
 132 Similarly, a donation made in this way will probably not make me work
 133 on this software much more, unless I get so many donations that I can
 134 consider working on free software full time, which seems unlikely at
 135 best.
 136
 137 To donate, log into PayPal and send money to autarch@urth.org or use
 138 the button on this page:
 139 L<http://www.urth.org/~autarch/fs-donation.html>
 140
 141 =head1 AUTHOR
 142
 143 Dave Rolsky, C<< <autarch@urth.org> >>
 144
 145 =head1 BUGS
 146
 147 Please report any bugs or feature requests to
 148 C<bug-moosex-classattribute@rt.cpan.org>, or through the web interface
 149 at L<http://rt.cpan.org>.  I will be notified, and then you'll
 150 automatically be notified of progress on your bug as I make changes.
 151
 152 =head1 COPYRIGHT & LICENSE
 153
 154 Copyright 2007-2008 Dave Rolsky, All Rights Reserved.
 155
 156 This program is free software; you can redistribute it and/or modify
 157 it under the same terms as Perl itself.
 158
 159 =cut