lib/MooseX/ClassAttribute.pm

   1 package MooseX::ClassAttribute;
   2
   3 use strict;
   4 use warnings;
   5
   6 our $VERSION   = '0.13';
   7 our $AUTHORITY = 'cpan:DROLSKY';
   8
   9 use Moose 0.98 ();
  10 use Moose::Exporter;
  11 use MooseX::ClassAttribute::Trait::Class;
  12 use MooseX::ClassAttribute::Trait::Role;
  13 use MooseX::ClassAttribute::Trait::Application::ToClass;
  14 use MooseX::ClassAttribute::Trait::Application::ToRole;
  15
  16 Moose::Exporter->setup_import_methods(
  17     with_meta       => ['class_has'],
  18     class_metaroles => {
  19         class => ['MooseX::ClassAttribute::Trait::Class'],
  20     },
  21     role_metaroles => {
  22         role => ['MooseX::ClassAttribute::Trait::Role'],
  23         application_to_class =>
  24             ['MooseX::ClassAttribute::Trait::Application::ToClass'],
  25         application_to_role =>
  26             ['MooseX::ClassAttribute::Trait::Application::ToRole'],
  27     },
  28 );
  29
  30 sub class_has {
  31     my $meta    = shift;
  32     my $name    = shift;
  33     my %options = @_;
  34
  35     my $attrs = ref $name eq 'ARRAY' ? $name : [$name];
  36
  37     $meta->add_class_attribute( $_, %options ) for @{$attrs};
  38 }
  39
  40 1;
  41
  42 __END__
  43
  44 =pod
  45
  46 =head1 NAME
  47
  48 MooseX::ClassAttribute - Declare class attributes Moose-style
  49
  50 =head1 SYNOPSIS
  51
  52     package My::Class;
  53
  54     use Moose;
  55     use MooseX::ClassAttribute;
  56
  57     class_has 'Cache' =>
  58         ( is      => 'rw',
  59           isa     => 'HashRef',
  60           default => sub { {} },
  61         );
  62
  63     __PACKAGE__->meta()->make_immutable();
  64
  65     no Moose;
  66     no MooseX::ClassAttribute;
  67
  68     # then later ...
  69
  70     My::Class->Cache()->{thing} = ...;
  71
  72 =head1 DESCRIPTION
  73
  74 This module allows you to declare class attributes in exactly the same
  75 way as object attributes, using C<class_has()> instead of C<has()>.
  76
  77 You can use any feature of Moose's attribute declarations, including
  78 overriding a parent's attributes, delegation (C<handles>), attribute traits,
  79 etc. All features should just work. The one exception is the "required" flag,
  80 which is not allowed for class attributes.
  81
  82 The accessor methods for class attribute may be called on the class
  83 directly, or on objects of that class. Passing a class attribute to
  84 the constructor will not set that attribute.
  85
  86 =head1 FUNCTIONS
  87
  88 This class exports one function when you use it, C<class_has()>. This
  89 works exactly like Moose's C<has()>, but it declares class attributes.
  90
  91 One little nit is that if you include C<no Moose> in your class, you won't
  92 remove the C<class_has()> function. To do that you must include C<no
  93 MooseX::ClassAttribute> as well. Or you can just use L<namespace::autoclean>
  94 instead.
  95
  96 =head2 Implementation and Immutability
  97
  98 This module will add a role to your class's metaclass, See
  99 L<MooseX::ClassAttribute::Trait::Class> for details. This role
 100 provides introspection methods for class attributes.
 101
 102 Class attributes themselves do the
 103 L<MooseX::ClassAttribute::Trait::Attribute> role.
 104
 105 There is also a L<MooseX::ClassAttribute::Meta::Method::Accessor>
 106 which provides part of the inlining implementation for class
 107 attributes.
 108
 109 =head2 Cooperation with Metaclasses and Traits
 110
 111 This module should work with most attribute metaclasses and traits,
 112 but it's possible that conflicts could occur. This module has been
 113 tested to work with Moose's native traits.
 114
 115 =head2 Class Attributes in Roles
 116
 117 You can add a class attribute to a role. When that role is applied to a class,
 118 the class will have the relevant class attributes added. Note that attribute
 119 defaults will be calculated when the class attribute is composed into the
 120 class.
 121
 122 =head1 DONATIONS
 123
 124 If you'd like to thank me for the work I've done on this module,
 125 please consider making a "donation" to me via PayPal. I spend a lot of
 126 free time creating free software, and would appreciate any support
 127 you'd care to offer.
 128
 129 Please note that B<I am not suggesting that you must do this> in order
 130 for me to continue working on this particular software. I will
 131 continue to do so, inasmuch as I have in the past, for as long as it
 132 interests me.
 133
 134 Similarly, a donation made in this way will probably not make me work
 135 on this software much more, unless I get so many donations that I can
 136 consider working on free software full time, which seems unlikely at
 137 best.
 138
 139 To donate, log into PayPal and send money to autarch@urth.org or use
 140 the button on this page:
 141 L<http://www.urth.org/~autarch/fs-donation.html>
 142
 143 =head1 AUTHOR
 144
 145 Dave Rolsky, C<< <autarch@urth.org> >>
 146
 147 =head1 BUGS
 148
 149 Please report any bugs or feature requests to
 150 C<bug-moosex-classattribute@rt.cpan.org>, or through the web interface
 151 at L<http://rt.cpan.org>.  I will be notified, and then you'll
 152 automatically be notified of progress on your bug as I make changes.
 153
 154 =head1 COPYRIGHT & LICENSE
 155
 156 Copyright 2007-2010 Dave Rolsky, All Rights Reserved.
 157
 158 This program is free software; you can redistribute it and/or modify
 159 it under the same terms as Perl itself.
 160
 161 =cut