lib/Moose/Meta/TypeConstraint/Role.pm

   1 package Moose::Meta::TypeConstraint::Role;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 use Scalar::Util 'blessed';
   8 use Moose::Util::TypeConstraints ();
   9
  10 use base 'Moose::Meta::TypeConstraint';
  11
  12 __PACKAGE__->meta->add_attribute('role' => (
  13     reader => 'role',
  14 ));
  15
  16 sub new {
  17     my ( $class, %args ) = @_;
  18
  19     $args{parent} = Moose::Util::TypeConstraints::find_type_constraint('Object');
  20
  21     my $role_name = $args{role};
  22     $args{constraint} = sub { Moose::Util::does_role( $_[0], $role_name ) };
  23
  24     my $self = $class->_new( \%args );
  25
  26     $self->_create_hand_optimized_type_constraint;
  27     $self->compile_type_constraint();
  28
  29     return $self;
  30 }
  31
  32 sub _create_hand_optimized_type_constraint {
  33     my $self = shift;
  34     my $role = $self->role;
  35     $self->hand_optimized_type_constraint(
  36         sub { Moose::Util::does_role($_[0], $role) }
  37     );
  38 }
  39
  40 sub parents {
  41     my $self = shift;
  42     return (
  43         $self->parent,
  44         map {
  45             # FIXME find_type_constraint might find a TC named after the role but that isn't really it
  46             # I did this anyway since it's a convention that preceded TypeConstraint::Role, and it should DWIM
  47             # if anybody thinks this problematic please discuss on IRC.
  48             # a possible fix is to add by attr indexing to the type registry to find types of a certain property
  49             # regardless of their name
  50             Moose::Util::TypeConstraints::find_type_constraint($_)
  51                 ||
  52             __PACKAGE__->new( role => $_, name => "__ANON__" )
  53         } @{ Class::MOP::class_of($self->role)->get_roles },
  54     );
  55 }
  56
  57 sub equals {
  58     my ( $self, $type_or_name ) = @_;
  59
  60     my $other = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  61
  62     return unless defined $other;
  63     return unless $other->isa(__PACKAGE__);
  64
  65     return $self->role eq $other->role;
  66 }
  67
  68 sub is_a_type_of {
  69     my ($self, $type_or_name) = @_;
  70
  71     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  72
  73     ($self->equals($type) || $self->is_subtype_of($type_or_name));
  74 }
  75
  76 sub is_subtype_of {
  77     my ($self, $type_or_name_or_role ) = @_;
  78
  79     if ( not ref $type_or_name_or_role ) {
  80         # it might be a role
  81         return 1 if Class::MOP::class_of($self->role)->does_role( $type_or_name_or_role );
  82     }
  83
  84     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name_or_role);
  85
  86     return unless defined $type;
  87
  88     if ( $type->isa(__PACKAGE__) ) {
  89         # if $type_or_name_or_role isn't a role, it might be the TC name of another ::Role type
  90         # or it could also just be a type object in this branch
  91         return Class::MOP::class_of($self->role)->does_role( $type->role );
  92     } else {
  93         # the only other thing we are a subtype of is Object
  94         $self->SUPER::is_subtype_of($type);
  95     }
  96 }
  97
  98 sub create_child_type {
  99     my ($self, @args) = @_;
 100     return Moose::Meta::TypeConstraint->new(@args, parent => $self);
 101 }
 102
 103 1;
 104
 105 # ABSTRACT: Role/TypeConstraint parallel hierarchy
 106
 107 __END__
 108
 109 =pod
 110
 111 =head1 DESCRIPTION
 112
 113 This class represents type constraints for a role.
 114
 115 =head1 INHERITANCE
 116
 117 C<Moose::Meta::TypeConstraint::Role> is a subclass of
 118 L<Moose::Meta::TypeConstraint>.
 119
 120 =head1 METHODS
 121
 122 =over 4
 123
 124 =item B<< Moose::Meta::TypeConstraint::Role->new(%options) >>
 125
 126 This creates a new role type constraint based on the given
 127 C<%options>.
 128
 129 It takes the same options as its parent, with two exceptions. First,
 130 it requires an additional option, C<role>, which is name of the
 131 constraint's role.  Second, it automatically sets the parent to the
 132 C<Object> type.
 133
 134 The constructor also overrides the hand optimized type constraint with
 135 one it creates internally.
 136
 137 =item B<< $constraint->role >>
 138
 139 Returns the role name associated with the constraint.
 140
 141 =item B<< $constraint->parents >>
 142
 143 Returns all the type's parent types, corresponding to the roles that
 144 its role does.
 145
 146 =item B<< $constraint->is_subtype_of($type_name_or_object) >>
 147
 148 If the given type is also a role type, then this checks that the
 149 type's role does the other type's role.
 150
 151 Otherwise it falls back to the implementation in
 152 L<Moose::Meta::TypeConstraint>.
 153
 154 =item B<< $constraint->create_child_type(%options) >>
 155
 156 This returns a new L<Moose::Meta::TypeConstraint> object with the type
 157 as its parent.
 158
 159 Note that it does I<not> return a C<Moose::Meta::TypeConstraint::Role>
 160 object!
 161
 162 =back
 163
 164 =head1 BUGS
 165
 166 See L<Moose/BUGS> for details on reporting bugs.
 167
 168 =cut