lib/MooseX/ClassAttribute.pm

   1 package MooseX::ClassAttribute;
   2
   3 use strict;
   4 use warnings;
   5
   6 our $VERSION   = '0.10';
   7 our $AUTHORITY = 'cpan:DROLSKY';
   8
   9 use Moose 0.89 ();
  10 use Moose::Exporter;
  11 use MooseX::ClassAttribute::Role::Meta::Class;
  12
  13 Moose::Exporter->setup_import_methods( with_meta => ['class_has'] );
  14
  15 sub init_meta {
  16     shift;
  17     my %p = @_;
  18
  19     return Moose::Util::MetaRole::apply_metaclass_roles(
  20         for             => $p{for_class},
  21         class_metaroles => {
  22             class => ['MooseX::ClassAttribute::Role::Meta::Class'],
  23         },
  24
  25         #        role_metaroles => {
  26         #            role => ['MooseX::ClassAttribute::Role::Meta::Role'],
  27         #        },
  28     );
  29 }
  30
  31 sub class_has {
  32     my $meta    = shift;
  33     my $name    = shift;
  34     my %options = @_;
  35
  36     my $attrs = ref $name eq 'ARRAY' ? $name : [$name];
  37
  38     $meta->add_class_attribute( $_, %options ) for @{$attrs};
  39 }
  40
  41 1;
  42
  43 __END__
  44
  45 =pod
  46
  47 =head1 NAME
  48
  49 MooseX::ClassAttribute - Declare class attributes Moose-style
  50
  51 =head1 SYNOPSIS
  52
  53     package My::Class;
  54
  55     use Moose;
  56     use MooseX::ClassAttribute;
  57
  58     class_has 'Cache' =>
  59         ( is      => 'rw',
  60           isa     => 'HashRef',
  61           default => sub { {} },
  62         );
  63
  64     __PACKAGE__->meta()->make_immutable();
  65
  66     no Moose;
  67     no MooseX::ClassAttribute;
  68
  69     # then later ...
  70
  71     My::Class->Cache()->{thing} = ...;
  72
  73
  74 =head1 DESCRIPTION
  75
  76 This module allows you to declare class attributes in exactly the same
  77 way as object attributes, using C<class_has()> instead of C<has()>.
  78
  79 You can use any feature of Moose's attribute declarations, including
  80 overriding a parent's attributes, delegation (C<handles>), and
  81 attribute metaclasses, and it should just work. The one exception is
  82 the "required" flag, which is not allowed for class attributes.
  83
  84 The accessor methods for class attribute may be called on the class
  85 directly, or on objects of that class. Passing a class attribute to
  86 the constructor will not set it.
  87
  88 =head1 FUNCTIONS
  89
  90 This class exports one function when you use it, C<class_has()>. This
  91 works exactly like Moose's C<has()>, but it declares class attributes.
  92
  93 One little nit is that if you include C<no Moose> in your class, you
  94 won't remove the C<class_has()> function. To do that you must include
  95 C<no MooseX::ClassAttribute> as well.
  96
  97 =head2 Implementation and Immutability
  98
  99 This module will add a role to your class's metaclass, See
 100 L<MooseX::ClassAttribute::Role::Meta::Class> for details. This role
 101 provides introspection methods for class attributes.
 102
 103 Class attributes themselves do the
 104 L<MooseX::ClassAttribute::Role::Meta::Attribute> role.
 105
 106 There is also a L<MooseX::ClassAttribute::Meta::Method::Accessor>
 107 which provides part of the inlining implementation for class
 108 attributes.
 109
 110 =head2 Cooperation with Metaclasses and Traits
 111
 112 This module should work with most attribute metaclasses and traits,
 113 but it's possible that conflicts could occur. This module has been
 114 tested to work with C<MooseX::AttributeHelpers>.
 115
 116 =head1 DONATIONS
 117
 118 If you'd like to thank me for the work I've done on this module,
 119 please consider making a "donation" to me via PayPal. I spend a lot of
 120 free time creating free software, and would appreciate any support
 121 you'd care to offer.
 122
 123 Please note that B<I am not suggesting that you must do this> in order
 124 for me to continue working on this particular software. I will
 125 continue to do so, inasmuch as I have in the past, for as long as it
 126 interests me.
 127
 128 Similarly, a donation made in this way will probably not make me work
 129 on this software much more, unless I get so many donations that I can
 130 consider working on free software full time, which seems unlikely at
 131 best.
 132
 133 To donate, log into PayPal and send money to autarch@urth.org or use
 134 the button on this page:
 135 L<http://www.urth.org/~autarch/fs-donation.html>
 136
 137 =head1 AUTHOR
 138
 139 Dave Rolsky, C<< <autarch@urth.org> >>
 140
 141 =head1 BUGS
 142
 143 Please report any bugs or feature requests to
 144 C<bug-moosex-classattribute@rt.cpan.org>, or through the web interface
 145 at L<http://rt.cpan.org>.  I will be notified, and then you'll
 146 automatically be notified of progress on your bug as I make changes.
 147
 148 =head1 COPYRIGHT & LICENSE
 149
 150 Copyright 2007-2008 Dave Rolsky, All Rights Reserved.
 151
 152 This program is free software; you can redistribute it and/or modify
 153 it under the same terms as Perl itself.
 154
 155 =cut