lib/Moose/Meta/TypeConstraint/Class.pm

   1 package Moose::Meta::TypeConstraint::Class;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 use Scalar::Util 'blessed';
   8 use Moose::Util::TypeConstraints ();
   9
  10 our $VERSION   = '1.14';
  11 $VERSION = eval $VERSION;
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 use base 'Moose::Meta::TypeConstraint';
  15
  16 __PACKAGE__->meta->add_attribute('class' => (
  17     reader => 'class',
  18 ));
  19
  20 sub new {
  21     my ( $class, %args ) = @_;
  22
  23     $args{parent} = Moose::Util::TypeConstraints::find_type_constraint('Object');
  24     my $self      = $class->_new(\%args);
  25
  26     $self->_create_hand_optimized_type_constraint;
  27     $self->compile_type_constraint();
  28
  29     return $self;
  30 }
  31
  32 sub _create_hand_optimized_type_constraint {
  33     my $self = shift;
  34     my $class = $self->class;
  35     $self->hand_optimized_type_constraint(
  36         sub {
  37             blessed( $_[0] ) && blessed( $_[0] ) ne 'Regexp' && $_[0]->isa($class)
  38         }
  39     );
  40 }
  41
  42 sub parents {
  43     my $self = shift;
  44     return (
  45         $self->parent,
  46         map {
  47             # FIXME find_type_constraint might find a TC named after the class but that isn't really it
  48             # I did this anyway since it's a convention that preceded TypeConstraint::Class, and it should DWIM
  49             # if anybody thinks this problematic please discuss on IRC.
  50             # a possible fix is to add by attr indexing to the type registry to find types of a certain property
  51             # regardless of their name
  52             Moose::Util::TypeConstraints::find_type_constraint($_)
  53                 ||
  54             __PACKAGE__->new( class => $_, name => "__ANON__" )
  55         } Class::MOP::class_of($self->class)->superclasses,
  56     );
  57 }
  58
  59 sub equals {
  60     my ( $self, $type_or_name ) = @_;
  61
  62     my $other = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  63
  64     return unless defined $other;
  65     return unless $other->isa(__PACKAGE__);
  66
  67     return $self->class eq $other->class;
  68 }
  69
  70 sub is_a_type_of {
  71     my ($self, $type_or_name) = @_;
  72
  73     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name);
  74
  75     ($self->equals($type) || $self->is_subtype_of($type_or_name));
  76 }
  77
  78 sub is_subtype_of {
  79     my ($self, $type_or_name_or_class ) = @_;
  80
  81     my $type = Moose::Util::TypeConstraints::find_type_constraint($type_or_name_or_class);
  82
  83     if ( not defined $type ) {
  84         if ( not ref $type_or_name_or_class ) {
  85             # it might be a class
  86             return 1 if $self->class->isa( $type_or_name_or_class );
  87         }
  88         return;
  89     }
  90
  91     if ( $type->isa(__PACKAGE__) && $type->class ne $self->class) {
  92         # if $type_or_name_or_class isn't a class, it might be the TC name of another ::Class type
  93         # or it could also just be a type object in this branch
  94         return $self->class->isa( $type->class );
  95     } else {
  96         # the only other thing we are a subtype of is Object
  97         $self->SUPER::is_subtype_of($type);
  98     }
  99 }
 100
 101 # This is a bit counter-intuitive, but a child type of a Class type
 102 # constraint is not itself a Class type constraint (it has no class
 103 # attribute). This whole create_child_type thing needs some changing
 104 # though, probably making MMC->new a factory or something.
 105 sub create_child_type {
 106     my ($self, @args) = @_;
 107     return Moose::Meta::TypeConstraint->new(@args, parent => $self);
 108 }
 109
 110 sub get_message {
 111     my $self = shift;
 112     my ($value) = @_;
 113
 114     if ($self->has_message) {
 115         return $self->SUPER::get_message(@_);
 116     }
 117
 118     $value = (defined $value ? overload::StrVal($value) : 'undef');
 119     return "Validation failed for '" . $self->name . "' with value $value (not isa " . $self->class . ")";
 120 }
 121
 122 1;
 123
 124 __END__
 125
 126 =pod
 127
 128 =head1 NAME
 129
 130 Moose::Meta::TypeConstraint::Class - Class/TypeConstraint parallel hierarchy
 131
 132 =head1 DESCRIPTION
 133
 134 This class represents type constraints for a class.
 135
 136 =head1 INHERITANCE
 137
 138 C<Moose::Meta::TypeConstraint::Class> is a subclass of
 139 L<Moose::Meta::TypeConstraint>.
 140
 141 =head1 METHODS
 142
 143 =over 4
 144
 145 =item B<< Moose::Meta::TypeConstraint::Class->new(%options) >>
 146
 147 This creates a new class type constraint based on the given
 148 C<%options>.
 149
 150 It takes the same options as its parent, with two exceptions. First,
 151 it requires an additional option, C<class>, which is name of the
 152 constraint's class.  Second, it automatically sets the parent to the
 153 C<Object> type.
 154
 155 The constructor also overrides the hand optimized type constraint with
 156 one it creates internally.
 157
 158 =item B<< $constraint->class >>
 159
 160 Returns the class name associated with the constraint.
 161
 162 =item B<< $constraint->parents >>
 163
 164 Returns all the type's parent types, corresponding to its parent
 165 classes.
 166
 167 =item B<< $constraint->is_subtype_of($type_name_or_object) >>
 168
 169 If the given type is also a class type, then this checks that the
 170 type's class is a subclass of the other type's class.
 171
 172 Otherwise it falls back to the implementation in
 173 L<Moose::Meta::TypeConstraint>.
 174
 175 =item B<< $constraint->create_child_type(%options) >>
 176
 177 This returns a new L<Moose::Meta::TypeConstraint> object with the type
 178 as its parent.
 179
 180 Note that it does I<not> return a
 181 C<Moose::Meta::TypeConstraint::Class> object!
 182
 183 =item B<< $constraint->get_message($value) >>
 184
 185 This is the same as L<Moose::Meta::TypeConstraint/get_message> except
 186 that it explicitly says C<isa> was checked. This is to help users deal
 187 with accidentally autovivified type constraints.
 188
 189 =back
 190
 191 =head1 BUGS
 192
 193 See L<Moose/BUGS> for details on reporting bugs.
 194
 195 =head1 AUTHOR
 196
 197 Yuval Kogman E<lt>nothingmuch@cpan.orgE<gt>
 198
 199 =head1 COPYRIGHT AND LICENSE
 200
 201 Copyright 2006-2010 by Infinity Interactive, Inc.
 202
 203 L<http://www.iinteractive.com>
 204
 205 This library is free software; you can redistribute it and/or modify
 206 it under the same terms as Perl itself.
 207
 208 =cut