lib/Moose/Meta/TypeConstraint/Role.pm

   1 package Moose::Meta::TypeConstraint::Role;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 use B;
   8 use Scalar::Util 'blessed';
   9 use Moose::Util::TypeConstraints ();
  10
  11 use base 'Moose::Meta::TypeConstraint';
  12
  13 __PACKAGE__->meta->add_attribute('role' => (
  14     reader => 'role',
  15     Class::MOP::_definition_context(),
  16 ));
  17
  18 my $inliner = sub {
  19     my $self = shift;
  20     my $val  = shift;
  21
  22     return 'Moose::Util::does_role('
  23              . $val . ', '
  24              . B::perlstring($self->role)
  25          . ')';
  26 };
  27
  28 sub new {
  29     my ( $class, %args ) = @_;
  30
  31     $args{parent} = Moose::Util::TypeConstraints::find_type_constraint('Object');
  32
  33     my $role_name = $args{role};
  34     $args{constraint} = sub { Moose::Util::does_role( $_[0], $role_name ) };
  35
  36     $args{inlined} = $inliner;
  37
  38     my $self = $class->SUPER::new( \%args );
  39
  40     $self->_create_hand_optimized_type_constraint;
  41     $self->compile_type_constraint();
  42
  43     return $self;
  44 }
  45
  46 sub _create_hand_optimized_type_constraint {
  47     my $self = shift;
  48     my $role = $self->role;
  49     $self->hand_optimized_type_constraint(
  50         sub { Moose::Util::does_role($_[0], $role) }
  51     );
  52 }
  53
  54 sub parents {
  55     my $self = shift;
  56     return (
  57         $self->parent,
  58         map {
  59             # FIXME find_type_constraint might find a TC named after the role but that isn't really it
  60             # I did this anyway since it's a convention that preceded TypeConstraint::Role, and it should DWIM
  61             # if anybody thinks this problematic please discuss on IRC.
  62             # a possible fix is to add by attr indexing to the type registry to find types of a certain property
  63             # regardless of their name
  64             Moose::Util::TypeConstraints::find_type_constraint($_)
  65                 ||
  66             __PACKAGE__->new( role => $_, name => "__ANON__" )
  67         } @{ Class::MOP::class_of($self->role)->get_roles },
  68     );
  69 }
  70
  71 sub equals {
  72     my ( $self, $type_or_name ) = @_;
  73
  74     my $other = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  75
  76     return unless defined $other;
  77     return unless $other->isa(__PACKAGE__);
  78
  79     return $self->role eq $other->role;
  80 }
  81
  82 sub is_a_type_of {
  83     my ($self, $type_or_name) = @_;
  84
  85     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  86
  87     ($self->equals($type) || $self->is_subtype_of($type_or_name));
  88 }
  89
  90 sub is_subtype_of {
  91     my ($self, $type_or_name_or_role ) = @_;
  92
  93     if ( not ref $type_or_name_or_role ) {
  94         # it might be a role
  95         my $class = Class::MOP::class_of($self->role);
  96         return 1 if defined($class) && $class->does_role( $type_or_name_or_role );
  97     }
  98
  99     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name_or_role);
 100
 101     return unless defined $type;
 102
 103     if ( $type->isa(__PACKAGE__) ) {
 104         # if $type_or_name_or_role isn't a role, it might be the TC name of another ::Role type
 105         # or it could also just be a type object in this branch
 106         my $class = Class::MOP::class_of($self->role);
 107         return defined($class) && $class->does_role( $type->role );
 108     } else {
 109         # the only other thing we are a subtype of is Object
 110         $self->SUPER::is_subtype_of($type);
 111     }
 112 }
 113
 114 sub create_child_type {
 115     my ($self, @args) = @_;
 116     return Moose::Meta::TypeConstraint->new(@args, parent => $self);
 117 }
 118
 119 1;
 120
 121 # ABSTRACT: Role/TypeConstraint parallel hierarchy
 122
 123 __END__
 124
 125 =pod
 126
 127 =head1 DESCRIPTION
 128
 129 This class represents type constraints for a role.
 130
 131 =head1 INHERITANCE
 132
 133 C<Moose::Meta::TypeConstraint::Role> is a subclass of
 134 L<Moose::Meta::TypeConstraint>.
 135
 136 =head1 METHODS
 137
 138 =over 4
 139
 140 =item B<< Moose::Meta::TypeConstraint::Role->new(%options) >>
 141
 142 This creates a new role type constraint based on the given
 143 C<%options>.
 144
 145 It takes the same options as its parent, with two exceptions. First,
 146 it requires an additional option, C<role>, which is name of the
 147 constraint's role.  Second, it automatically sets the parent to the
 148 C<Object> type.
 149
 150 The constructor also overrides the hand optimized type constraint with
 151 one it creates internally.
 152
 153 =item B<< $constraint->role >>
 154
 155 Returns the role name associated with the constraint.
 156
 157 =item B<< $constraint->parents >>
 158
 159 Returns all the type's parent types, corresponding to the roles that
 160 its role does.
 161
 162 =item B<< $constraint->is_subtype_of($type_name_or_object) >>
 163
 164 If the given type is also a role type, then this checks that the
 165 type's role does the other type's role.
 166
 167 Otherwise it falls back to the implementation in
 168 L<Moose::Meta::TypeConstraint>.
 169
 170 =item B<< $constraint->create_child_type(%options) >>
 171
 172 This returns a new L<Moose::Meta::TypeConstraint> object with the type
 173 as its parent.
 174
 175 Note that it does I<not> return a C<Moose::Meta::TypeConstraint::Role>
 176 object!
 177
 178 =back
 179
 180 =head1 BUGS
 181
 182 See L<Moose/BUGS> for details on reporting bugs.
 183
 184 =cut