lib/Moose/Meta/TypeConstraint/Parameterized.pm

   1 package Moose::Meta::TypeConstraint::Parameterized;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 use Scalar::Util 'blessed';
   8 use Moose::Util::TypeConstraints;
   9 use Moose::Meta::TypeConstraint::Parameterizable;
  10
  11 our $VERSION   = '0.91';
  12 $VERSION = eval $VERSION;
  13 our $AUTHORITY = 'cpan:STEVAN';
  14
  15 use base 'Moose::Meta::TypeConstraint';
  16
  17 __PACKAGE__->meta->add_attribute('type_parameter' => (
  18     accessor  => 'type_parameter',
  19     predicate => 'has_type_parameter',
  20 ));
  21
  22 sub equals {
  23     my ( $self, $type_or_name ) = @_;
  24
  25     my $other = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  26
  27     return unless $other->isa(__PACKAGE__);
  28
  29     return (
  30         $self->type_parameter->equals( $other->type_parameter )
  31             and
  32         $self->parent->equals( $other->parent )
  33     );
  34 }
  35
  36 sub compile_type_constraint {
  37     my $self = shift;
  38
  39     unless ( $self->has_type_parameter ) {
  40         require Moose;
  41         Moose->throw_error("You cannot create a Higher Order type without a type parameter");
  42     }
  43
  44     my $type_parameter = $self->type_parameter;
  45
  46     unless ( blessed $type_parameter && $type_parameter->isa('Moose::Meta::TypeConstraint') ) {
  47         require Moose;
  48         Moose->throw_error("The type parameter must be a Moose meta type");
  49     }
  50
  51     foreach my $type (Moose::Util::TypeConstraints::get_all_parameterizable_types()) {
  52         if (my $constraint = $type->generate_constraint_for($self)) {
  53             $self->_set_constraint($constraint);
  54             return $self->SUPER::compile_type_constraint;
  55         }
  56     }
  57
  58     # if we get here, then we couldn't
  59     # find a way to parameterize this type
  60     require Moose;
  61     Moose->throw_error("The " . $self->name . " constraint cannot be used, because "
  62           . $self->parent->name . " doesn't subtype or coerce from a parameterizable type.");
  63 }
  64
  65 sub create_child_type {
  66     my ($self, %opts) = @_;
  67     return Moose::Meta::TypeConstraint::Parameterizable->new(%opts, parent=>$self);
  68 }
  69
  70 1;
  71
  72 __END__
  73
  74
  75 =pod
  76
  77 =head1 NAME
  78
  79 Moose::Meta::TypeConstraint::Parameterized - Type constraints with a bound parameter (ArrayRef[Int])
  80
  81 =head1 METHODS
  82
  83 This class is intentionally not documented because the API is
  84 confusing and needs some work.
  85
  86 =head1 INHERITANCE
  87
  88 C<Moose::Meta::TypeConstraint::Parameterized> is a subclass of
  89 L<Moose::Meta::TypeConstraint>.
  90
  91 =head1 BUGS
  92
  93 All complex software has bugs lurking in it, and this module is no
  94 exception. If you find a bug please either email me, or add the bug
  95 to cpan-RT.
  96
  97 =head1 AUTHOR
  98
  99 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 100
 101 =head1 COPYRIGHT AND LICENSE
 102
 103 Copyright 2006-2009 by Infinity Interactive, Inc.
 104
 105 L<http://www.iinteractive.com>
 106
 107 This library is free software; you can redistribute it and/or modify
 108 it under the same terms as Perl itself.
 109
 110 =cut