lib/Moose/Meta/TypeConstraint/Class.pm

   1 package Moose::Meta::TypeConstraint::Class;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 use Scalar::Util 'blessed';
   8 use Moose::Util::TypeConstraints ();
   9
  10 our $VERSION   = '0.56';
  11 $VERSION = eval $VERSION;
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 use base 'Moose::Meta::TypeConstraint';
  15
  16 __PACKAGE__->meta->add_attribute('class' => (
  17     reader => 'class',
  18 ));
  19
  20 sub new {
  21     my ( $class, %args ) = @_;
  22
  23     $args{parent} = Moose::Util::TypeConstraints::find_type_constraint('Object');
  24     my $self      = $class->_new(\%args);
  25
  26     $self->_create_hand_optimized_type_constraint;
  27     $self->compile_type_constraint();
  28
  29     return $self;
  30 }
  31
  32 sub _create_hand_optimized_type_constraint {
  33     my $self = shift;
  34     my $class = $self->class;
  35     $self->hand_optimized_type_constraint(
  36         sub {
  37             blessed( $_[0] ) && $_[0]->isa($class)
  38         }
  39     );
  40 }
  41
  42 sub parents {
  43     my $self = shift;
  44     return (
  45         $self->parent,
  46         map {
  47             # FIXME find_type_constraint might find a TC named after the class but that isn't really it
  48             # I did this anyway since it's a convention that preceded TypeConstraint::Class, and it should DWIM
  49             # if anybody thinks this problematic please discuss on IRC.
  50             # a possible fix is to add by attr indexing to the type registry to find types of a certain property
  51             # regardless of their name
  52             Moose::Util::TypeConstraints::find_type_constraint($_)
  53                 ||
  54             __PACKAGE__->new( class => $_, name => "__ANON__" )
  55         } $self->class->meta->superclasses,
  56     );
  57 }
  58
  59 sub equals {
  60     my ( $self, $type_or_name ) = @_;
  61
  62     my $other = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  63
  64     return unless $other->isa(__PACKAGE__);
  65
  66     return $self->class eq $other->class;
  67 }
  68
  69 sub is_a_type_of {
  70     my ($self, $type_or_name) = @_;
  71
  72     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  73
  74     ($self->equals($type) || $self->is_subtype_of($type_or_name));
  75 }
  76
  77 sub is_subtype_of {
  78     my ($self, $type_or_name_or_class ) = @_;
  79
  80     if ( not ref $type_or_name_or_class ) {
  81         # it might be a class
  82         return 1 if $self->class->isa( $type_or_name_or_class );
  83     }
  84
  85     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name_or_class);
  86
  87     if ( $type->isa(__PACKAGE__) ) {
  88         # if $type_or_name_or_class isn't a class, it might be the TC name of another ::Class type
  89         # or it could also just be a type object in this branch
  90         return $self->class->isa( $type->class );
  91     } else {
  92         # the only other thing we are a subtype of is Object
  93         $self->SUPER::is_subtype_of($type);
  94     }
  95 }
  96
  97 1;
  98
  99 __END__
 100
 101 =pod
 102
 103 =head1 NAME
 104
 105 Moose::Meta::TypeConstraint::Class - Class/TypeConstraint parallel hierarchy
 106
 107 =head1 METHODS
 108
 109 =over 4
 110
 111 =item B<new>
 112
 113 =item B<class>
 114
 115 =item B<hand_optimized_type_constraint>
 116
 117 =item B<has_hand_optimized_type_constraint>
 118
 119 =item B<equals>
 120
 121 =item B<is_a_type_of>
 122
 123 =item B<is_subtype_of>
 124
 125 =item B<parents>
 126
 127 Return all the parent types, corresponding to the parent classes.
 128
 129 =item B<meta>
 130
 131 =back
 132
 133 =head1 BUGS
 134
 135 All complex software has bugs lurking in it, and this module is no
 136 exception. If you find a bug please either email me, or add the bug
 137 to cpan-RT.
 138
 139 =head1 AUTHOR
 140
 141 Yuval Kogman E<lt>nothingmuch@cpan.orgE<gt>
 142
 143 =head1 COPYRIGHT AND LICENSE
 144
 145 Copyright 2006-2008 by Infinity Interactive, Inc.
 146
 147 L<http://www.iinteractive.com>
 148
 149 This library is free software; you can redistribute it and/or modify
 150 it under the same terms as Perl itself.
 151
 152 =cut