lib/Moose/Meta/Method/Destructor.pm

   1
   2 package Moose::Meta::Method::Destructor;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Devel::GlobalDestruction ();
   8 use Scalar::Util 'blessed', 'weaken';
   9 use Try::Tiny;
  10
  11 use base 'Moose::Meta::Method',
  12          'Class::MOP::Method::Inlined';
  13
  14 sub new {
  15     my $class   = shift;
  16     my %options = @_;
  17
  18     (ref $options{options} eq 'HASH')
  19         || $class->throw_error("You must pass a hash of options", data => $options{options});
  20
  21     ($options{package_name} && $options{name})
  22         || $class->throw_error("You must supply the package_name and name parameters $Class::MOP::Method::UPGRADE_ERROR_TEXT");
  23
  24     my $self = bless {
  25         # from our superclass
  26         'body'                 => undef,
  27         'package_name'         => $options{package_name},
  28         'name'                 => $options{name},
  29         # ...
  30         'options'              => $options{options},
  31         'associated_metaclass' => $options{metaclass},
  32     } => $class;
  33
  34     # we don't want this creating
  35     # a cycle in the code, if not
  36     # needed
  37     weaken($self->{'associated_metaclass'});
  38
  39     $self->_initialize_body;
  40
  41     return $self;
  42 }
  43
  44 ## accessors
  45
  46 sub options              { (shift)->{'options'}              }
  47
  48 ## method
  49
  50 sub is_needed {
  51     my $self      = shift;
  52     my $metaclass = shift;
  53
  54     ( blessed $metaclass && $metaclass->isa('Class::MOP::Class') )
  55         || $self->throw_error(
  56         "The is_needed method expected a metaclass object as its arugment");
  57
  58     return $metaclass->find_method_by_name("DEMOLISHALL");
  59 }
  60
  61 sub initialize_body {
  62     Carp::cluck('The initialize_body method has been made private.'
  63         . " The public version is deprecated and will be removed in a future release.\n");
  64     shift->_initialize_body;
  65 }
  66
  67 sub _initialize_body {
  68     my $self = shift;
  69     # TODO:
  70     # the %options should also include a both
  71     # a call 'initializer' and call 'SUPER::'
  72     # options, which should cover approx 90%
  73     # of the possible use cases (even if it
  74     # requires some adaption on the part of
  75     # the author, after all, nothing is free)
  76
  77     my $class = $self->associated_metaclass->name;
  78     my @source = (
  79         'sub {',
  80             'my $self = shift;',
  81             'return ' . $self->_generate_fallback_destructor('$self'),
  82                 'if Scalar::Util::blessed($self) ne \'' . $class . '\';',
  83             $self->_generate_DEMOLISHALL('$self'),
  84         '}',
  85     );
  86     warn join("\n", @source) if $self->options->{debug};
  87
  88     my $code = try {
  89         $self->_compile_code(source => \@source);
  90     }
  91     catch {
  92         my $source = join("\n", @source);
  93         $self->throw_error(
  94             "Could not eval the destructor :\n\n$source\n\nbecause :\n\n$_",
  95             error => $_,
  96             data  => $source,
  97         );
  98     };
  99
 100     $self->{'body'} = $code;
 101 }
 102
 103 sub _generate_fallback_destructor {
 104     my $self = shift;
 105     my ($inv) = @_;
 106
 107     return $inv . '->Moose::Object::DESTROY(@_)';
 108 }
 109
 110 sub _generate_DEMOLISHALL {
 111     my $self = shift;
 112     my ($inv) = @_;
 113
 114     my @methods = $self->associated_metaclass->find_all_methods_by_name('DEMOLISH');
 115     return unless @methods;
 116
 117     return (
 118         'local $?;',
 119         'my $igd = Devel::GlobalDestruction::in_global_destruction;',
 120         'Try::Tiny::try {',
 121             (map { $inv . '->' . $_->{class} . '::DEMOLISH($igd);' } @methods),
 122         '}',
 123         'Try::Tiny::catch {',
 124             'no warnings \'misc\';',
 125             'die $_;',
 126         '};',
 127         'return;',
 128     );
 129 }
 130
 131
 132 1;
 133
 134 # ABSTRACT: Method Meta Object for destructors
 135
 136 __END__
 137
 138 =pod
 139
 140 =head1 DESCRIPTION
 141
 142 This class is a subclass of L<Class::MOP::Class::Generated> that
 143 provides Moose-specific functionality for inlining destructors.
 144
 145 To understand this class, you should read the the
 146 L<Class::MOP::Class::Generated> documentation as well.
 147
 148 =head1 INHERITANCE
 149
 150 C<Moose::Meta::Method::Destructor> is a subclass of
 151 L<Moose::Meta::Method> I<and> L<Class::MOP::Method::Generated>.
 152
 153 =head1 METHODS
 154
 155 =over 4
 156
 157 =item B<< Moose::Meta::Method::Destructor->new(%options) >>
 158
 159 This constructs a new object. It accepts the following options:
 160
 161 =over 8
 162
 163 =item * package_name
 164
 165 The package for the class in which the destructor is being
 166 inlined. This option is required.
 167
 168 =item * name
 169
 170 The name of the destructor method. This option is required.
 171
 172 =item * metaclass
 173
 174 The metaclass for the class this destructor belongs to. This is
 175 optional, as it can be set later by calling C<<
 176 $metamethod->attach_to_class >>.
 177
 178 =back
 179
 180 =item B<< Moose::Meta;:Method::Destructor->is_needed($metaclass) >>
 181
 182 Given a L<Moose::Meta::Class> object, this method returns a boolean
 183 indicating whether the class needs a destructor. If the class or any
 184 of its parents defines a C<DEMOLISH> method, it needs a destructor.
 185
 186 =back
 187
 188 =head1 BUGS
 189
 190 See L<Moose/BUGS> for details on reporting bugs.
 191
 192 =cut
 193