lib/Moose/Meta/Role.pm

   1
   2 package Moose::Meta::Role;
   3
   4 use strict;
   5 use warnings;
   6 use metaclass;
   7
   8 use Scalar::Util 'blessed';
   9 use Carp         'confess';
  10 use Devel::GlobalDestruction 'in_global_destruction';
  11
  12 our $VERSION   = '1.04';
  13 $VERSION = eval $VERSION;
  14 our $AUTHORITY = 'cpan:STEVAN';
  15
  16 use Moose::Meta::Class;
  17 use Moose::Meta::Role::Attribute;
  18 use Moose::Meta::Role::Method;
  19 use Moose::Meta::Role::Method::Required;
  20 use Moose::Meta::Role::Method::Conflicting;
  21 use Moose::Util qw( ensure_all_roles );
  22
  23 use base 'Class::MOP::Module',
  24          'Class::MOP::Mixin::HasAttributes',
  25          'Class::MOP::Mixin::HasMethods';
  26
  27 ## ------------------------------------------------------------------
  28 ## NOTE:
  29 ## I normally don't do this, but I am doing
  30 ## a whole bunch of meta-programmin in this
  31 ## module, so it just makes sense. For a clearer
  32 ## picture of what is going on in the next
  33 ## several lines of code, look at the really
  34 ## big comment at the end of this file (right
  35 ## before the POD).
  36 ## - SL
  37 ## ------------------------------------------------------------------
  38
  39 my $META = __PACKAGE__->meta;
  40
  41 ## ------------------------------------------------------------------
  42 ## attributes ...
  43
  44 # NOTE:
  45 # since roles are lazy, we hold all the attributes
  46 # of the individual role in 'statis' until which
  47 # time when it is applied to a class. This means
  48 # keeping a lot of things in hash maps, so we are
  49 # using a little of that meta-programmin' magic
  50 # here an saving lots of extra typin. And since
  51 # many of these attributes above require similar
  52 # functionality to support them, so we again use
  53 # the wonders of meta-programmin' to deliver a
  54 # very compact solution to this normally verbose
  55 # problem.
  56 # - SL
  57
  58 foreach my $action (
  59     {
  60         name        => 'excluded_roles_map',
  61         attr_reader => 'get_excluded_roles_map' ,
  62         methods     => {
  63             add       => 'add_excluded_roles',
  64             get_keys  => 'get_excluded_roles_list',
  65             existence => 'excludes_role',
  66         }
  67     },
  68     {
  69         name        => 'required_methods',
  70         attr_reader => 'get_required_methods_map',
  71         methods     => {
  72             remove     => 'remove_required_methods',
  73             get_values => 'get_required_method_list',
  74             existence  => 'requires_method',
  75         }
  76     },
  77 ) {
  78
  79     my $attr_reader = $action->{attr_reader};
  80     my $methods     = $action->{methods};
  81
  82     # create the attribute
  83     $META->add_attribute($action->{name} => (
  84         reader  => $attr_reader,
  85         default => sub { {} }
  86     ));
  87
  88     # create some helper methods
  89     $META->add_method($methods->{add} => sub {
  90         my ($self, @values) = @_;
  91         $self->$attr_reader->{$_} = undef foreach @values;
  92     }) if exists $methods->{add};
  93
  94     $META->add_method($methods->{get_keys} => sub {
  95         my ($self) = @_;
  96         keys %{$self->$attr_reader};
  97     }) if exists $methods->{get_keys};
  98
  99     $META->add_method($methods->{get_values} => sub {
 100         my ($self) = @_;
 101         values %{$self->$attr_reader};
 102     }) if exists $methods->{get_values};
 103
 104     $META->add_method($methods->{get} => sub {
 105         my ($self, $name) = @_;
 106         $self->$attr_reader->{$name}
 107     }) if exists $methods->{get};
 108
 109     $META->add_method($methods->{existence} => sub {
 110         my ($self, $name) = @_;
 111         exists $self->$attr_reader->{$name} ? 1 : 0;
 112     }) if exists $methods->{existence};
 113
 114     $META->add_method($methods->{remove} => sub {
 115         my ($self, @values) = @_;
 116         delete $self->$attr_reader->{$_} foreach @values;
 117     }) if exists $methods->{remove};
 118 }
 119
 120 $META->add_attribute(
 121     'method_metaclass',
 122     reader  => 'method_metaclass',
 123     default => 'Moose::Meta::Role::Method',
 124 );
 125
 126 $META->add_attribute(
 127     'required_method_metaclass',
 128     reader  => 'required_method_metaclass',
 129     default => 'Moose::Meta::Role::Method::Required',
 130 );
 131
 132 $META->add_attribute(
 133     'conflicting_method_metaclass',
 134     reader  => 'conflicting_method_metaclass',
 135     default => 'Moose::Meta::Role::Method::Conflicting',
 136 );
 137
 138 $META->add_attribute(
 139     'application_to_class_class',
 140     reader  => 'application_to_class_class',
 141     default => 'Moose::Meta::Role::Application::ToClass',
 142 );
 143
 144 $META->add_attribute(
 145     'application_to_role_class',
 146     reader  => 'application_to_role_class',
 147     default => 'Moose::Meta::Role::Application::ToRole',
 148 );
 149
 150 $META->add_attribute(
 151     'application_to_instance_class',
 152     reader  => 'application_to_instance_class',
 153     default => 'Moose::Meta::Role::Application::ToInstance',
 154 );
 155
 156 # More or less copied from Moose::Meta::Class
 157 sub initialize {
 158     my $class = shift;
 159     my $pkg   = shift;
 160     return Class::MOP::get_metaclass_by_name($pkg)
 161         || $class->SUPER::initialize(
 162         $pkg,
 163         'attribute_metaclass' => 'Moose::Meta::Role::Attribute',
 164         @_
 165         );
 166 }
 167
 168 sub reinitialize {
 169     my $self = shift;
 170     my $pkg  = shift;
 171
 172     my $meta = blessed $pkg ? $pkg : Class::MOP::class_of($pkg);
 173
 174     my %existing_classes;
 175     if ($meta) {
 176         %existing_classes = map { $_ => $meta->$_() } qw(
 177             attribute_metaclass
 178             method_metaclass
 179             wrapped_method_metaclass
 180             required_method_metaclass
 181             conflicting_method_metaclass
 182             application_to_class_class
 183             application_to_role_class
 184             application_to_instance_class
 185         );
 186     }
 187
 188     return $self->SUPER::reinitialize(
 189         $pkg,
 190         %existing_classes,
 191         @_,
 192     );
 193 }
 194
 195 sub add_attribute {
 196     my $self = shift;
 197
 198     if (blessed $_[0] && ! $_[0]->isa('Moose::Meta::Role::Attribute') ) {
 199         my $class = ref $_[0];
 200         Moose->throw_error( "Cannot add a $class as an attribute to a role" );
 201     }
 202     elsif (!blessed($_[0]) && defined($_[0]) && $_[0] =~ /^\+(.*)/) {
 203         Moose->throw_error( "has '+attr' is not supported in roles" );
 204     }
 205
 206     return $self->SUPER::add_attribute(@_);
 207 }
 208
 209 sub _attach_attribute {
 210     my ( $self, $attribute ) = @_;
 211
 212     $attribute->attach_to_role($self);
 213 }
 214
 215 sub add_required_methods {
 216     my $self = shift;
 217
 218     for (@_) {
 219         my $method = $_;
 220         if (!blessed($method)) {
 221             $method = $self->required_method_metaclass->new(
 222                 name => $method,
 223             );
 224         }
 225         $self->get_required_methods_map->{$method->name} = $method;
 226     }
 227 }
 228
 229 sub add_conflicting_method {
 230     my $self = shift;
 231
 232     my $method;
 233     if (@_ == 1 && blessed($_[0])) {
 234         $method = shift;
 235     }
 236     else {
 237         $method = $self->conflicting_method_metaclass->new(@_);
 238     }
 239
 240     $self->add_required_methods($method);
 241 }
 242
 243 ## ------------------------------------------------------------------
 244 ## method modifiers
 245
 246 # NOTE:
 247 # the before/around/after method modifiers are
 248 # stored by name, but there can be many methods
 249 # then associated with that name. So again we have
 250 # lots of similar functionality, so we can do some
 251 # meta-programmin' and save some time.
 252 # - SL
 253
 254 foreach my $modifier_type (qw[ before around after ]) {
 255
 256     my $attr_reader = "get_${modifier_type}_method_modifiers_map";
 257
 258     # create the attribute ...
 259     $META->add_attribute("${modifier_type}_method_modifiers" => (
 260         reader  => $attr_reader,
 261         default => sub { {} }
 262     ));
 263
 264     # and some helper methods ...
 265     $META->add_method("get_${modifier_type}_method_modifiers" => sub {
 266         my ($self, $method_name) = @_;
 267         #return () unless exists $self->$attr_reader->{$method_name};
 268         my $mm = $self->$attr_reader->{$method_name};
 269         $mm ? @$mm : ();
 270     });
 271
 272     $META->add_method("has_${modifier_type}_method_modifiers" => sub {
 273         my ($self, $method_name) = @_;
 274         # NOTE:
 275         # for now we assume that if it exists,..
 276         # it has at least one modifier in it
 277         (exists $self->$attr_reader->{$method_name}) ? 1 : 0;
 278     });
 279
 280     $META->add_method("add_${modifier_type}_method_modifier" => sub {
 281         my ($self, $method_name, $method) = @_;
 282
 283         $self->$attr_reader->{$method_name} = []
 284             unless exists $self->$attr_reader->{$method_name};
 285
 286         my $modifiers = $self->$attr_reader->{$method_name};
 287
 288         # NOTE:
 289         # check to see that we aren't adding the
 290         # same code twice. We err in favor of the
 291         # first on here, this may not be as expected
 292         foreach my $modifier (@{$modifiers}) {
 293             return if $modifier == $method;
 294         }
 295
 296         push @{$modifiers} => $method;
 297     });
 298
 299 }
 300
 301 ## ------------------------------------------------------------------
 302 ## override method mofidiers
 303
 304 $META->add_attribute('override_method_modifiers' => (
 305     reader  => 'get_override_method_modifiers_map',
 306     default => sub { {} }
 307 ));
 308
 309 # NOTE:
 310 # these are a little different because there
 311 # can only be one per name, whereas the other
 312 # method modifiers can have multiples.
 313 # - SL
 314
 315 sub add_override_method_modifier {
 316     my ($self, $method_name, $method) = @_;
 317     (!$self->has_method($method_name))
 318         || Moose->throw_error("Cannot add an override of method '$method_name' " .
 319                    "because there is a local version of '$method_name'");
 320     $self->get_override_method_modifiers_map->{$method_name} = $method;
 321 }
 322
 323 sub has_override_method_modifier {
 324     my ($self, $method_name) = @_;
 325     # NOTE:
 326     # for now we assume that if it exists,..
 327     # it has at least one modifier in it
 328     (exists $self->get_override_method_modifiers_map->{$method_name}) ? 1 : 0;
 329 }
 330
 331 sub get_override_method_modifier {
 332     my ($self, $method_name) = @_;
 333     $self->get_override_method_modifiers_map->{$method_name};
 334 }
 335
 336 ## general list accessor ...
 337
 338 sub get_method_modifier_list {
 339     my ($self, $modifier_type) = @_;
 340     my $accessor = "get_${modifier_type}_method_modifiers_map";
 341     keys %{$self->$accessor};
 342 }
 343
 344 sub reset_package_cache_flag  { (shift)->{'_package_cache_flag'} = undef }
 345 sub update_package_cache_flag {
 346     my $self = shift;
 347     $self->{'_package_cache_flag'} = Class::MOP::check_package_cache_flag($self->name);
 348 }
 349
 350
 351
 352 ## ------------------------------------------------------------------
 353 ## subroles
 354
 355 $META->add_attribute('roles' => (
 356     reader  => 'get_roles',
 357     default => sub { [] }
 358 ));
 359
 360 sub add_role {
 361     my ($self, $role) = @_;
 362     (blessed($role) && $role->isa('Moose::Meta::Role'))
 363         || Moose->throw_error("Roles must be instances of Moose::Meta::Role");
 364     push @{$self->get_roles} => $role;
 365     $self->reset_package_cache_flag;
 366 }
 367
 368 sub calculate_all_roles {
 369     my $self = shift;
 370     my %seen;
 371     grep {
 372         !$seen{$_->name}++
 373     } ($self, map {
 374                   $_->calculate_all_roles
 375               } @{ $self->get_roles });
 376 }
 377
 378 sub does_role {
 379     my ($self, $role) = @_;
 380     (defined $role)
 381         || Moose->throw_error("You must supply a role name to look for");
 382     my $role_name = blessed $role ? $role->name : $role;
 383     # if we are it,.. then return true
 384     return 1 if $role_name eq $self->name;
 385     # otherwise.. check our children
 386     foreach my $role (@{$self->get_roles}) {
 387         return 1 if $role->does_role($role_name);
 388     }
 389     return 0;
 390 }
 391
 392 sub find_method_by_name { (shift)->get_method(@_) }
 393
 394 sub alias_method {
 395     Carp::cluck("The alias_method method is deprecated. Use add_method instead.\n");
 396
 397     my $self = shift;
 398
 399     $self->add_method(@_);
 400 }
 401
 402 ## ------------------------------------------------------------------
 403 ## role construction
 404 ## ------------------------------------------------------------------
 405
 406 sub apply {
 407     my ($self, $other, %args) = @_;
 408
 409     (blessed($other))
 410         || Moose->throw_error("You must pass in an blessed instance");
 411
 412     my $application_class;
 413     if ($other->isa('Moose::Meta::Role')) {
 414         $application_class = $self->application_to_role_class;
 415     }
 416     elsif ($other->isa('Moose::Meta::Class')) {
 417         $application_class = $self->application_to_class_class;
 418     }
 419     else {
 420         $application_class = $self->application_to_instance_class;
 421     }
 422
 423     Class::MOP::load_class($application_class);
 424     return $application_class->new(%args)->apply($self, $other, \%args);
 425 }
 426
 427 sub composition_class_roles { }
 428
 429 sub combine {
 430     my ($class, @role_specs) = @_;
 431
 432     require Moose::Meta::Role::Composite;
 433
 434     my (@roles, %role_params);
 435     while (@role_specs) {
 436         my ($role, $params) = @{ splice @role_specs, 0, 1 };
 437         my $requested_role
 438             = blessed $role
 439             ? $role
 440             : Class::MOP::class_of($role);
 441
 442         my $actual_role = $requested_role->_role_for_combination($params);
 443         push @roles => $actual_role;
 444
 445         next unless defined $params;
 446         $role_params{$actual_role->name} = $params;
 447     }
 448
 449     my $c = Moose::Meta::Role::Composite->new(roles => \@roles);
 450     return $c->apply_params(\%role_params);
 451 }
 452
 453 sub _role_for_combination {
 454     my ($self, $params) = @_;
 455     return $self;
 456 }
 457
 458 sub create {
 459     my ( $role, $package_name, %options ) = @_;
 460
 461     $options{package} = $package_name;
 462
 463     (ref $options{attributes} eq 'HASH')
 464         || confess "You must pass a HASH ref of attributes"
 465             if exists $options{attributes};
 466
 467     (ref $options{methods} eq 'HASH')
 468         || confess "You must pass a HASH ref of methods"
 469             if exists $options{methods};
 470
 471     my (%initialize_options) = %options;
 472     delete @initialize_options{qw(
 473         package
 474         attributes
 475         methods
 476         version
 477         authority
 478     )};
 479
 480     my $meta = $role->initialize( $package_name => %initialize_options );
 481
 482     $meta->_instantiate_module( $options{version}, $options{authority} );
 483
 484     # FIXME totally lame
 485     $meta->add_method('meta' => sub {
 486         $role->initialize(ref($_[0]) || $_[0]);
 487     });
 488
 489     if (exists $options{attributes}) {
 490         foreach my $attribute_name (keys %{$options{attributes}}) {
 491             my $attr = $options{attributes}->{$attribute_name};
 492             $meta->add_attribute(
 493                 $attribute_name => blessed $attr ? $attr : %{$attr} );
 494         }
 495     }
 496
 497     if (exists $options{methods}) {
 498         foreach my $method_name (keys %{$options{methods}}) {
 499             $meta->add_method($method_name, $options{methods}->{$method_name});
 500         }
 501     }
 502
 503     Class::MOP::weaken_metaclass($meta->name)
 504         if $meta->is_anon_role;
 505
 506     return $meta;
 507 }
 508
 509 sub consumers {
 510     my $self = shift;
 511     my @consumers;
 512     for my $meta (Class::MOP::get_all_metaclass_instances) {
 513         next if $meta->name eq $self->name;
 514         next unless $meta->isa('Moose::Meta::Class')
 515                  || $meta->isa('Moose::Meta::Role');
 516         push @consumers, $meta->name
 517             if $meta->does_role($self->name);
 518     }
 519     return @consumers;
 520 }
 521
 522 # anonymous roles. most of it is copied straight out of Class::MOP::Class.
 523 # an intrepid hacker might find great riches if he unifies this code with that
 524 # code in Class::MOP::Module or Class::MOP::Package
 525 {
 526     # NOTE:
 527     # this should be sufficient, if you have a
 528     # use case where it is not, write a test and
 529     # I will change it.
 530     my $ANON_ROLE_SERIAL = 0;
 531
 532     # NOTE:
 533     # we need a sufficiently annoying prefix
 534     # this should suffice for now, this is
 535     # used in a couple of places below, so
 536     # need to put it up here for now.
 537     my $ANON_ROLE_PREFIX = 'Moose::Meta::Role::__ANON__::SERIAL::';
 538
 539     sub is_anon_role {
 540         my $self = shift;
 541         no warnings 'uninitialized';
 542         $self->name =~ /^$ANON_ROLE_PREFIX/;
 543     }
 544
 545     sub create_anon_role {
 546         my ($role, %options) = @_;
 547         my $package_name = $ANON_ROLE_PREFIX . ++$ANON_ROLE_SERIAL;
 548         return $role->create($package_name, %options);
 549     }
 550
 551     # NOTE:
 552     # this will only get called for
 553     # anon-roles, all other calls
 554     # are assumed to occur during
 555     # global destruction and so don't
 556     # really need to be handled explicitly
 557     sub DESTROY {
 558         my $self = shift;
 559
 560         return if in_global_destruction(); # it'll happen soon anyway and this just makes things more complicated
 561
 562         no warnings 'uninitialized';
 563         return unless $self->name =~ /^$ANON_ROLE_PREFIX/;
 564
 565         # XXX: is this necessary for us? I don't understand what it's doing
 566         # -sartak
 567
 568         # Moose does a weird thing where it replaces the metaclass for
 569         # class when fixing metaclass incompatibility. In that case,
 570         # we don't want to clean out the namespace now. We can detect
 571         # that because Moose will explicitly update the singleton
 572         # cache in Class::MOP.
 573         #my $current_meta = Class::MOP::get_metaclass_by_name($self->name);
 574         #return if $current_meta ne $self;
 575
 576         my ($serial_id) = ($self->name =~ /^$ANON_ROLE_PREFIX(\d+)/);
 577         no strict 'refs';
 578         foreach my $key (keys %{$ANON_ROLE_PREFIX . $serial_id}) {
 579             delete ${$ANON_ROLE_PREFIX . $serial_id}{$key};
 580         }
 581         delete ${'main::' . $ANON_ROLE_PREFIX}{$serial_id . '::'};
 582     }
 583 }
 584
 585 #####################################################################
 586 ## NOTE:
 587 ## This is Moose::Meta::Role as defined by Moose (plus the use of
 588 ## MooseX::AttributeHelpers module). It is here as a reference to
 589 ## make it easier to see what is happening above with all the meta
 590 ## programming. - SL
 591 #####################################################################
 592 #
 593 # has 'roles' => (
 594 #     metaclass => 'Array',
 595 #     reader    => 'get_roles',
 596 #     isa       => 'ArrayRef[Moose::Meta::Role]',
 597 #     default   => sub { [] },
 598 #     provides  => {
 599 #         'push' => 'add_role',
 600 #     }
 601 # );
 602 #
 603 # has 'excluded_roles_map' => (
 604 #     metaclass => 'Hash',
 605 #     reader    => 'get_excluded_roles_map',
 606 #     isa       => 'HashRef[Str]',
 607 #     provides  => {
 608 #         # Not exactly set, cause it sets multiple
 609 #         'set'    => 'add_excluded_roles',
 610 #         'keys'   => 'get_excluded_roles_list',
 611 #         'exists' => 'excludes_role',
 612 #     }
 613 # );
 614 #
 615 # has 'required_methods' => (
 616 #     metaclass => 'Hash',
 617 #     reader    => 'get_required_methods_map',
 618 #     isa       => 'HashRef[Moose::Meta::Role::Method::Required]',
 619 #     provides  => {
 620 #         # not exactly set, or delete since it works for multiple
 621 #         'set'    => 'add_required_methods',
 622 #         'delete' => 'remove_required_methods',
 623 #         'keys'   => 'get_required_method_list',
 624 #         'exists' => 'requires_method',
 625 #     }
 626 # );
 627 #
 628 # # the before, around and after modifiers are
 629 # # HASH keyed by method-name, with ARRAY of
 630 # # CODE refs to apply in that order
 631 #
 632 # has 'before_method_modifiers' => (
 633 #     metaclass => 'Hash',
 634 #     reader    => 'get_before_method_modifiers_map',
 635 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 636 #     provides  => {
 637 #         'keys'   => 'get_before_method_modifiers',
 638 #         'exists' => 'has_before_method_modifiers',
 639 #         # This actually makes sure there is an
 640 #         # ARRAY at the given key, and pushed onto
 641 #         # it. It also checks for duplicates as well
 642 #         # 'add'  => 'add_before_method_modifier'
 643 #     }
 644 # );
 645 #
 646 # has 'after_method_modifiers' => (
 647 #     metaclass => 'Hash',
 648 #     reader    =>'get_after_method_modifiers_map',
 649 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 650 #     provides  => {
 651 #         'keys'   => 'get_after_method_modifiers',
 652 #         'exists' => 'has_after_method_modifiers',
 653 #         # This actually makes sure there is an
 654 #         # ARRAY at the given key, and pushed onto
 655 #         # it. It also checks for duplicates as well
 656 #         # 'add'  => 'add_after_method_modifier'
 657 #     }
 658 # );
 659 #
 660 # has 'around_method_modifiers' => (
 661 #     metaclass => 'Hash',
 662 #     reader    =>'get_around_method_modifiers_map',
 663 #     isa       => 'HashRef[ArrayRef[CodeRef]]',
 664 #     provides  => {
 665 #         'keys'   => 'get_around_method_modifiers',
 666 #         'exists' => 'has_around_method_modifiers',
 667 #         # This actually makes sure there is an
 668 #         # ARRAY at the given key, and pushed onto
 669 #         # it. It also checks for duplicates as well
 670 #         # 'add'  => 'add_around_method_modifier'
 671 #     }
 672 # );
 673 #
 674 # # override is similar to the other modifiers
 675 # # except that it is not an ARRAY of code refs
 676 # # but instead just a single name->code mapping
 677 #
 678 # has 'override_method_modifiers' => (
 679 #     metaclass => 'Hash',
 680 #     reader    =>'get_override_method_modifiers_map',
 681 #     isa       => 'HashRef[CodeRef]',
 682 #     provides  => {
 683 #         'keys'   => 'get_override_method_modifier',
 684 #         'exists' => 'has_override_method_modifier',
 685 #         'add'    => 'add_override_method_modifier', # checks for local method ..
 686 #     }
 687 # );
 688 #
 689 #####################################################################
 690
 691
 692 1;
 693
 694 __END__
 695
 696 =pod
 697
 698 =head1 NAME
 699
 700 Moose::Meta::Role - The Moose Role metaclass
 701
 702 =head1 DESCRIPTION
 703
 704 This class is a subclass of L<Class::MOP::Module> that provides
 705 additional Moose-specific functionality.
 706
 707 It's API looks a lot like L<Moose::Meta::Class>, but internally it
 708 implements many things differently. This may change in the future.
 709
 710 =head1 INHERITANCE
 711
 712 C<Moose::Meta::Role> is a subclass of L<Class::MOP::Module>.
 713
 714 =head1 METHODS
 715
 716 =head2 Construction
 717
 718 =over 4
 719
 720 =item B<< Moose::Meta::Role->initialize($role_name) >>
 721
 722 This method creates a new role object with the provided name.
 723
 724 =item B<< Moose::Meta::Role->combine( [ $role => { ... } ], [ $role ], ... ) >>
 725
 726 This method accepts a list of array references. Each array reference
 727 should contain a role name or L<Moose::Meta::Role> object as its first element. The second element is
 728 an optional hash reference. The hash reference can contain C<-excludes>
 729 and C<-alias> keys to control how methods are composed from the role.
 730
 731 The return value is a new L<Moose::Meta::Role::Composite> that
 732 represents the combined roles.
 733
 734 =item B<< $metarole->composition_class_roles >>
 735
 736 When combining multiple roles using C<combine>, this method is used to obtain a
 737 list of role names to be applied to the L<Moose::Meta::Role::Composite>
 738 instance returned by C<combine>. The default implementation returns an empty
 739 list. Extensions that need to hook into role combination may wrap this method
 740 to return additional role names.
 741
 742 =item B<< Moose::Meta::Role->create($name, %options) >>
 743
 744 This method is identical to the L<Moose::Meta::Class> C<create>
 745 method.
 746
 747 =item B<< Moose::Meta::Role->create_anon_role >>
 748
 749 This method is identical to the L<Moose::Meta::Class>
 750 C<create_anon_class> method.
 751
 752 =item B<< $metarole->is_anon_role >>
 753
 754 Returns true if the role is an anonymous role.
 755
 756 =item B<< $metarole->consumers >>
 757
 758 Returns a list of names of classes and roles which consume this role.
 759
 760 =back
 761
 762 =head2 Role application
 763
 764 =over 4
 765
 766 =item B<< $metarole->apply( $thing, @options ) >>
 767
 768 This method applies a role to the given C<$thing>. That can be another
 769 L<Moose::Meta::Role>, object, a L<Moose::Meta::Class> object, or a
 770 (non-meta) object instance.
 771
 772 The options are passed directly to the constructor for the appropriate
 773 L<Moose::Meta::Role::Application> subclass.
 774
 775 Note that this will apply the role even if the C<$thing> in question already
 776 C<does> this role.  L<Moose::Util/does_role> is a convenient wrapper for
 777 finding out if role application is necessary.
 778
 779 =back
 780
 781 =head2 Roles and other roles
 782
 783 =over 4
 784
 785 =item B<< $metarole->get_roles >>
 786
 787 This returns an array reference of roles which this role does. This
 788 list may include duplicates.
 789
 790 =item B<< $metarole->calculate_all_roles >>
 791
 792 This returns a I<unique> list of all roles that this role does, and
 793 all the roles that its roles do.
 794
 795 =item B<< $metarole->does_role($role) >>
 796
 797 Given a role I<name> or L<Moose::Meta::Role> object, returns true if this role
 798 does the given role.
 799
 800 =item B<< $metarole->add_role($role) >>
 801
 802 Given a L<Moose::Meta::Role> object, this adds the role to the list of
 803 roles that the role does.
 804
 805 =item B<< $metarole->get_excluded_roles_list >>
 806
 807 Returns a list of role names which this role excludes.
 808
 809 =item B<< $metarole->excludes_role($role_name) >>
 810
 811 Given a role I<name>, returns true if this role excludes the named
 812 role.
 813
 814 =item B<< $metarole->add_excluded_roles(@role_names) >>
 815
 816 Given one or more role names, adds those roles to the list of excluded
 817 roles.
 818
 819 =back
 820
 821 =head2 Methods
 822
 823 The methods for dealing with a role's methods are all identical in API
 824 and behavior to the same methods in L<Class::MOP::Class>.
 825
 826 =over 4
 827
 828 =item B<< $metarole->method_metaclass >>
 829
 830 Returns the method metaclass name for the role. This defaults to
 831 L<Moose::Meta::Role::Method>.
 832
 833 =item B<< $metarole->get_method($name) >>
 834
 835 =item B<< $metarole->has_method($name) >>
 836
 837 =item B<< $metarole->add_method( $name, $body ) >>
 838
 839 =item B<< $metarole->get_method_list >>
 840
 841 =item B<< $metarole->find_method_by_name($name) >>
 842
 843 These methods are all identical to the methods of the same name in
 844 L<Class::MOP::Package>
 845
 846 =back
 847
 848 =head2 Attributes
 849
 850 As with methods, the methods for dealing with a role's attribute are
 851 all identical in API and behavior to the same methods in
 852 L<Class::MOP::Class>.
 853
 854 However, attributes stored in this class are I<not> stored as
 855 objects. Rather, the attribute definition is stored as a hash
 856 reference. When a role is composed into a class, this hash reference
 857 is passed directly to the metaclass's C<add_attribute> method.
 858
 859 This is quite likely to change in the future.
 860
 861 =over 4
 862
 863 =item B<< $metarole->get_attribute($attribute_name) >>
 864
 865 =item B<< $metarole->has_attribute($attribute_name) >>
 866
 867 =item B<< $metarole->get_attribute_list >>
 868
 869 =item B<< $metarole->add_attribute($name, %options) >>
 870
 871 =item B<< $metarole->remove_attribute($attribute_name) >>
 872
 873 =back
 874
 875 =head2 Required methods
 876
 877 =over 4
 878
 879 =item B<< $metarole->get_required_method_list >>
 880
 881 Returns the list of methods required by the role.
 882
 883 =item B<< $metarole->requires_method($name) >>
 884
 885 Returns true if the role requires the named method.
 886
 887 =item B<< $metarole->add_required_methods(@names) >>
 888
 889 Adds the named methods to the role's list of required methods.
 890
 891 =item B<< $metarole->remove_required_methods(@names) >>
 892
 893 Removes the named methods from the role's list of required methods.
 894
 895 =item B<< $metarole->add_conflicting_method(%params) >>
 896
 897 Instantiate the parameters as a L<Moose::Meta::Role::Method::Conflicting>
 898 object, then add it to the required method list.
 899
 900 =back
 901
 902 =head2 Method modifiers
 903
 904 These methods act like their counterparts in L<Class::MOP::Class> and
 905 L<Moose::Meta::Class>.
 906
 907 However, method modifiers are simply stored internally, and are not
 908 applied until the role itself is applied to a class.
 909
 910 =over 4
 911
 912 =item B<< $metarole->add_after_method_modifier($method_name, $method) >>
 913
 914 =item B<< $metarole->add_around_method_modifier($method_name, $method) >>
 915
 916 =item B<< $metarole->add_before_method_modifier($method_name, $method) >>
 917
 918 =item B<< $metarole->add_override_method_modifier($method_name, $method) >>
 919
 920 These methods all add an appropriate modifier to the internal list of
 921 modifiers.
 922
 923 =item B<< $metarole->has_after_method_modifiers >>
 924
 925 =item B<< $metarole->has_around_method_modifiers >>
 926
 927 =item B<< $metarole->has_before_method_modifiers >>
 928
 929 =item B<< $metarole->has_override_method_modifier >>
 930
 931 Return true if the role has any modifiers of the given type.
 932
 933 =item B<< $metarole->get_after_method_modifiers($method_name) >>
 934
 935 =item B<< $metarole->get_around_method_modifiers($method_name) >>
 936
 937 =item B<< $metarole->get_before_method_modifiers($method_name) >>
 938
 939 Given a method name, returns a list of the appropriate modifiers for
 940 that method.
 941
 942 =item B<< $metarole->get_override_method_modifier($method_name) >>
 943
 944 Given a method name, returns the override method modifier for that
 945 method, if it has one.
 946
 947 =back
 948
 949 =head2 Introspection
 950
 951 =over 4
 952
 953 =item B<< Moose::Meta::Role->meta >>
 954
 955 This will return a L<Class::MOP::Class> instance for this class.
 956
 957 =back
 958
 959 =head1 BUGS
 960
 961 See L<Moose/BUGS> for details on reporting bugs.
 962
 963 =head1 AUTHOR
 964
 965 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 966
 967 =head1 COPYRIGHT AND LICENSE
 968
 969 Copyright 2006-2010 by Infinity Interactive, Inc.
 970
 971 L<http://www.iinteractive.com>
 972
 973 This library is free software; you can redistribute it and/or modify
 974 it under the same terms as Perl itself.
 975
 976 =cut