t/070_native_traits/010_trait_array.t

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use lib 't/lib';
   7
   8 use Moose ();
   9 use Moose::Util::TypeConstraints;
  10 use NoInlineAttribute;
  11 use Test::More;
  12 use Test::Fatal;
  13 use Test::Moose;
  14
  15 {
  16     my %handles = (
  17         count    => 'count',
  18         elements => 'elements',
  19         is_empty => 'is_empty',
  20         push     => 'push',
  21         push_curried =>
  22             [ push => 42, 84 ],
  23         unshift => 'unshift',
  24         unshift_curried =>
  25             [ unshift => 42, 84 ],
  26         pop           => 'pop',
  27         shift         => 'shift',
  28         get           => 'get',
  29         get_curried   => [ get => 1 ],
  30         set           => 'set',
  31         set_curried_1 => [ set => 1 ],
  32         set_curried_2 => [ set => ( 1, 98 ) ],
  33         accessor      => 'accessor',
  34         accessor_curried_1 => [ accessor => 1 ],
  35         accessor_curried_2 => [ accessor => ( 1, 90 ) ],
  36         clear          => 'clear',
  37         delete         => 'delete',
  38         delete_curried => [ delete => 1 ],
  39         insert         => 'insert',
  40         insert_curried => [ insert => ( 1, 101 ) ],
  41         splice         => 'splice',
  42         splice_curried_1   => [ splice => 1 ],
  43         splice_curried_2   => [ splice => 1, 2 ],
  44         splice_curried_all => [ splice => 1, 2, ( 3, 4, 5 ) ],
  45         sort          => 'sort',
  46         sort_curried  => [ sort => ( sub { $_[1] <=> $_[0] } ) ],
  47         sort_in_place => 'sort_in_place',
  48         sort_in_place_curried =>
  49             [ sort_in_place => ( sub { $_[1] <=> $_[0] } ) ],
  50         map           => 'map',
  51         map_curried   => [ map => ( sub { $_ + 1 } ) ],
  52         grep          => 'grep',
  53         grep_curried  => [ grep => ( sub { $_ < 5 } ) ],
  54         first         => 'first',
  55         first_curried => [ first => ( sub { $_ % 2 } ) ],
  56         join          => 'join',
  57         join_curried => [ join => '-' ],
  58         shuffle      => 'shuffle',
  59         uniq         => 'uniq',
  60         reduce       => 'reduce',
  61         reduce_curried => [ reduce => ( sub { $_[0] * $_[1] } ) ],
  62         natatime       => 'natatime',
  63         natatime_curried => [ natatime => 2 ],
  64     );
  65
  66     my $name = 'Foo1';
  67
  68     sub build_class {
  69         my %attr = @_;
  70
  71         my $class = Moose::Meta::Class->create(
  72             $name++,
  73             superclasses => ['Moose::Object'],
  74         );
  75
  76         my @traits = 'Array';
  77         push @traits, 'NoInlineAttribute'
  78             if delete $attr{no_inline};
  79
  80         $class->add_attribute(
  81             _values => (
  82                 traits  => \@traits,
  83                 is      => 'rw',
  84                 isa     => 'ArrayRef[Int]',
  85                 default => sub { [] },
  86                 handles => \%handles,
  87                 clearer => '_clear_values',
  88                 %attr,
  89             ),
  90         );
  91
  92         return ( $class->name, \%handles );
  93     }
  94 }
  95
  96 {
  97     package Overloader;
  98
  99     use overload
 100         '&{}' => sub { ${ $_[0] } },
 101         bool  => sub {1};
 102
 103     sub new {
 104         bless \$_[1], $_[0];
 105     }
 106 }
 107
 108 {
 109     run_tests(build_class);
 110     run_tests( build_class( lazy => 1, default => sub { [ 42, 84 ] } ) );
 111     run_tests( build_class( trigger => sub { } ) );
 112     run_tests( build_class( no_inline => 1 ) );
 113
 114     # Will force the inlining code to check the entire arrayref when it is modified.
 115     subtype 'MyArrayRef', as 'ArrayRef', where { 1 };
 116
 117     run_tests( build_class( isa => 'MyArrayRef' ) );
 118
 119     coerce 'MyArrayRef', from 'ArrayRef', via { $_ };
 120
 121     run_tests( build_class( isa => 'MyArrayRef', coerce => 1 ) );
 122 }
 123
 124 sub run_tests {
 125     my ( $class, $handles ) = @_;
 126
 127     can_ok( $class, $_ ) for sort keys %{$handles};
 128
 129     with_immutable {
 130         my $obj = $class->new( _values => [ 10, 12, 42 ] );
 131
 132         is_deeply(
 133             $obj->_values, [ 10, 12, 42 ],
 134             'values can be set in constructor'
 135         );
 136
 137         ok( !$obj->is_empty, 'values is not empty' );
 138         is( $obj->count, 3, 'count returns 3' );
 139
 140         like( exception { $obj->count(22) }, qr/Cannot call count with any arguments/, 'throws an error when passing an argument passed to count' );
 141
 142         is( exception { $obj->push( 1, 2, 3 ) }, undef, 'pushed three new values and lived' );
 143
 144         is( exception { $obj->push() }, undef, 'call to push without arguments lives' );
 145
 146         is( exception {
 147             is( $obj->unshift( 101, 22 ), 8,
 148                 'unshift returns size of the new array' );
 149         }, undef, 'unshifted two values and lived' );
 150
 151         is_deeply(
 152             $obj->_values, [ 101, 22, 10, 12, 42, 1, 2, 3 ],
 153             'unshift changed the value of the array in the object'
 154         );
 155
 156         is( exception { $obj->unshift() }, undef, 'call to unshift without arguments lives' );
 157
 158         is( $obj->pop, 3, 'pop returns the last value in the array' );
 159
 160         is_deeply(
 161             $obj->_values, [ 101, 22, 10, 12, 42, 1, 2 ],
 162             'pop changed the value of the array in the object'
 163         );
 164
 165         like( exception { $obj->pop(42) }, qr/Cannot call pop with any arguments/, 'call to pop with arguments dies' );
 166
 167         is( $obj->shift, 101, 'shift returns the first value' );
 168
 169         like( exception { $obj->shift(42) }, qr/Cannot call shift with any arguments/, 'call to shift with arguments dies' );
 170
 171         is_deeply(
 172             $obj->_values, [ 22, 10, 12, 42, 1, 2 ],
 173             'shift changed the value of the array in the object'
 174         );
 175
 176         is_deeply(
 177             [ $obj->elements ], [ 22, 10, 12, 42, 1, 2 ],
 178             'call to elements returns values as a list'
 179         );
 180
 181         like( exception { $obj->elements(22) }, qr/Cannot call elements with any arguments/, 'throws an error when passing an argument passed to elements' );
 182
 183         $obj->_values( [ 1, 2, 3 ] );
 184
 185         is( $obj->get(0),      1, 'get values at index 0' );
 186         is( $obj->get(1),      2, 'get values at index 1' );
 187         is( $obj->get(2),      3, 'get values at index 2' );
 188         is( $obj->get_curried, 2, 'get_curried returns value at index 1' );
 189
 190         like( exception { $obj->get() }, qr/Cannot call get without at least 1 argument/, 'throws an error when get is called without any arguments' );
 191
 192         like( exception { $obj->get( {} ) }, qr/The index passed to get must be an integer/, 'throws an error when get is called with an invalid argument' );
 193
 194         like( exception { $obj->get(2.2) }, qr/The index passed to get must be an integer/, 'throws an error when get is called with an invalid argument' );
 195
 196         like( exception { $obj->get('foo') }, qr/The index passed to get must be an integer/, 'throws an error when get is called with an invalid argument' );
 197
 198         like( exception { $obj->get_curried(2) }, qr/Cannot call get with more than 1 argument/, 'throws an error when get_curried is called with an argument' );
 199
 200         is( exception {
 201             is( $obj->set( 1, 100 ), 100, 'set returns new value' );
 202         }, undef, 'set value at index 1 lives' );
 203
 204         is( $obj->get(1), 100, 'get value at index 1 returns new value' );
 205
 206
 207         like( exception { $obj->set( 1, 99, 42 ) }, qr/Cannot call set with more than 2 arguments/, 'throws an error when set is called with three arguments' );
 208
 209         is( exception { $obj->set_curried_1(99) }, undef, 'set_curried_1 lives' );
 210
 211         is( $obj->get(1), 99, 'get value at index 1 returns new value' );
 212
 213         like( exception { $obj->set_curried_1( 99, 42 ) }, qr/Cannot call set with more than 2 arguments/, 'throws an error when set_curried_1 is called with two arguments' );
 214
 215         is( exception { $obj->set_curried_2 }, undef, 'set_curried_2 lives' );
 216
 217         is( $obj->get(1), 98, 'get value at index 1 returns new value' );
 218
 219         like( exception { $obj->set_curried_2(42) }, qr/Cannot call set with more than 2 arguments/, 'throws an error when set_curried_2 is called with one argument' );
 220
 221         is(
 222             $obj->accessor(1), 98,
 223             'accessor with one argument returns value at index 1'
 224         );
 225
 226         is( exception {
 227             is( $obj->accessor( 1 => 97 ), 97, 'accessor returns new value' );
 228         }, undef, 'accessor as writer lives' );
 229
 230         is(
 231             $obj->get(1), 97,
 232             'accessor set value at index 1'
 233         );
 234
 235         like( exception { $obj->accessor( 1, 96, 42 ) }, qr/Cannot call accessor with more than 2 arguments/, 'throws an error when accessor is called with three arguments' );
 236
 237         is(
 238             $obj->accessor_curried_1, 97,
 239             'accessor_curried_1 returns expected value when called with no arguments'
 240         );
 241
 242         is( exception { $obj->accessor_curried_1(95) }, undef, 'accessor_curried_1 as writer lives' );
 243
 244         is(
 245             $obj->get(1), 95,
 246             'accessor_curried_1 set value at index 1'
 247         );
 248
 249         like( exception { $obj->accessor_curried_1( 96, 42 ) }, qr/Cannot call accessor with more than 2 arguments/, 'throws an error when accessor_curried_1 is called with two arguments' );
 250
 251         is( exception { $obj->accessor_curried_2 }, undef, 'accessor_curried_2 as writer lives' );
 252
 253         is(
 254             $obj->get(1), 90,
 255             'accessor_curried_2 set value at index 1'
 256         );
 257
 258         like( exception { $obj->accessor_curried_2(42) }, qr/Cannot call accessor with more than 2 arguments/, 'throws an error when accessor_curried_2 is called with one argument' );
 259
 260         is( exception { $obj->clear }, undef, 'clear lives' );
 261
 262         ok( $obj->is_empty, 'values is empty after call to clear' );
 263
 264         $obj->set( 0 => 42 );
 265
 266         like( exception { $obj->clear(50) }, qr/Cannot call clear with any arguments/, 'throws an error when clear is called with an argument' );
 267
 268         ok(
 269             !$obj->is_empty,
 270             'values is not empty after failed call to clear'
 271         );
 272
 273         like( exception { $obj->is_empty(50) }, qr/Cannot call is_empty with any arguments/, 'throws an error when is_empty is called with an argument' );
 274
 275         $obj->clear;
 276         is(
 277             $obj->push( 1, 5, 10, 42 ), 4,
 278             'pushed 4 elements, got number of elements in the array back'
 279         );
 280
 281         is( exception {
 282             is( $obj->delete(2), 10, 'delete returns deleted value' );
 283         }, undef, 'delete lives' );
 284
 285         is_deeply(
 286             $obj->_values, [ 1, 5, 42 ],
 287             'delete removed the specified element'
 288         );
 289
 290         like( exception { $obj->delete( 2, 3 ) }, qr/Cannot call delete with more than 1 argument/, 'throws an error when delete is called with two arguments' );
 291
 292         is( exception { $obj->delete_curried }, undef, 'delete_curried lives' );
 293
 294         is_deeply(
 295             $obj->_values, [ 1, 42 ],
 296             'delete removed the specified element'
 297         );
 298
 299         like( exception { $obj->delete_curried(2) }, qr/Cannot call delete with more than 1 argument/, 'throws an error when delete_curried is called with one argument' );
 300
 301         is( exception { $obj->insert( 1, 21 ) }, undef, 'insert lives' );
 302
 303         is_deeply(
 304             $obj->_values, [ 1, 21, 42 ],
 305             'insert added the specified element'
 306         );
 307
 308         like( exception { $obj->insert( 1, 22, 44 ) }, qr/Cannot call insert with more than 2 arguments/, 'throws an error when insert is called with three arguments' );
 309
 310         is( exception {
 311             is_deeply(
 312                 [ $obj->splice( 1, 0, 2, 3 ) ],
 313                 [],
 314                 'return value of splice is empty list when not removing elements'
 315             );
 316         }, undef, 'splice lives' );
 317
 318         is_deeply(
 319             $obj->_values, [ 1, 2, 3, 21, 42 ],
 320             'splice added the specified elements'
 321         );
 322
 323         is( exception {
 324             is_deeply(
 325                 [ $obj->splice( 1, 2, 99 ) ],
 326                 [ 2, 3 ],
 327                 'splice returns list of removed values'
 328             );
 329         }, undef, 'splice lives' );
 330
 331         is_deeply(
 332             $obj->_values, [ 1, 99, 21, 42 ],
 333             'splice added the specified elements'
 334         );
 335
 336         like( exception { $obj->splice() }, qr/Cannot call splice without at least 1 argument/, 'throws an error when splice is called with no arguments' );
 337
 338         like( exception { $obj->splice( 1, 'foo', ) }, qr/The length argument passed to splice must be an integer/, 'throws an error when splice is called with an invalid length' );
 339
 340         is( exception { $obj->splice_curried_1( 2, 101 ) }, undef, 'splice_curried_1 lives' );
 341
 342         is_deeply(
 343             $obj->_values, [ 1, 101, 42 ],
 344             'splice added the specified elements'
 345         );
 346
 347         is( exception { $obj->splice_curried_2(102) }, undef, 'splice_curried_2 lives' );
 348
 349         is_deeply(
 350             $obj->_values, [ 1, 102 ],
 351             'splice added the specified elements'
 352         );
 353
 354         is( exception { $obj->splice_curried_all }, undef, 'splice_curried_all lives' );
 355
 356         is_deeply(
 357             $obj->_values, [ 1, 3, 4, 5 ],
 358             'splice added the specified elements'
 359         );
 360
 361         is_deeply(
 362             scalar $obj->splice( 1, 2 ),
 363             4,
 364             'splice in scalar context returns last element removed'
 365         );
 366
 367         is_deeply(
 368             scalar $obj->splice( 1, 0, 42 ),
 369             undef,
 370             'splice in scalar context returns undef when no elements are removed'
 371         );
 372
 373         $obj->_values( [ 3, 9, 5, 22, 11 ] );
 374
 375         is_deeply(
 376             [ $obj->sort ], [ 11, 22, 3, 5, 9 ],
 377             'sort returns sorted values'
 378         );
 379
 380         is_deeply(
 381             [ $obj->sort( sub { $_[0] <=> $_[1] } ) ], [ 3, 5, 9, 11, 22 ],
 382             'sort returns values sorted by provided function'
 383         );
 384
 385         like( exception { $obj->sort(1) }, qr/The argument passed to sort must be a code reference/, 'throws an error when passing a non coderef to sort' );
 386
 387         like( exception {
 388             $obj->sort( sub { }, 27 );
 389         }, qr/Cannot call sort with more than 1 argument/, 'throws an error when passing two arguments to sort' );
 390
 391         $obj->_values( [ 3, 9, 5, 22, 11 ] );
 392
 393         $obj->sort_in_place;
 394
 395         is_deeply(
 396             $obj->_values, [ 11, 22, 3, 5, 9 ],
 397             'sort_in_place sorts values'
 398         );
 399
 400         $obj->sort_in_place( sub { $_[0] <=> $_[1] } );
 401
 402         is_deeply(
 403             $obj->_values, [ 3, 5, 9, 11, 22 ],
 404             'sort_in_place with function sorts values'
 405         );
 406
 407         like( exception {
 408             $obj->sort_in_place( 27 );
 409         }, qr/The argument passed to sort_in_place must be a code reference/, 'throws an error when passing a non coderef to sort_in_place' );
 410
 411         like( exception {
 412             $obj->sort_in_place( sub { }, 27 );
 413         }, qr/Cannot call sort_in_place with more than 1 argument/, 'throws an error when passing two arguments to sort_in_place' );
 414
 415         $obj->_values( [ 3, 9, 5, 22, 11 ] );
 416
 417         $obj->sort_in_place_curried;
 418
 419         is_deeply(
 420             $obj->_values, [ 22, 11, 9, 5, 3 ],
 421             'sort_in_place_curried sorts values'
 422         );
 423
 424         like( exception { $obj->sort_in_place_curried(27) }, qr/Cannot call sort_in_place with more than 1 argument/, 'throws an error when passing one argument passed to sort_in_place_curried' );
 425
 426         $obj->_values( [ 1 .. 5 ] );
 427
 428         is_deeply(
 429             [ $obj->map( sub { $_ + 1 } ) ],
 430             [ 2 .. 6 ],
 431             'map returns the expected values'
 432         );
 433
 434         like( exception { $obj->map }, qr/Cannot call map without at least 1 argument/, 'throws an error when passing no arguments to map' );
 435
 436         like( exception {
 437             $obj->map( sub { }, 2 );
 438         }, qr/Cannot call map with more than 1 argument/, 'throws an error when passing two arguments to map' );
 439
 440         like( exception { $obj->map( {} ) }, qr/The argument passed to map must be a code reference/, 'throws an error when passing a non coderef to map' );
 441
 442         $obj->_values( [ 1 .. 5 ] );
 443
 444         is_deeply(
 445             [ $obj->map_curried ],
 446             [ 2 .. 6 ],
 447             'map_curried returns the expected values'
 448         );
 449
 450         like( exception {
 451             $obj->map_curried( sub { } );
 452         }, qr/Cannot call map with more than 1 argument/, 'throws an error when passing one argument passed to map_curried' );
 453
 454         $obj->_values( [ 2 .. 9 ] );
 455
 456         is_deeply(
 457             [ $obj->grep( sub { $_ < 5 } ) ],
 458             [ 2 .. 4 ],
 459             'grep returns the expected values'
 460         );
 461
 462         like( exception { $obj->grep }, qr/Cannot call grep without at least 1 argument/, 'throws an error when passing no arguments to grep' );
 463
 464         like( exception {
 465             $obj->grep( sub { }, 2 );
 466         }, qr/Cannot call grep with more than 1 argument/, 'throws an error when passing two arguments to grep' );
 467
 468         like( exception { $obj->grep( {} ) }, qr/The argument passed to grep must be a code reference/, 'throws an error when passing a non coderef to grep' );
 469
 470         my $overloader = Overloader->new( sub { $_ < 5 } );
 471         is_deeply(
 472             [ $obj->grep($overloader) ],
 473             [ 2 .. 4 ],
 474             'grep works with obj that overload code dereferencing'
 475         );
 476
 477         is_deeply(
 478             [ $obj->grep_curried ],
 479             [ 2 .. 4 ],
 480             'grep_curried returns the expected values'
 481         );
 482
 483         like( exception {
 484             $obj->grep_curried( sub { } );
 485         }, qr/Cannot call grep with more than 1 argument/, 'throws an error when passing one argument passed to grep_curried' );
 486
 487         $obj->_values( [ 2, 4, 22, 99, 101, 6 ] );
 488
 489         is(
 490             $obj->first( sub { $_ % 2 } ),
 491             99,
 492             'first returns expected value'
 493         );
 494
 495         like( exception { $obj->first }, qr/Cannot call first without at least 1 argument/, 'throws an error when passing no arguments to first' );
 496
 497         like( exception {
 498             $obj->first( sub { }, 2 );
 499         }, qr/Cannot call first with more than 1 argument/, 'throws an error when passing two arguments to first' );
 500
 501         like( exception { $obj->first( {} ) }, qr/The argument passed to first must be a code reference/, 'throws an error when passing a non coderef to first' );
 502
 503         is(
 504             $obj->first_curried,
 505             99,
 506             'first_curried returns expected value'
 507         );
 508
 509         like( exception {
 510             $obj->first_curried( sub { } );
 511         }, qr/Cannot call first with more than 1 argument/, 'throws an error when passing one argument passed to first_curried' );
 512
 513         $obj->_values( [ 1 .. 4 ] );
 514
 515         is(
 516             $obj->join('-'), '1-2-3-4',
 517             'join returns expected result'
 518         );
 519
 520         is(
 521             $obj->join(q{}), '1234',
 522             'join returns expected result when joining with empty string'
 523         );
 524
 525         like( exception { $obj->join }, qr/Cannot call join without at least 1 argument/, 'throws an error when passing no arguments to join' );
 526
 527         like( exception { $obj->join( '-', 2 ) }, qr/Cannot call join with more than 1 argument/, 'throws an error when passing two arguments to join' );
 528
 529         like( exception { $obj->join( {} ) }, qr/The argument passed to join must be a string/, 'throws an error when passing a non string to join' );
 530
 531         is_deeply(
 532             [ sort $obj->shuffle ],
 533             [ 1 .. 4 ],
 534             'shuffle returns all values (cannot check for a random order)'
 535         );
 536
 537         like( exception { $obj->shuffle(2) }, qr/Cannot call shuffle with any arguments/, 'throws an error when passing an argument passed to shuffle' );
 538
 539         $obj->_values( [ 1 .. 4, 2, 5, 3, 7, 3, 3, 1 ] );
 540
 541         is_deeply(
 542             [ $obj->uniq ],
 543             [ 1 .. 4, 5, 7 ],
 544             'uniq returns expected values (in original order)'
 545         );
 546
 547         like( exception { $obj->uniq(2) }, qr/Cannot call uniq with any arguments/, 'throws an error when passing an argument passed to uniq' );
 548
 549         $obj->_values( [ 1 .. 5 ] );
 550
 551         is(
 552             $obj->reduce( sub { $_[0] * $_[1] } ),
 553             120,
 554             'reduce returns expected value'
 555         );
 556
 557         like( exception { $obj->reduce }, qr/Cannot call reduce without at least 1 argument/, 'throws an error when passing no arguments to reduce' );
 558
 559         like( exception {
 560             $obj->reduce( sub { }, 2 );
 561         }, qr/Cannot call reduce with more than 1 argument/, 'throws an error when passing two arguments to reduce' );
 562
 563         like( exception { $obj->reduce( {} ) }, qr/The argument passed to reduce must be a code reference/, 'throws an error when passing a non coderef to reduce' );
 564
 565         is(
 566             $obj->reduce_curried,
 567             120,
 568             'reduce_curried returns expected value'
 569         );
 570
 571         like( exception {
 572             $obj->reduce_curried( sub { } );
 573         }, qr/Cannot call reduce with more than 1 argument/, 'throws an error when passing one argument passed to reduce_curried' );
 574
 575         $obj->_values( [ 1 .. 6 ] );
 576
 577         my $it = $obj->natatime(2);
 578         my @nat;
 579         while ( my @v = $it->() ) {
 580             push @nat, \@v;
 581         }
 582
 583         is_deeply(
 584             [ [ 1, 2 ], [ 3, 4 ], [ 5, 6 ] ],
 585             \@nat,
 586             'natatime returns expected iterator'
 587         );
 588
 589         @nat = ();
 590         $obj->natatime( 2, sub { push @nat, [@_] } );
 591
 592         is_deeply(
 593             [ [ 1, 2 ], [ 3, 4 ], [ 5, 6 ] ],
 594             \@nat,
 595             'natatime with function returns expected value'
 596         );
 597
 598         like( exception { $obj->natatime( {} ) }, qr/The n value passed to natatime must be an integer/, 'throws an error when passing a non integer to natatime' );
 599
 600         like( exception { $obj->natatime( 2, {} ) }, qr/The second argument passed to natatime must be a code reference/, 'throws an error when passing a non code ref to natatime' );
 601
 602         $it = $obj->natatime_curried();
 603         @nat = ();
 604         while ( my @v = $it->() ) {
 605             push @nat, \@v;
 606         }
 607
 608         is_deeply(
 609             [ [ 1, 2 ], [ 3, 4 ], [ 5, 6 ] ],
 610             \@nat,
 611             'natatime_curried returns expected iterator'
 612         );
 613
 614         @nat = ();
 615         $obj->natatime_curried( sub { push @nat, [@_] } );
 616
 617         is_deeply(
 618             [ [ 1, 2 ], [ 3, 4 ], [ 5, 6 ] ],
 619             \@nat,
 620             'natatime_curried with function returns expected value'
 621         );
 622
 623         like( exception { $obj->natatime_curried( {} ) }, qr/The second argument passed to natatime must be a code reference/, 'throws an error when passing a non code ref to natatime_curried' );
 624
 625         if ( $class->meta->get_attribute('_values')->is_lazy ) {
 626             my $obj = $class->new;
 627
 628             is( $obj->count, 2, 'count is 2 (lazy init)' );
 629
 630             $obj->_clear_values;
 631
 632             is_deeply(
 633                 [ $obj->elements ], [ 42, 84 ],
 634                 'elements contains default with lazy init'
 635             );
 636
 637             $obj->_clear_values;
 638
 639             $obj->push(2);
 640
 641             is_deeply(
 642                 $obj->_values, [ 42, 84, 2 ],
 643                 'push works with lazy init'
 644             );
 645
 646             $obj->_clear_values;
 647
 648             $obj->unshift( 3, 4 );
 649
 650             is_deeply(
 651                 $obj->_values, [ 3, 4, 42, 84 ],
 652                 'unshift works with lazy init'
 653             );
 654         }
 655     }
 656     $class;
 657 }
 658
 659 done_testing;