lib/Moose/Meta/Role/Application/ToClass.pm

   1 package Moose::Meta::Role::Application::ToClass;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 use Moose::Util  'english_list';
   8 use Scalar::Util 'weaken', 'blessed';
   9
  10 our $VERSION   = '0.87';
  11 $VERSION = eval $VERSION;
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 use base 'Moose::Meta::Role::Application';
  15
  16 __PACKAGE__->meta->add_attribute('role' => (
  17     reader => 'role',
  18 ));
  19
  20 __PACKAGE__->meta->add_attribute('class' => (
  21     reader => 'class',
  22 ));
  23
  24 sub apply {
  25     my ($self, $role, $class) = @_;
  26
  27     # We need weak_ref in CMOP :(
  28     weaken($self->{role}  = $role);
  29     weaken($self->{class} = $class);
  30
  31     $self->SUPER::apply($role, $class);
  32
  33     $class->add_role($role);
  34     $class->add_role_application($self);
  35 }
  36
  37 sub check_role_exclusions {
  38     my ($self, $role, $class) = @_;
  39     if ($class->excludes_role($role->name)) {
  40         $class->throw_error("Conflict detected: " . $class->name . " excludes role '" . $role->name . "'");
  41     }
  42     foreach my $excluded_role_name ($role->get_excluded_roles_list) {
  43         if ($class->does_role($excluded_role_name)) {
  44             $class->throw_error("The class " . $class->name . " does the excluded role '$excluded_role_name'");
  45         }
  46     }
  47 }
  48
  49 sub check_required_methods {
  50     my ($self, $role, $class) = @_;
  51
  52     my @missing;
  53     my @is_attr;
  54
  55     # NOTE:
  56     # we might need to move this down below the
  57     # the attributes so that we can require any
  58     # attribute accessors. However I am thinking
  59     # that maybe those are somehow exempt from
  60     # the require methods stuff.
  61     foreach my $required_method ($role->get_required_method_list) {
  62         my $required_method_name = $required_method->name;
  63
  64         if (!$class->find_method_by_name($required_method_name)) {
  65
  66             next if $self->is_aliased_method($required_method_name);
  67
  68             push @missing, $required_method;
  69         }
  70     }
  71
  72     return unless @missing;
  73
  74     my $error = '';
  75
  76     my @conflicts = grep { $_->isa('Moose::Meta::Role::Method::Conflicting') } @missing;
  77
  78     if (@conflicts) {
  79         my $conflict = $conflicts[0];
  80         my $roles = Moose::Util::english_list( map { q{'} . $_ . q{'} } @{ $conflict->roles } );
  81
  82         $error
  83             .= "Due to a method name conflict in roles "
  84             .  $roles
  85             . ", the method '"
  86             . $conflict->name
  87             . "' must be implemented or excluded by '"
  88             . $class->name
  89             . q{'};
  90     }
  91     elsif (@missing) {
  92         my $noun = @missing == 1 ? 'method' : 'methods';
  93
  94         my $list
  95             = Moose::Util::english_list( map { q{'} . $_ . q{'} } @missing );
  96
  97         $error
  98             .= q{'}
  99             . $role->name
 100             . "' requires the $noun $list "
 101             . "to be implemented by '"
 102             . $class->name . q{'};
 103     }
 104
 105     $class->throw_error($error);
 106 }
 107
 108 sub check_required_attributes {
 109
 110 }
 111
 112 sub apply_attributes {
 113     my ($self, $role, $class) = @_;
 114     foreach my $attribute_name ($role->get_attribute_list) {
 115         # it if it has one already
 116         if ($class->has_attribute($attribute_name) &&
 117             # make sure we haven't seen this one already too
 118             $class->get_attribute($attribute_name) != $role->get_attribute($attribute_name)) {
 119             next;
 120         }
 121         else {
 122             $class->add_attribute(
 123                 $attribute_name,
 124                 $role->get_attribute($attribute_name)
 125             );
 126         }
 127     }
 128 }
 129
 130 sub apply_methods {
 131     my ($self, $role, $class) = @_;
 132     foreach my $method_name ($role->get_method_list) {
 133
 134         unless ($self->is_method_excluded($method_name)) {
 135             # it if it has one already
 136             if ($class->has_method($method_name) &&
 137                 # and if they are not the same thing ...
 138                 $class->get_method($method_name)->body != $role->get_method($method_name)->body) {
 139                 next;
 140             }
 141             else {
 142                 # add it, although it could be overridden
 143                 $class->add_method(
 144                     $method_name,
 145                     $role->get_method($method_name)
 146                 );
 147             }
 148         }
 149
 150         if ($self->is_method_aliased($method_name)) {
 151             my $aliased_method_name = $self->get_method_aliases->{$method_name};
 152             # it if it has one already
 153             if ($class->has_method($aliased_method_name) &&
 154                 # and if they are not the same thing ...
 155                 $class->get_method($aliased_method_name)->body != $role->get_method($method_name)->body) {
 156                 $class->throw_error("Cannot create a method alias if a local method of the same name exists");
 157             }
 158             $class->add_method(
 159                 $aliased_method_name,
 160                 $role->get_method($method_name)
 161             );
 162         }
 163     }
 164     # we must reset the cache here since
 165     # we are just aliasing methods, otherwise
 166     # the modifiers go wonky.
 167     $class->reset_package_cache_flag;
 168 }
 169
 170 sub apply_override_method_modifiers {
 171     my ($self, $role, $class) = @_;
 172     foreach my $method_name ($role->get_method_modifier_list('override')) {
 173         # it if it has one already then ...
 174         if ($class->has_method($method_name)) {
 175             next;
 176         }
 177         else {
 178             # if this is not a role, then we need to
 179             # find the original package of the method
 180             # so that we can tell the class were to
 181             # find the right super() method
 182             my $method = $role->get_override_method_modifier($method_name);
 183             my ($package) = Class::MOP::get_code_info($method);
 184             # if it is a class, we just add it
 185             $class->add_override_method_modifier($method_name, $method, $package);
 186         }
 187     }
 188 }
 189
 190 sub apply_method_modifiers {
 191     my ($self, $modifier_type, $role, $class) = @_;
 192     my $add = "add_${modifier_type}_method_modifier";
 193     my $get = "get_${modifier_type}_method_modifiers";
 194     foreach my $method_name ($role->get_method_modifier_list($modifier_type)) {
 195         $class->$add(
 196             $method_name,
 197             $_
 198         ) foreach $role->$get($method_name);
 199     }
 200 }
 201
 202 1;
 203
 204 __END__
 205
 206 =pod
 207
 208 =head1 NAME
 209
 210 Moose::Meta::Role::Application::ToClass - Compose a role into a class
 211
 212 =head1 DESCRIPTION
 213
 214 =head2 METHODS
 215
 216 =over 4
 217
 218 =item B<new>
 219
 220 =item B<meta>
 221
 222 =item B<apply>
 223
 224 =item B<check_role_exclusions>
 225
 226 =item B<check_required_methods>
 227
 228 =item B<check_required_attributes>
 229
 230 =item B<apply_attributes>
 231
 232 =item B<apply_methods>
 233
 234 =item B<apply_method_modifiers>
 235
 236 =item B<apply_override_method_modifiers>
 237
 238 =back
 239
 240 =head1 BUGS
 241
 242 All complex software has bugs lurking in it, and this module is no
 243 exception. If you find a bug please either email me, or add the bug
 244 to cpan-RT.
 245
 246 =head1 AUTHOR
 247
 248 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 249
 250 =head1 COPYRIGHT AND LICENSE
 251
 252 Copyright 2006-2009 by Infinity Interactive, Inc.
 253
 254 L<http://www.iinteractive.com>
 255
 256 This library is free software; you can redistribute it and/or modify
 257 it under the same terms as Perl itself.
 258
 259 =cut
 260