lib/MooseX/ClassAttribute.pm

   1 package MooseX::ClassAttribute;
   2
   3 use strict;
   4 use warnings;
   5
   6 our $VERSION   = '0.10';
   7 our $AUTHORITY = 'cpan:DROLSKY';
   8
   9 use Moose 0.89 ();
  10 use Moose::Exporter;
  11 use MooseX::ClassAttribute::Role::Meta::Class;
  12
  13 Moose::Exporter->setup_import_methods( with_meta => ['class_has'] );
  14
  15 sub init_meta {
  16     shift;
  17     my %p = @_;
  18
  19     Moose->init_meta(%p);
  20
  21     return Moose::Util::MetaRole::apply_metaclass_roles(
  22         for_class       => $p{for_class},
  23         class_metaroles => {
  24             class => ['MooseX::ClassAttribute::Role::Meta::Class'],
  25         },
  26         role_metaroles => {
  27             role => ['MooseX::ClassAttribute::Role::Meta::Role'],
  28         },
  29     );
  30 }
  31
  32 sub class_has {
  33     my $meta    = shift;
  34     my $name    = shift;
  35     my %options = @_;
  36
  37     my $attrs = ref $name eq 'ARRAY' ? $name : [$name];
  38
  39     $meta->add_class_attribute( $_, %options ) for @{$attrs};
  40 }
  41
  42 1;
  43
  44 __END__
  45
  46 =pod
  47
  48 =head1 NAME
  49
  50 MooseX::ClassAttribute - Declare class attributes Moose-style
  51
  52 =head1 SYNOPSIS
  53
  54     package My::Class;
  55
  56     use Moose;
  57     use MooseX::ClassAttribute;
  58
  59     class_has 'Cache' =>
  60         ( is      => 'rw',
  61           isa     => 'HashRef',
  62           default => sub { {} },
  63         );
  64
  65     __PACKAGE__->meta()->make_immutable();
  66
  67     no Moose;
  68     no MooseX::ClassAttribute;
  69
  70     # then later ...
  71
  72     My::Class->Cache()->{thing} = ...;
  73
  74
  75 =head1 DESCRIPTION
  76
  77 This module allows you to declare class attributes in exactly the same
  78 way as object attributes, using C<class_has()> instead of C<has()>.
  79
  80 You can use any feature of Moose's attribute declarations, including
  81 overriding a parent's attributes, delegation (C<handles>), and
  82 attribute metaclasses, and it should just work. The one exception is
  83 the "required" flag, which is not allowed for class attributes.
  84
  85 The accessor methods for class attribute may be called on the class
  86 directly, or on objects of that class. Passing a class attribute to
  87 the constructor will not set it.
  88
  89 =head1 FUNCTIONS
  90
  91 This class exports one function when you use it, C<class_has()>. This
  92 works exactly like Moose's C<has()>, but it declares class attributes.
  93
  94 One little nit is that if you include C<no Moose> in your class, you
  95 won't remove the C<class_has()> function. To do that you must include
  96 C<no MooseX::ClassAttribute> as well.
  97
  98 =head2 Implementation and Immutability
  99
 100 This module will add a role to your class's metaclass, See
 101 L<MooseX::ClassAttribute::Role::Meta::Class> for details. This role
 102 provides introspection methods for class attributes.
 103
 104 Class attributes themselves do the
 105 L<MooseX::ClassAttribute::Role::Meta::Attribute> role.
 106
 107 There is also a L<MooseX::ClassAttribute::Meta::Method::Accessor>
 108 which provides part of the inlining implementation for class
 109 attributes.
 110
 111 =head2 Cooperation with Metaclasses and Traits
 112
 113 This module should work with most attribute metaclasses and traits,
 114 but it's possible that conflicts could occur. This module has been
 115 tested to work with C<MooseX::AttributeHelpers>.
 116
 117 =head1 DONATIONS
 118
 119 If you'd like to thank me for the work I've done on this module,
 120 please consider making a "donation" to me via PayPal. I spend a lot of
 121 free time creating free software, and would appreciate any support
 122 you'd care to offer.
 123
 124 Please note that B<I am not suggesting that you must do this> in order
 125 for me to continue working on this particular software. I will
 126 continue to do so, inasmuch as I have in the past, for as long as it
 127 interests me.
 128
 129 Similarly, a donation made in this way will probably not make me work
 130 on this software much more, unless I get so many donations that I can
 131 consider working on free software full time, which seems unlikely at
 132 best.
 133
 134 To donate, log into PayPal and send money to autarch@urth.org or use
 135 the button on this page:
 136 L<http://www.urth.org/~autarch/fs-donation.html>
 137
 138 =head1 AUTHOR
 139
 140 Dave Rolsky, C<< <autarch@urth.org> >>
 141
 142 =head1 BUGS
 143
 144 Please report any bugs or feature requests to
 145 C<bug-moosex-classattribute@rt.cpan.org>, or through the web interface
 146 at L<http://rt.cpan.org>.  I will be notified, and then you'll
 147 automatically be notified of progress on your bug as I make changes.
 148
 149 =head1 COPYRIGHT & LICENSE
 150
 151 Copyright 2007-2008 Dave Rolsky, All Rights Reserved.
 152
 153 This program is free software; you can redistribute it and/or modify
 154 it under the same terms as Perl itself.
 155
 156 =cut