lib/Moose/Meta/Role/Application/ToClass.pm

   1 package Moose::Meta::Role::Application::ToClass;
   2
   3 use strict;
   4 use warnings;
   5 use metaclass;
   6
   7 use Moose::Util  'english_list';
   8 use Scalar::Util 'weaken', 'blessed';
   9
  10 our $VERSION   = '0.79';
  11 $VERSION = eval $VERSION;
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 use base 'Moose::Meta::Role::Application';
  15
  16 __PACKAGE__->meta->add_attribute('role' => (
  17     reader => 'role',
  18 ));
  19
  20 __PACKAGE__->meta->add_attribute('class' => (
  21     reader => 'class',
  22 ));
  23
  24 sub apply {
  25     my ($self, $role, $class) = @_;
  26
  27     # We need weak_ref in CMOP :(
  28     weaken($self->{role}  = $role);
  29     weaken($self->{class} = $class);
  30
  31     $self->SUPER::apply($role, $class);
  32
  33     $class->add_role($role);
  34     $class->add_role_application($self);
  35 }
  36
  37 sub check_role_exclusions {
  38     my ($self, $role, $class) = @_;
  39     if ($class->excludes_role($role->name)) {
  40         $class->throw_error("Conflict detected: " . $class->name . " excludes role '" . $role->name . "'");
  41     }
  42     foreach my $excluded_role_name ($role->get_excluded_roles_list) {
  43         if ($class->does_role($excluded_role_name)) {
  44             $class->throw_error("The class " . $class->name . " does the excluded role '$excluded_role_name'");
  45         }
  46     }
  47 }
  48
  49 sub check_required_methods {
  50     my ($self, $role, $class) = @_;
  51
  52     my @missing;
  53     my @is_attr;
  54
  55     # NOTE:
  56     # we might need to move this down below the
  57     # the attributes so that we can require any
  58     # attribute accessors. However I am thinking
  59     # that maybe those are somehow exempt from
  60     # the require methods stuff.
  61     foreach my $required_method_name ($role->get_required_method_list) {
  62
  63         if (!$class->find_method_by_name($required_method_name)) {
  64
  65             next if $self->is_aliased_method($required_method_name);
  66
  67             push @missing, $required_method_name;
  68         }
  69     }
  70
  71     return unless @missing;
  72
  73     my $error = '';
  74
  75     if (@missing) {
  76         my $noun = @missing == 1 ? 'method' : 'methods';
  77
  78         my $list
  79             = Moose::Util::english_list( map { q{'} . $_ . q{'} } @missing );
  80
  81         $error
  82             .= q{'}
  83             . $role->name
  84             . "' requires the $noun $list "
  85             . "to be implemented by '"
  86             . $class->name . q{'};
  87     }
  88
  89     $class->throw_error($error);
  90 }
  91
  92 sub check_required_attributes {
  93
  94 }
  95
  96 sub apply_attributes {
  97     my ($self, $role, $class) = @_;
  98     foreach my $attribute_name ($role->get_attribute_list) {
  99         # it if it has one already
 100         if ($class->has_attribute($attribute_name) &&
 101             # make sure we haven't seen this one already too
 102             $class->get_attribute($attribute_name) != $role->get_attribute($attribute_name)) {
 103             next;
 104         }
 105         else {
 106             $class->add_attribute(
 107                 $attribute_name,
 108                 $role->get_attribute($attribute_name)
 109             );
 110         }
 111     }
 112 }
 113
 114 sub apply_methods {
 115     my ($self, $role, $class) = @_;
 116     foreach my $method_name ($role->get_method_list) {
 117
 118         unless ($self->is_method_excluded($method_name)) {
 119             # it if it has one already
 120             if ($class->has_method($method_name) &&
 121                 # and if they are not the same thing ...
 122                 $class->get_method($method_name)->body != $role->get_method($method_name)->body) {
 123                 next;
 124             }
 125             else {
 126                 # add it, although it could be overridden
 127                 $class->add_method(
 128                     $method_name,
 129                     $role->get_method($method_name)
 130                 );
 131             }
 132         }
 133
 134         if ($self->is_method_aliased($method_name)) {
 135             my $aliased_method_name = $self->get_method_aliases->{$method_name};
 136             # it if it has one already
 137             if ($class->has_method($aliased_method_name) &&
 138                 # and if they are not the same thing ...
 139                 $class->get_method($aliased_method_name)->body != $role->get_method($method_name)->body) {
 140                 $class->throw_error("Cannot create a method alias if a local method of the same name exists");
 141             }
 142             $class->add_method(
 143                 $aliased_method_name,
 144                 $role->get_method($method_name)
 145             );
 146         }
 147     }
 148     # we must reset the cache here since
 149     # we are just aliasing methods, otherwise
 150     # the modifiers go wonky.
 151     $class->reset_package_cache_flag;
 152 }
 153
 154 sub apply_override_method_modifiers {
 155     my ($self, $role, $class) = @_;
 156     foreach my $method_name ($role->get_method_modifier_list('override')) {
 157         # it if it has one already then ...
 158         if ($class->has_method($method_name)) {
 159             next;
 160         }
 161         else {
 162             # if this is not a role, then we need to
 163             # find the original package of the method
 164             # so that we can tell the class were to
 165             # find the right super() method
 166             my $method = $role->get_override_method_modifier($method_name);
 167             my ($package) = Class::MOP::get_code_info($method);
 168             # if it is a class, we just add it
 169             $class->add_override_method_modifier($method_name, $method, $package);
 170         }
 171     }
 172 }
 173
 174 sub apply_method_modifiers {
 175     my ($self, $modifier_type, $role, $class) = @_;
 176     my $add = "add_${modifier_type}_method_modifier";
 177     my $get = "get_${modifier_type}_method_modifiers";
 178     foreach my $method_name ($role->get_method_modifier_list($modifier_type)) {
 179         $class->$add(
 180             $method_name,
 181             $_
 182         ) foreach $role->$get($method_name);
 183     }
 184 }
 185
 186 1;
 187
 188 __END__
 189
 190 =pod
 191
 192 =head1 NAME
 193
 194 Moose::Meta::Role::Application::ToClass - Compose a role into a class
 195
 196 =head1 DESCRIPTION
 197
 198 =head2 METHODS
 199
 200 =over 4
 201
 202 =item B<new>
 203
 204 =item B<meta>
 205
 206 =item B<apply>
 207
 208 =item B<check_role_exclusions>
 209
 210 =item B<check_required_methods>
 211
 212 =item B<check_required_attributes>
 213
 214 =item B<apply_attributes>
 215
 216 =item B<apply_methods>
 217
 218 =item B<apply_method_modifiers>
 219
 220 =item B<apply_override_method_modifiers>
 221
 222 =back
 223
 224 =head1 BUGS
 225
 226 All complex software has bugs lurking in it, and this module is no
 227 exception. If you find a bug please either email me, or add the bug
 228 to cpan-RT.
 229
 230 =head1 AUTHOR
 231
 232 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 233
 234 =head1 COPYRIGHT AND LICENSE
 235
 236 Copyright 2006-2009 by Infinity Interactive, Inc.
 237
 238 L<http://www.iinteractive.com>
 239
 240 This library is free software; you can redistribute it and/or modify
 241 it under the same terms as Perl itself.
 242
 243 =cut
 244