t/040_type_constraints/001_util_type_constraints.t

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More tests => 85;
   7 use Test::Exception;
   8
   9 use Scalar::Util ();
  10
  11 use Moose::Util::TypeConstraints;
  12
  13
  14 type Number => where { Scalar::Util::looks_like_number($_) };
  15 type String
  16     => where { !ref($_) && !Number($_) }
  17     => message { "This is not a string ($_)" };
  18
  19 subtype Natural
  20         => as Number
  21         => where { $_ > 0 };
  22
  23 subtype NaturalLessThanTen
  24         => as Natural
  25         => where { $_ < 10 }
  26         => message { "The number '$_' is not less than 10" };
  27
  28 Moose::Util::TypeConstraints->export_type_constraints_as_functions();
  29
  30 ok(Number(5), '... this is a Num');
  31 ok(!defined(Number('Foo')), '... this is not a Num');
  32 {
  33     my $number_tc = Moose::Util::TypeConstraints::find_type_constraint('Number');
  34     is("$number_tc", 'Number', '... type constraint stringifies to name');
  35 }
  36
  37 ok(String('Foo'), '... this is a Str');
  38 ok(!defined(String(5)), '... this is not a Str');
  39
  40 ok(Natural(5), '... this is a Natural');
  41 is(Natural(-5), undef, '... this is not a Natural');
  42 is(Natural('Foo'), undef, '... this is not a Natural');
  43
  44 ok(NaturalLessThanTen(5), '... this is a NaturalLessThanTen');
  45 is(NaturalLessThanTen(12), undef, '... this is not a NaturalLessThanTen');
  46 is(NaturalLessThanTen(-5), undef, '... this is not a NaturalLessThanTen');
  47 is(NaturalLessThanTen('Foo'), undef, '... this is not a NaturalLessThanTen');
  48
  49 # anon sub-typing
  50
  51 my $negative = subtype Number => where  { $_ < 0 };
  52 ok(defined $negative, '... got a value back from negative');
  53 isa_ok($negative, 'Moose::Meta::TypeConstraint');
  54
  55 ok($negative->check(-5), '... this is a negative number');
  56 ok(!defined($negative->check(5)), '... this is not a negative number');
  57 is($negative->check('Foo'), undef, '... this is not a negative number');
  58
  59 ok($negative->is_subtype_of('Number'), '... $negative is a subtype of Number');
  60 ok(!$negative->is_subtype_of('String'), '... $negative is not a subtype of String');
  61
  62 my $negative2 = subtype Number => where { $_ < 0 } => message {"$_ is not a negative number"};
  63
  64 ok(defined $negative2, '... got a value back from negative');
  65 isa_ok($negative2, 'Moose::Meta::TypeConstraint');
  66
  67 ok($negative2->check(-5), '... this is a negative number');
  68 ok(!defined($negative2->check(5)), '... this is not a negative number');
  69 is($negative2->check('Foo'), undef, '... this is not a negative number');
  70
  71 ok($negative2->is_subtype_of('Number'), '... $negative2 is a subtype of Number');
  72 ok(!$negative2->is_subtype_of('String'), '... $negative is not a subtype of String');
  73
  74 ok($negative2->has_message, '... it has a message');
  75 is($negative2->validate(2),
  76    '2 is not a negative number',
  77    '... validated unsuccessfully (got error)');
  78
  79 # check some meta-details
  80
  81 my $natural_less_than_ten = find_type_constraint('NaturalLessThanTen');
  82 isa_ok($natural_less_than_ten, 'Moose::Meta::TypeConstraint');
  83
  84 ok($natural_less_than_ten->is_subtype_of('Natural'), '... NaturalLessThanTen is subtype of Natural');
  85 ok($natural_less_than_ten->is_subtype_of('Number'), '... NaturalLessThanTen is subtype of Number');
  86 ok(!$natural_less_than_ten->is_subtype_of('String'), '... NaturalLessThanTen is not subtype of String');
  87
  88 ok($natural_less_than_ten->has_message, '... it has a message');
  89
  90 ok(!defined($natural_less_than_ten->validate(5)), '... validated successfully (no error)');
  91
  92 is($natural_less_than_ten->validate(15),
  93    "The number '15' is not less than 10",
  94    '... validated unsuccessfully (got error)');
  95
  96 my $natural = find_type_constraint('Natural');
  97 isa_ok($natural, 'Moose::Meta::TypeConstraint');
  98
  99 ok($natural->is_subtype_of('Number'), '... Natural is a subtype of Number');
 100 ok(!$natural->is_subtype_of('String'), '... Natural is not a subtype of String');
 101
 102 ok(!$natural->has_message, '... it does not have a message');
 103
 104 ok(!defined($natural->validate(5)), '... validated successfully (no error)');
 105
 106 is($natural->validate(-5),
 107   "Validation failed for 'Natural' failed with value -5",
 108   '... validated unsuccessfully (got error)');
 109
 110 my $string = find_type_constraint('String');
 111 isa_ok($string, 'Moose::Meta::TypeConstraint');
 112
 113 ok($string->has_message, '... it does have a message');
 114
 115 ok(!defined($string->validate("Five")), '... validated successfully (no error)');
 116
 117 is($string->validate(5),
 118 "This is not a string (5)",
 119 '... validated unsuccessfully (got error)');
 120
 121 lives_ok { Moose::Meta::Attribute->new('bob', isa => 'Spong') }
 122   'meta-attr construction ok even when type constraint utils loaded first';
 123
 124 # Test type constraint predicate return values.
 125
 126 foreach my $predicate (qw/equals is_subtype_of is_a_type_of/) {
 127     ok( !defined $string->$predicate('DoesNotExist'), "$predicate predicate returns undef for non existant constraint");
 128 }
 129
 130 # Test adding things which don't look like types to the registry throws an exception
 131
 132 my $r = Moose::Util::TypeConstraints->get_type_constraint_registry;
 133 throws_ok {$r->add_type_constraint()} qr/not a valid type constraint/, '->add_type_constraint(undef) throws';
 134 throws_ok {$r->add_type_constraint('foo')} qr/not a valid type constraint/, '->add_type_constraint("foo") throws';
 135 throws_ok {$r->add_type_constraint(bless {}, 'SomeClass')} qr/not a valid type constraint/, '->add_type_constraint(SomeClass->new) throws';
 136
 137 # Test some specific things that in the past did not work,
 138 # specifically weird variations on anon subtypes.
 139
 140 {
 141     my $subtype = subtype as 'Str';
 142     isa_ok( $subtype, 'Moose::Meta::TypeConstraint', 'got an anon subtype' );
 143     is( $subtype->parent->name, 'Str', 'parent is Str' );
 144     # This test sucks but is the best we can do
 145     is( $subtype->constraint->(), 1,
 146         'subtype has the null constraint' );
 147     ok( ! $subtype->has_message, 'subtype has no message' );
 148 }
 149
 150 {
 151     my $subtype = subtype as 'ArrayRef[Num|Str]';
 152     isa_ok( $subtype, 'Moose::Meta::TypeConstraint', 'got an anon subtype' );
 153     is( $subtype->parent->name, 'ArrayRef[Num|Str]', 'parent is ArrayRef[Num|Str]' );
 154     ok( ! $subtype->has_message, 'subtype has no message' );
 155 }
 156
 157 {
 158     my $subtype = subtype 'ArrayRef[Num|Str]' => message { 'foo' };
 159     isa_ok( $subtype, 'Moose::Meta::TypeConstraint', 'got an anon subtype' );
 160     is( $subtype->parent->name, 'ArrayRef[Num|Str]', 'parent is ArrayRef[Num|Str]' );
 161     ok( $subtype->has_message, 'subtype does have a message' );
 162 }
 163
 164 # alternative sugar-less calling style which is documented as legit:
 165 {
 166     my $subtype = subtype( 'MyStr', { as => 'Str' } );
 167     isa_ok( $subtype, 'Moose::Meta::TypeConstraint', 'got a subtype' );
 168     is( $subtype->name, 'MyStr', 'name is MyStr' );
 169     is( $subtype->parent->name, 'Str', 'parent is Str' );
 170 }
 171
 172 {
 173     my $subtype = subtype( { as => 'Str' } );
 174     isa_ok( $subtype, 'Moose::Meta::TypeConstraint', 'got a subtype' );
 175     is( $subtype->name, '__ANON__', 'name is __ANON__' );
 176     is( $subtype->parent->name, 'Str', 'parent is Str' );
 177 }
 178
 179 {
 180     my $subtype = subtype( { as => 'Str', where => sub { /X/ } } );
 181     isa_ok( $subtype, 'Moose::Meta::TypeConstraint', 'got a subtype' );
 182     is( $subtype->name, '__ANON__', 'name is __ANON__' );
 183     is( $subtype->parent->name, 'Str', 'parent is Str' );
 184     ok( $subtype->check('FooX'), 'constraint accepts FooX' );
 185     ok( ! $subtype->check('Foo'), 'constraint reject Foo' );
 186 }
 187
 188 {
 189     throws_ok { subtype 'Foo' } qr/cannot consist solely of a name/,
 190         'Cannot call subtype with a single string argument';
 191 }
 192
 193 # Back-compat for being called without sugar. Previously, calling with
 194 # sugar was indistinguishable from calling directly.
 195
 196 {
 197     my $type = type( 'Number2', sub { Scalar::Util::looks_like_number($_) } );
 198
 199     ok( $type->check(5), '... this is a Num' );
 200     ok( ! $type->check('Foo'), '... this is not a Num' );
 201 }
 202
 203 {
 204     # anon subtype
 205     my $subtype = subtype( 'Number2', sub { $_ > 0 } );
 206
 207     ok( $subtype->check(5), '... this is a Natural');
 208     ok( ! $subtype->check(-5), '... this is not a Natural');
 209     ok( ! $subtype->check('Foo'), '... this is not a Natural');
 210 }
 211
 212 {
 213     my $subtype = subtype( 'Natural2', 'Number2', sub { $_ > 0 } );
 214
 215     ok( $subtype->check(5), '... this is a Natural');
 216     ok( ! $subtype->check(-5), '... this is not a Natural');
 217     ok( ! $subtype->check('Foo'), '... this is not a Natural');
 218 }
 219
 220 {
 221     my $subtype = subtype( 'Natural3', 'Number2' );
 222
 223     ok( $subtype->check(5), '... this is a Natural');
 224     ok( $subtype->check(-5), '... this is a Natural');
 225     ok( ! $subtype->check('Foo'), '... this is not a Natural');
 226 }
 227