lib/Moose/Meta/TypeConstraint/Class.pm

   1 package Moose::Meta::TypeConstraint::Class;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 use Scalar::Util 'blessed';
   8 use Moose::Util::TypeConstraints ();
   9
  10 our $VERSION   = '0.67';
  11 $VERSION = eval $VERSION;
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 use base 'Moose::Meta::TypeConstraint';
  15
  16 __PACKAGE__->meta->add_attribute('class' => (
  17     reader => 'class',
  18 ));
  19
  20 sub new {
  21     my ( $class, %args ) = @_;
  22
  23     $args{parent} = Moose::Util::TypeConstraints::find_type_constraint('Object');
  24     my $self      = $class->_new(\%args);
  25
  26     $self->_create_hand_optimized_type_constraint;
  27     $self->compile_type_constraint();
  28
  29     return $self;
  30 }
  31
  32 sub _create_hand_optimized_type_constraint {
  33     my $self = shift;
  34     my $class = $self->class;
  35     $self->hand_optimized_type_constraint(
  36         sub {
  37             blessed( $_[0] ) && $_[0]->isa($class)
  38         }
  39     );
  40 }
  41
  42 sub parents {
  43     my $self = shift;
  44     return (
  45         $self->parent,
  46         map {
  47             # FIXME find_type_constraint might find a TC named after the class but that isn't really it
  48             # I did this anyway since it's a convention that preceded TypeConstraint::Class, and it should DWIM
  49             # if anybody thinks this problematic please discuss on IRC.
  50             # a possible fix is to add by attr indexing to the type registry to find types of a certain property
  51             # regardless of their name
  52             Moose::Util::TypeConstraints::find_type_constraint($_)
  53                 ||
  54             __PACKAGE__->new( class => $_, name => "__ANON__" )
  55         } $self->class->meta->superclasses,
  56     );
  57 }
  58
  59 sub equals {
  60     my ( $self, $type_or_name ) = @_;
  61
  62     my $other = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  63
  64     return unless defined $other;
  65     return unless $other->isa(__PACKAGE__);
  66
  67     return $self->class eq $other->class;
  68 }
  69
  70 sub is_a_type_of {
  71     my ($self, $type_or_name) = @_;
  72
  73     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  74
  75     ($self->equals($type) || $self->is_subtype_of($type_or_name));
  76 }
  77
  78 sub is_subtype_of {
  79     my ($self, $type_or_name_or_class ) = @_;
  80
  81     if ( not ref $type_or_name_or_class ) {
  82         # it might be a class
  83         return 1 if $self->class->isa( $type_or_name_or_class );
  84     }
  85
  86     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name_or_class);
  87
  88     return unless defined $type;
  89
  90     if ( $type->isa(__PACKAGE__) ) {
  91         # if $type_or_name_or_class isn't a class, it might be the TC name of another ::Class type
  92         # or it could also just be a type object in this branch
  93         return $self->class->isa( $type->class );
  94     } else {
  95         # the only other thing we are a subtype of is Object
  96         $self->SUPER::is_subtype_of($type);
  97     }
  98 }
  99
 100 # This is a bit counter-intuitive, but a child type of a Class type
 101 # constraint is not itself a Class type constraint (it has no class
 102 # attribute). This whole create_child_type thing needs some changing
 103 # though, probably making MMC->new a factory or something.
 104 sub create_child_type {
 105     my ($self, @args) = @_;
 106     return Moose::Meta::TypeConstraint->new(@args, parent => $self);
 107 }
 108
 109 1;
 110
 111 __END__
 112
 113 =pod
 114
 115 =head1 NAME
 116
 117 Moose::Meta::TypeConstraint::Class - Class/TypeConstraint parallel hierarchy
 118
 119 =head1 METHODS
 120
 121 =over 4
 122
 123 =item B<new>
 124
 125 =item B<class>
 126
 127 =item B<hand_optimized_type_constraint>
 128
 129 =item B<has_hand_optimized_type_constraint>
 130
 131 =item B<equals>
 132
 133 =item B<is_a_type_of>
 134
 135 =item B<is_subtype_of>
 136
 137 =item B<parents>
 138
 139 Return all the parent types, corresponding to the parent classes.
 140
 141 =item B<meta>
 142
 143 =item B<create_child_type>
 144
 145 =back
 146
 147 =head1 BUGS
 148
 149 All complex software has bugs lurking in it, and this module is no
 150 exception. If you find a bug please either email me, or add the bug
 151 to cpan-RT.
 152
 153 =head1 AUTHOR
 154
 155 Yuval Kogman E<lt>nothingmuch@cpan.orgE<gt>
 156
 157 =head1 COPYRIGHT AND LICENSE
 158
 159 Copyright 2006-2009 by Infinity Interactive, Inc.
 160
 161 L<http://www.iinteractive.com>
 162
 163 This library is free software; you can redistribute it and/or modify
 164 it under the same terms as Perl itself.
 165
 166 =cut