lib/Moose/Meta/Method/Destructor.pm

   1
   2 package Moose::Meta::Method::Destructor;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Scalar::Util 'blessed', 'weaken';
   8
   9 our $VERSION   = '0.72';
  10 $VERSION = eval $VERSION;
  11 our $AUTHORITY = 'cpan:STEVAN';
  12
  13 use base 'Moose::Meta::Method',
  14          'Class::MOP::Method::Generated';
  15
  16 sub new {
  17     my $class   = shift;
  18     my %options = @_;
  19
  20     (ref $options{options} eq 'HASH')
  21         || $class->throw_error("You must pass a hash of options", data => $options{options});
  22
  23     ($options{package_name} && $options{name})
  24         || $class->throw_error("You must supply the package_name and name parameters $Class::MOP::Method::UPGRADE_ERROR_TEXT");
  25
  26     my $self = bless {
  27         # from our superclass
  28         'body'                 => undef,
  29         'package_name'         => $options{package_name},
  30         'name'                 => $options{name},
  31         # ...
  32         'options'              => $options{options},
  33         'associated_metaclass' => $options{metaclass},
  34     } => $class;
  35
  36     # we don't want this creating
  37     # a cycle in the code, if not
  38     # needed
  39     weaken($self->{'associated_metaclass'});
  40
  41     $self->initialize_body;
  42
  43     return $self;
  44 }
  45
  46 ## accessors
  47
  48 sub options              { (shift)->{'options'}              }
  49 sub associated_metaclass { (shift)->{'associated_metaclass'} }
  50
  51 ## method
  52
  53 sub is_needed {
  54     my $self      = shift;
  55     my $metaclass = shift;
  56
  57     ( blessed $metaclass && $metaclass->isa('Class::MOP::Class') )
  58         || $self->throw_error(
  59         "The is_needed method expected a metaclass object as its arugment");
  60
  61     return $metaclass->meta->can('DEMOLISH');
  62 }
  63
  64 sub initialize_body {
  65     my $self = shift;
  66     # TODO:
  67     # the %options should also include a both
  68     # a call 'initializer' and call 'SUPER::'
  69     # options, which should cover approx 90%
  70     # of the possible use cases (even if it
  71     # requires some adaption on the part of
  72     # the author, after all, nothing is free)
  73
  74     my @DEMOLISH_methods = $self->associated_metaclass->find_all_methods_by_name('DEMOLISH');
  75
  76     return unless @DEMOLISH_methods;
  77
  78     my $source = 'sub {';
  79
  80     my @DEMOLISH_calls;
  81     foreach my $method (@DEMOLISH_methods) {
  82         push @DEMOLISH_calls => '$_[0]->' . $method->{class} . '::DEMOLISH()';
  83     }
  84
  85     $source .= join ";\n" => @DEMOLISH_calls;
  86
  87     $source .= ";\n" . '}';
  88     warn $source if $self->options->{debug};
  89
  90     my $code = $self->_compile_code(
  91         environment => {},
  92         code => $source,
  93     ) or $self->throw_error("Could not eval the destructor :\n\n$source\n\nbecause :\n\n$@", error => $@, data => $source);
  94
  95     $self->{'body'} = $code;
  96 }
  97
  98
  99 1;
 100
 101 __END__
 102
 103 =pod
 104
 105 =head1 NAME
 106
 107 Moose::Meta::Method::Destructor - Method Meta Object for destructors
 108
 109 =head1 DESCRIPTION
 110
 111 This is a subclass of L<Class::MOP::Method> which handles
 112 constructing an appropriate Destructor method. This is primarily
 113 used in the making of immutable metaclasses, otherwise it is
 114 not particularly useful.
 115
 116 =head1 METHODS
 117
 118 =over 4
 119
 120 =item B<new>
 121
 122 =item B<attributes>
 123
 124 =item B<meta_instance>
 125
 126 =item B<options>
 127
 128 =item B<is_needed>
 129
 130 =item B<initialize_body>
 131
 132 =item B<associated_metaclass>
 133
 134 =back
 135
 136 =head1 AUTHORS
 137
 138 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 139
 140 =head1 COPYRIGHT AND LICENSE
 141
 142 Copyright 2006-2009 by Infinity Interactive, Inc.
 143
 144 L<http://www.iinteractive.com>
 145
 146 This library is free software; you can redistribute it and/or modify
 147 it under the same terms as Perl itself.
 148
 149 =cut
 150