lib/MooseX/ClassAttribute.pm

   1 package MooseX::ClassAttribute;
   2
   3 use strict;
   4 use warnings;
   5
   6 our $VERSION   = '0.11';
   7 our $AUTHORITY = 'cpan:DROLSKY';
   8
   9 use Moose 0.96 ();
  10 use Moose::Exporter;
  11 use MooseX::ClassAttribute::Trait::Class;
  12 use MooseX::ClassAttribute::Trait::Role;
  13 use MooseX::ClassAttribute::Trait::Application::ToClass;
  14 use MooseX::ClassAttribute::Trait::Application::ToRole;
  15 use MooseX::ClassAttribute::Trait::Application::ToInstance;
  16
  17 Moose::Exporter->setup_import_methods( with_meta => ['class_has'] );
  18
  19 sub init_meta {
  20     shift;
  21     my %p = @_;
  22
  23     return Moose::Util::MetaRole::apply_metaclass_roles(
  24         for             => $p{for_class},
  25         class_metaroles => {
  26             class => ['MooseX::ClassAttribute::Trait::Class'],
  27         },
  28         role_metaroles => {
  29             role => ['MooseX::ClassAttribute::Trait::Role'],
  30             application_to_class =>
  31                 ['MooseX::ClassAttribute::Trait::Application::ToClass'],
  32             application_to_role =>
  33                 ['MooseX::ClassAttribute::Trait::Application::ToRole'],
  34             application_to_instance => [
  35                 'MooseX::ClassAttribute::Trait::Application::ToInstance'
  36             ],
  37         },
  38     );
  39 }
  40
  41 sub class_has {
  42     my $meta    = shift;
  43     my $name    = shift;
  44     my %options = @_;
  45
  46     my $attrs = ref $name eq 'ARRAY' ? $name : [$name];
  47
  48     $meta->add_class_attribute( $_, %options ) for @{$attrs};
  49 }
  50
  51 1;
  52
  53 __END__
  54
  55 =pod
  56
  57 =head1 NAME
  58
  59 MooseX::ClassAttribute - Declare class attributes Moose-style
  60
  61 =head1 SYNOPSIS
  62
  63     package My::Class;
  64
  65     use Moose;
  66     use MooseX::ClassAttribute;
  67
  68     class_has 'Cache' =>
  69         ( is      => 'rw',
  70           isa     => 'HashRef',
  71           default => sub { {} },
  72         );
  73
  74     __PACKAGE__->meta()->make_immutable();
  75
  76     no Moose;
  77     no MooseX::ClassAttribute;
  78
  79     # then later ...
  80
  81     My::Class->Cache()->{thing} = ...;
  82
  83 =head1 DESCRIPTION
  84
  85 This module allows you to declare class attributes in exactly the same
  86 way as object attributes, using C<class_has()> instead of C<has()>.
  87
  88 You can use any feature of Moose's attribute declarations, including
  89 overriding a parent's attributes, delegation (C<handles>), attribute traits,
  90 etc. All features should just work. The one exception is the "required" flag,
  91 which is not allowed for class attributes.
  92
  93 The accessor methods for class attribute may be called on the class
  94 directly, or on objects of that class. Passing a class attribute to
  95 the constructor will not set that attribute.
  96
  97 =head1 FUNCTIONS
  98
  99 This class exports one function when you use it, C<class_has()>. This
 100 works exactly like Moose's C<has()>, but it declares class attributes.
 101
 102 One little nit is that if you include C<no Moose> in your class, you won't
 103 remove the C<class_has()> function. To do that you must include C<no
 104 MooseX::ClassAttribute> as well. Or you can just use L<namespace::autoclean>
 105 instead.
 106
 107 =head2 Implementation and Immutability
 108
 109 This module will add a role to your class's metaclass, See
 110 L<MooseX::ClassAttribute::Trait::Class> for details. This role
 111 provides introspection methods for class attributes.
 112
 113 Class attributes themselves do the
 114 L<MooseX::ClassAttribute::Trait::Attribute> role.
 115
 116 There is also a L<MooseX::ClassAttribute::Meta::Method::Accessor>
 117 which provides part of the inlining implementation for class
 118 attributes.
 119
 120 =head2 Cooperation with Metaclasses and Traits
 121
 122 This module should work with most attribute metaclasses and traits,
 123 but it's possible that conflicts could occur. This module has been
 124 tested to work with Moose's native traits.
 125
 126 =head2 Class Attributes in Roles
 127
 128 You can add a class attribute to a role. When that role is applied to a class,
 129 the class will have the relevant class attributes added. Note that attribute
 130 defaults will be calculated when the class attribute is composed into the
 131 class.
 132
 133 =head1 DONATIONS
 134
 135 If you'd like to thank me for the work I've done on this module,
 136 please consider making a "donation" to me via PayPal. I spend a lot of
 137 free time creating free software, and would appreciate any support
 138 you'd care to offer.
 139
 140 Please note that B<I am not suggesting that you must do this> in order
 141 for me to continue working on this particular software. I will
 142 continue to do so, inasmuch as I have in the past, for as long as it
 143 interests me.
 144
 145 Similarly, a donation made in this way will probably not make me work
 146 on this software much more, unless I get so many donations that I can
 147 consider working on free software full time, which seems unlikely at
 148 best.
 149
 150 To donate, log into PayPal and send money to autarch@urth.org or use
 151 the button on this page:
 152 L<http://www.urth.org/~autarch/fs-donation.html>
 153
 154 =head1 AUTHOR
 155
 156 Dave Rolsky, C<< <autarch@urth.org> >>
 157
 158 =head1 BUGS
 159
 160 Please report any bugs or feature requests to
 161 C<bug-moosex-classattribute@rt.cpan.org>, or through the web interface
 162 at L<http://rt.cpan.org>.  I will be notified, and then you'll
 163 automatically be notified of progress on your bug as I make changes.
 164
 165 =head1 COPYRIGHT & LICENSE
 166
 167 Copyright 2007-2008 Dave Rolsky, All Rights Reserved.
 168
 169 This program is free software; you can redistribute it and/or modify
 170 it under the same terms as Perl itself.
 171
 172 =cut