lib/MooseX/ClassAttribute.pm

   1 package MooseX::ClassAttribute;
   2
   3 use strict;
   4 use warnings;
   5
   6 our $VERSION   = '0.13';
   7 our $AUTHORITY = 'cpan:DROLSKY';
   8
   9 use Moose 0.98 ();
  10 use Moose::Exporter;
  11 use MooseX::ClassAttribute::Trait::Class;
  12 use MooseX::ClassAttribute::Trait::Role;
  13 use MooseX::ClassAttribute::Trait::Application::ToClass;
  14 use MooseX::ClassAttribute::Trait::Application::ToRole;
  15
  16 Moose::Exporter->setup_import_methods( with_meta => ['class_has'] );
  17
  18 sub init_meta {
  19     shift;
  20     my %p = @_;
  21
  22     return Moose::Util::MetaRole::apply_metaclass_roles(
  23         for             => $p{for_class},
  24         class_metaroles => {
  25             class => ['MooseX::ClassAttribute::Trait::Class'],
  26         },
  27         role_metaroles => {
  28             role => ['MooseX::ClassAttribute::Trait::Role'],
  29             application_to_class =>
  30                 ['MooseX::ClassAttribute::Trait::Application::ToClass'],
  31             application_to_role =>
  32                 ['MooseX::ClassAttribute::Trait::Application::ToRole'],
  33         },
  34     );
  35 }
  36
  37 sub class_has {
  38     my $meta    = shift;
  39     my $name    = shift;
  40     my %options = @_;
  41
  42     my $attrs = ref $name eq 'ARRAY' ? $name : [$name];
  43
  44     $meta->add_class_attribute( $_, %options ) for @{$attrs};
  45 }
  46
  47 1;
  48
  49 __END__
  50
  51 =pod
  52
  53 =head1 NAME
  54
  55 MooseX::ClassAttribute - Declare class attributes Moose-style
  56
  57 =head1 SYNOPSIS
  58
  59     package My::Class;
  60
  61     use Moose;
  62     use MooseX::ClassAttribute;
  63
  64     class_has 'Cache' =>
  65         ( is      => 'rw',
  66           isa     => 'HashRef',
  67           default => sub { {} },
  68         );
  69
  70     __PACKAGE__->meta()->make_immutable();
  71
  72     no Moose;
  73     no MooseX::ClassAttribute;
  74
  75     # then later ...
  76
  77     My::Class->Cache()->{thing} = ...;
  78
  79 =head1 DESCRIPTION
  80
  81 This module allows you to declare class attributes in exactly the same
  82 way as object attributes, using C<class_has()> instead of C<has()>.
  83
  84 You can use any feature of Moose's attribute declarations, including
  85 overriding a parent's attributes, delegation (C<handles>), attribute traits,
  86 etc. All features should just work. The one exception is the "required" flag,
  87 which is not allowed for class attributes.
  88
  89 The accessor methods for class attribute may be called on the class
  90 directly, or on objects of that class. Passing a class attribute to
  91 the constructor will not set that attribute.
  92
  93 =head1 FUNCTIONS
  94
  95 This class exports one function when you use it, C<class_has()>. This
  96 works exactly like Moose's C<has()>, but it declares class attributes.
  97
  98 One little nit is that if you include C<no Moose> in your class, you won't
  99 remove the C<class_has()> function. To do that you must include C<no
 100 MooseX::ClassAttribute> as well. Or you can just use L<namespace::autoclean>
 101 instead.
 102
 103 =head2 Implementation and Immutability
 104
 105 This module will add a role to your class's metaclass, See
 106 L<MooseX::ClassAttribute::Trait::Class> for details. This role
 107 provides introspection methods for class attributes.
 108
 109 Class attributes themselves do the
 110 L<MooseX::ClassAttribute::Trait::Attribute> role.
 111
 112 There is also a L<MooseX::ClassAttribute::Meta::Method::Accessor>
 113 which provides part of the inlining implementation for class
 114 attributes.
 115
 116 =head2 Cooperation with Metaclasses and Traits
 117
 118 This module should work with most attribute metaclasses and traits,
 119 but it's possible that conflicts could occur. This module has been
 120 tested to work with Moose's native traits.
 121
 122 =head2 Class Attributes in Roles
 123
 124 You can add a class attribute to a role. When that role is applied to a class,
 125 the class will have the relevant class attributes added. Note that attribute
 126 defaults will be calculated when the class attribute is composed into the
 127 class.
 128
 129 =head1 DONATIONS
 130
 131 If you'd like to thank me for the work I've done on this module,
 132 please consider making a "donation" to me via PayPal. I spend a lot of
 133 free time creating free software, and would appreciate any support
 134 you'd care to offer.
 135
 136 Please note that B<I am not suggesting that you must do this> in order
 137 for me to continue working on this particular software. I will
 138 continue to do so, inasmuch as I have in the past, for as long as it
 139 interests me.
 140
 141 Similarly, a donation made in this way will probably not make me work
 142 on this software much more, unless I get so many donations that I can
 143 consider working on free software full time, which seems unlikely at
 144 best.
 145
 146 To donate, log into PayPal and send money to autarch@urth.org or use
 147 the button on this page:
 148 L<http://www.urth.org/~autarch/fs-donation.html>
 149
 150 =head1 AUTHOR
 151
 152 Dave Rolsky, C<< <autarch@urth.org> >>
 153
 154 =head1 BUGS
 155
 156 Please report any bugs or feature requests to
 157 C<bug-moosex-classattribute@rt.cpan.org>, or through the web interface
 158 at L<http://rt.cpan.org>.  I will be notified, and then you'll
 159 automatically be notified of progress on your bug as I make changes.
 160
 161 =head1 COPYRIGHT & LICENSE
 162
 163 Copyright 2007-2010 Dave Rolsky, All Rights Reserved.
 164
 165 This program is free software; you can redistribute it and/or modify
 166 it under the same terms as Perl itself.
 167
 168 =cut