lib/MooseX/ClassAttribute.pm

   1 package MooseX::ClassAttribute;
   2
   3 use strict;
   4 use warnings;
   5
   6 our $VERSION   = '0.10';
   7 our $AUTHORITY = 'cpan:DROLSKY';
   8
   9 use Moose 0.89 ();
  10 use Moose::Exporter;
  11 use MooseX::ClassAttribute::Role::Meta::Class;
  12
  13 Moose::Exporter->setup_import_methods( with_meta => ['class_has'] );
  14
  15 sub init_meta {
  16     shift;
  17     my %p = @_;
  18
  19     return Moose::Util::MetaRole::apply_metaclass_roles(
  20         for             => $p{for_class},
  21         class_metaroles => {
  22             class => ['MooseX::ClassAttribute::Role::Meta::Class'],
  23         },
  24         role_metaroles => {
  25             role => ['MooseX::ClassAttribute::Role::Meta::Role'],
  26         },
  27     );
  28 }
  29
  30 sub class_has {
  31     my $meta    = shift;
  32     my $name    = shift;
  33     my %options = @_;
  34
  35     my $attrs = ref $name eq 'ARRAY' ? $name : [$name];
  36
  37     $meta->add_class_attribute( $_, %options ) for @{$attrs};
  38 }
  39
  40 1;
  41
  42 __END__
  43
  44 =pod
  45
  46 =head1 NAME
  47
  48 MooseX::ClassAttribute - Declare class attributes Moose-style
  49
  50 =head1 SYNOPSIS
  51
  52     package My::Class;
  53
  54     use Moose;
  55     use MooseX::ClassAttribute;
  56
  57     class_has 'Cache' =>
  58         ( is      => 'rw',
  59           isa     => 'HashRef',
  60           default => sub { {} },
  61         );
  62
  63     __PACKAGE__->meta()->make_immutable();
  64
  65     no Moose;
  66     no MooseX::ClassAttribute;
  67
  68     # then later ...
  69
  70     My::Class->Cache()->{thing} = ...;
  71
  72 =head1 DESCRIPTION
  73
  74 This module allows you to declare class attributes in exactly the same
  75 way as object attributes, using C<class_has()> instead of C<has()>.
  76
  77 You can use any feature of Moose's attribute declarations, including
  78 overriding a parent's attributes, delegation (C<handles>), and
  79 attribute metaclasses, and it should just work. The one exception is
  80 the "required" flag, which is not allowed for class attributes.
  81
  82 The accessor methods for class attribute may be called on the class
  83 directly, or on objects of that class. Passing a class attribute to
  84 the constructor will not set it.
  85
  86 =head1 FUNCTIONS
  87
  88 This class exports one function when you use it, C<class_has()>. This
  89 works exactly like Moose's C<has()>, but it declares class attributes.
  90
  91 One little nit is that if you include C<no Moose> in your class, you
  92 won't remove the C<class_has()> function. To do that you must include
  93 C<no MooseX::ClassAttribute> as well.
  94
  95 =head2 Implementation and Immutability
  96
  97 This module will add a role to your class's metaclass, See
  98 L<MooseX::ClassAttribute::Role::Meta::Class> for details. This role
  99 provides introspection methods for class attributes.
 100
 101 Class attributes themselves do the
 102 L<MooseX::ClassAttribute::Role::Meta::Attribute> role.
 103
 104 There is also a L<MooseX::ClassAttribute::Meta::Method::Accessor>
 105 which provides part of the inlining implementation for class
 106 attributes.
 107
 108 =head2 Cooperation with Metaclasses and Traits
 109
 110 This module should work with most attribute metaclasses and traits,
 111 but it's possible that conflicts could occur. This module has been
 112 tested to work with C<MooseX::AttributeHelpers>.
 113
 114 =head1 DONATIONS
 115
 116 If you'd like to thank me for the work I've done on this module,
 117 please consider making a "donation" to me via PayPal. I spend a lot of
 118 free time creating free software, and would appreciate any support
 119 you'd care to offer.
 120
 121 Please note that B<I am not suggesting that you must do this> in order
 122 for me to continue working on this particular software. I will
 123 continue to do so, inasmuch as I have in the past, for as long as it
 124 interests me.
 125
 126 Similarly, a donation made in this way will probably not make me work
 127 on this software much more, unless I get so many donations that I can
 128 consider working on free software full time, which seems unlikely at
 129 best.
 130
 131 To donate, log into PayPal and send money to autarch@urth.org or use
 132 the button on this page:
 133 L<http://www.urth.org/~autarch/fs-donation.html>
 134
 135 =head1 AUTHOR
 136
 137 Dave Rolsky, C<< <autarch@urth.org> >>
 138
 139 =head1 BUGS
 140
 141 Please report any bugs or feature requests to
 142 C<bug-moosex-classattribute@rt.cpan.org>, or through the web interface
 143 at L<http://rt.cpan.org>.  I will be notified, and then you'll
 144 automatically be notified of progress on your bug as I make changes.
 145
 146 =head1 COPYRIGHT & LICENSE
 147
 148 Copyright 2007-2008 Dave Rolsky, All Rights Reserved.
 149
 150 This program is free software; you can redistribute it and/or modify
 151 it under the same terms as Perl itself.
 152
 153 =cut