lib/MooseX/ClassAttribute.pm

   1 package MooseX::ClassAttribute;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Moose 1.15 ();
   7 use Moose::Exporter;
   8 use MooseX::ClassAttribute::Trait::Class;
   9 use MooseX::ClassAttribute::Trait::Role;
  10 use MooseX::ClassAttribute::Trait::Application::ToClass;
  11 use MooseX::ClassAttribute::Trait::Application::ToRole;
  12
  13 Moose::Exporter->setup_import_methods(
  14     with_meta       => ['class_has'],
  15     class_metaroles => {
  16         class => ['MooseX::ClassAttribute::Trait::Class'],
  17     },
  18     role_metaroles => {
  19         role => ['MooseX::ClassAttribute::Trait::Role'],
  20         application_to_class =>
  21             ['MooseX::ClassAttribute::Trait::Application::ToClass'],
  22         application_to_role =>
  23             ['MooseX::ClassAttribute::Trait::Application::ToRole'],
  24     },
  25 );
  26
  27 sub class_has {
  28     my $meta    = shift;
  29     my $name    = shift;
  30     my %options = @_;
  31
  32     my $attrs = ref $name eq 'ARRAY' ? $name : [$name];
  33
  34     $meta->add_class_attribute( $_, %options ) for @{$attrs};
  35 }
  36
  37 1;
  38
  39 # ABSTRACT: Declare class attributes Moose-style
  40
  41 __END__
  42
  43 =pod
  44
  45 =head1 SYNOPSIS
  46
  47     package My::Class;
  48
  49     use Moose;
  50     use MooseX::ClassAttribute;
  51
  52     class_has 'Cache' =>
  53         ( is      => 'rw',
  54           isa     => 'HashRef',
  55           default => sub { {} },
  56         );
  57
  58     __PACKAGE__->meta()->make_immutable();
  59
  60     no Moose;
  61     no MooseX::ClassAttribute;
  62
  63     # then later ...
  64
  65     My::Class->Cache()->{thing} = ...;
  66
  67 =head1 DESCRIPTION
  68
  69 This module allows you to declare class attributes in exactly the same
  70 way as object attributes, using C<class_has()> instead of C<has()>.
  71
  72 You can use any feature of Moose's attribute declarations, including
  73 overriding a parent's attributes, delegation (C<handles>), attribute traits,
  74 etc. All features should just work. The one exception is the "required" flag,
  75 which is not allowed for class attributes.
  76
  77 The accessor methods for class attribute may be called on the class
  78 directly, or on objects of that class. Passing a class attribute to
  79 the constructor will not set that attribute.
  80
  81 =head1 FUNCTIONS
  82
  83 This class exports one function when you use it, C<class_has()>. This
  84 works exactly like Moose's C<has()>, but it declares class attributes.
  85
  86 One little nit is that if you include C<no Moose> in your class, you won't
  87 remove the C<class_has()> function. To do that you must include C<no
  88 MooseX::ClassAttribute> as well. Or you can just use L<namespace::autoclean>
  89 instead.
  90
  91 =head2 Implementation and Immutability
  92
  93 This module will add a role to your class's metaclass, See
  94 L<MooseX::ClassAttribute::Trait::Class> for details. This role
  95 provides introspection methods for class attributes.
  96
  97 Class attributes themselves do the
  98 L<MooseX::ClassAttribute::Trait::Attribute> role.
  99
 100 There is also a L<MooseX::ClassAttribute::Meta::Method::Accessor>
 101 which provides part of the inlining implementation for class
 102 attributes.
 103
 104 =head2 Cooperation with Metaclasses and Traits
 105
 106 This module should work with most attribute metaclasses and traits,
 107 but it's possible that conflicts could occur. This module has been
 108 tested to work with Moose's native traits.
 109
 110 =head2 Class Attributes in Roles
 111
 112 You can add a class attribute to a role. When that role is applied to a class,
 113 the class will have the relevant class attributes added. Note that attribute
 114 defaults will be calculated when the class attribute is composed into the
 115 class.
 116
 117 =head1 DONATIONS
 118
 119 If you'd like to thank me for the work I've done on this module,
 120 please consider making a "donation" to me via PayPal. I spend a lot of
 121 free time creating free software, and would appreciate any support
 122 you'd care to offer.
 123
 124 Please note that B<I am not suggesting that you must do this> in order
 125 for me to continue working on this particular software. I will
 126 continue to do so, inasmuch as I have in the past, for as long as it
 127 interests me.
 128
 129 Similarly, a donation made in this way will probably not make me work
 130 on this software much more, unless I get so many donations that I can
 131 consider working on free software full time, which seems unlikely at
 132 best.
 133
 134 To donate, log into PayPal and send money to autarch@urth.org or use
 135 the button on this page:
 136 L<http://www.urth.org/~autarch/fs-donation.html>
 137
 138 =head1 BUGS
 139
 140 Please report any bugs or feature requests to
 141 C<bug-moosex-classattribute@rt.cpan.org>, or through the web interface
 142 at L<http://rt.cpan.org>.  I will be notified, and then you'll
 143 automatically be notified of progress on your bug as I make changes.
 144
 145 =cut