lib/Moose/Meta/Method/Destructor.pm

   1
   2 package Moose::Meta::Method::Destructor;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Scalar::Util 'blessed', 'weaken';
   8
   9 our $VERSION   = '0.72';
  10 $VERSION = eval $VERSION;
  11 our $AUTHORITY = 'cpan:STEVAN';
  12
  13 use base 'Moose::Meta::Method',
  14          'Class::MOP::Method::Generated';
  15
  16 sub new {
  17     my $class   = shift;
  18     my %options = @_;
  19
  20     (ref $options{options} eq 'HASH')
  21         || $class->throw_error("You must pass a hash of options", data => $options{options});
  22
  23     ($options{package_name} && $options{name})
  24         || $class->throw_error("You must supply the package_name and name parameters $Class::MOP::Method::UPGRADE_ERROR_TEXT");
  25
  26     my $self = bless {
  27         # from our superclass
  28         'body'                 => undef,
  29         'package_name'         => $options{package_name},
  30         'name'                 => $options{name},
  31         # ...
  32         'options'              => $options{options},
  33         'associated_metaclass' => $options{metaclass},
  34     } => $class;
  35
  36     # we don't want this creating
  37     # a cycle in the code, if not
  38     # needed
  39     weaken($self->{'associated_metaclass'});
  40
  41     $self->initialize_body;
  42
  43     return $self;
  44 }
  45
  46 ## accessors
  47
  48 sub options              { (shift)->{'options'}              }
  49
  50 ## method
  51
  52 sub is_needed {
  53     my $self      = shift;
  54     my $metaclass = shift;
  55
  56     ( blessed $metaclass && $metaclass->isa('Class::MOP::Class') )
  57         || $self->throw_error(
  58         "The is_needed method expected a metaclass object as its arugment");
  59
  60     return $metaclass->meta->can('DEMOLISH');
  61 }
  62
  63 sub initialize_body {
  64     my $self = shift;
  65     # TODO:
  66     # the %options should also include a both
  67     # a call 'initializer' and call 'SUPER::'
  68     # options, which should cover approx 90%
  69     # of the possible use cases (even if it
  70     # requires some adaption on the part of
  71     # the author, after all, nothing is free)
  72
  73     my @DEMOLISH_methods = $self->associated_metaclass->find_all_methods_by_name('DEMOLISH');
  74
  75     return unless @DEMOLISH_methods;
  76
  77     my $source = 'sub {';
  78
  79     my @DEMOLISH_calls;
  80     foreach my $method (@DEMOLISH_methods) {
  81         push @DEMOLISH_calls => '$_[0]->' . $method->{class} . '::DEMOLISH()';
  82     }
  83
  84     $source .= join ";\n" => @DEMOLISH_calls;
  85
  86     $source .= ";\n" . '}';
  87     warn $source if $self->options->{debug};
  88
  89     my $code = $self->_compile_code(
  90         environment => {},
  91         code => $source,
  92     ) or $self->throw_error("Could not eval the destructor :\n\n$source\n\nbecause :\n\n$@", error => $@, data => $source);
  93
  94     $self->{'body'} = $code;
  95 }
  96
  97
  98 1;
  99
 100 __END__
 101
 102 =pod
 103
 104 =head1 NAME
 105
 106 Moose::Meta::Method::Destructor - Method Meta Object for destructors
 107
 108 =head1 DESCRIPTION
 109
 110 This class is a subclass of L<Class::MOP::Class::Generated> that
 111 provides Moose-specific functionality for inlining destructors.
 112
 113 To understand this class, you should read the the
 114 L<Class::MOP::Class::Generated> documentation as well.
 115
 116 =head1 INHERITANCE
 117
 118 C<Moose::Meta::Method::Destructor> is a subclass of
 119 L<Moose::Meta::Method> I<and> L<Class::MOP::Method::Generated>.
 120
 121 =head1 METHODS
 122
 123 =over 4
 124
 125 =item B<< Moose::Meta;:Method::Destructor->new(%options) >>
 126
 127 This constructs a new object. It accepts the following options:
 128
 129 =over 8
 130
 131 =item * package_name
 132
 133 The package for the class in which the destructor is being
 134 inlined. This option is required.
 135
 136 =item * name
 137
 138 The name of the destructor method. This option is required.
 139
 140 =item * metaclass
 141
 142 The metaclass for the class this destructor belongs to. This is
 143 optional, as it can be set later by calling C<<
 144 $metamethod->attach_to_class >>.
 145
 146 =back
 147
 148 =item B<< Moose::Meta;:Method::Destructor->is_needed($metaclass) >>
 149
 150 Given a L<Moose::Meta::Class> object, this method returns a boolean
 151 indicating whether the class needs a destructor. If the class or any
 152 of its parents defines a C<DEMOLISH> method, it needs a destructor.
 153
 154 =back
 155
 156 =head1 AUTHORS
 157
 158 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 159
 160 =head1 COPYRIGHT AND LICENSE
 161
 162 Copyright 2006-2009 by Infinity Interactive, Inc.
 163
 164 L<http://www.iinteractive.com>
 165
 166 This library is free software; you can redistribute it and/or modify
 167 it under the same terms as Perl itself.
 168
 169 =cut
 170