lib/Moose/Meta/TypeConstraint/Role.pm

   1 package Moose::Meta::TypeConstraint::Role;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 use Scalar::Util 'blessed';
   8 use Moose::Util::TypeConstraints ();
   9
  10 our $VERSION   = '0.88';
  11 $VERSION = eval $VERSION;
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 use base 'Moose::Meta::TypeConstraint';
  15
  16 __PACKAGE__->meta->add_attribute('role' => (
  17     reader => 'role',
  18 ));
  19
  20 sub new {
  21     my ( $class, %args ) = @_;
  22
  23     $args{parent} = Moose::Util::TypeConstraints::find_type_constraint('Object');
  24     my $self      = $class->_new(\%args);
  25
  26     $self->_create_hand_optimized_type_constraint;
  27     $self->compile_type_constraint();
  28
  29     return $self;
  30 }
  31
  32 sub _create_hand_optimized_type_constraint {
  33     my $self = shift;
  34     my $role = $self->role;
  35     $self->hand_optimized_type_constraint(
  36         sub { Moose::Util::does_role($_[0], $role) }
  37     );
  38 }
  39
  40 sub parents {
  41     my $self = shift;
  42     return (
  43         $self->parent,
  44         map {
  45             # FIXME find_type_constraint might find a TC named after the role but that isn't really it
  46             # I did this anyway since it's a convention that preceded TypeConstraint::Role, and it should DWIM
  47             # if anybody thinks this problematic please discuss on IRC.
  48             # a possible fix is to add by attr indexing to the type registry to find types of a certain property
  49             # regardless of their name
  50             Moose::Util::TypeConstraints::find_type_constraint($_)
  51                 ||
  52             __PACKAGE__->new( role => $_, name => "__ANON__" )
  53         } @{ Class::MOP::class_of($self->role)->get_roles },
  54     );
  55 }
  56
  57 sub equals {
  58     my ( $self, $type_or_name ) = @_;
  59
  60     my $other = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  61
  62     return unless defined $other;
  63     return unless $other->isa(__PACKAGE__);
  64
  65     return $self->role eq $other->role;
  66 }
  67
  68 sub is_a_type_of {
  69     my ($self, $type_or_name) = @_;
  70
  71     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  72
  73     ($self->equals($type) || $self->is_subtype_of($type_or_name));
  74 }
  75
  76 sub is_subtype_of {
  77     my ($self, $type_or_name_or_role ) = @_;
  78
  79     if ( not ref $type_or_name_or_role ) {
  80         # it might be a role
  81         return 1 if Class::MOP::class_of($self->role)->does_role( $type_or_name_or_role );
  82     }
  83
  84     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name_or_role);
  85
  86     return unless defined $type;
  87
  88     if ( $type->isa(__PACKAGE__) ) {
  89         # if $type_or_name_or_role isn't a role, it might be the TC name of another ::Role type
  90         # or it could also just be a type object in this branch
  91         return Class::MOP::class_of($self->role)->does_role( $type->role );
  92     } else {
  93         # the only other thing we are a subtype of is Object
  94         $self->SUPER::is_subtype_of($type);
  95     }
  96 }
  97
  98 sub create_child_type {
  99     my ($self, @args) = @_;
 100     return Moose::Meta::TypeConstraint->new(@args, parent => $self);
 101 }
 102
 103 1;
 104
 105 __END__
 106
 107 =pod
 108
 109 =head1 NAME
 110
 111 Moose::Meta::TypeConstraint::Role - Role/TypeConstraint parallel hierarchy
 112
 113 =head1 DESCRIPTION
 114
 115 This class represents type constraints for a role.
 116
 117 =head1 INHERITANCE
 118
 119 C<Moose::Meta::TypeConstraint::Role> is a subclass of
 120 L<Moose::Meta::TypeConstraint>.
 121
 122 =head1 METHODS
 123
 124 =over 4
 125
 126 =item B<< Moose::Meta::TypeConstraint::Role->new(%options) >>
 127
 128 This creates a new role type constraint based on the given
 129 C<%options>.
 130
 131 It takes the same options as its parent, with two exceptions. First,
 132 it requires an additional option, C<role>, which is name of the
 133 constraint's role.  Second, it automatically sets the parent to the
 134 C<Object> type.
 135
 136 The constructor also overrides the hand optimized type constraint with
 137 one it creates internally.
 138
 139 =item B<< $constraint->role >>
 140
 141 Returns the role name associated with the constraint.
 142
 143 =item B<< $constraint->parents >>
 144
 145 Returns all the type's parent types, corresponding to the roles that
 146 its role does.
 147
 148 =item B<< $constraint->is_subtype_of($type_name_or_object) >>
 149
 150 If the given type is also a role type, then this checks that the
 151 type's role does the other type's role.
 152
 153 Otherwise it falls back to the implementation in
 154 L<Moose::Meta::TypeConstraint>.
 155
 156 =item B<< $constraint->create_child_type(%options) >>
 157
 158 This returns a new L<Moose::Meta::TypeConstraint> object with the type
 159 as its parent.
 160
 161 Note that it does I<not> return a C<Moose::Meta::TypeConstraint::Role>
 162 object!
 163
 164 =back
 165
 166 =head1 BUGS
 167
 168 All complex software has bugs lurking in it, and this module is no
 169 exception. If you find a bug please either email me, or add the bug
 170 to cpan-RT.
 171
 172 =head1 AUTHOR
 173
 174 Yuval Kogman E<lt>nothingmuch@cpan.orgE<gt>
 175
 176 =head1 COPYRIGHT AND LICENSE
 177
 178 Copyright 2006-2009 by Infinity Interactive, Inc.
 179
 180 L<http://www.iinteractive.com>
 181
 182 This library is free software; you can redistribute it and/or modify
 183 it under the same terms as Perl itself.
 184
 185 =cut